Pavage

[mumblee]

Bonjour,

Juste un exemple de pavage que j'ai demandé de faire à mes élèves de sixième. Ils devaient remplir une page A4.

Comme d'habitude, je prends les améliorations du code que vous suggérerez

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
// Changez l'unité de longueur pour remplir une page A4.
// Avec 1cm, l'image obtenue est trop grande pour être acceptée par le forum.
unitsize(2.5mm);
// unitsize(1cm);
 
point pA=(0,0), pB=shift((4,0))*pA, pC=rotate(60,pA)*pB;
 
void Pave(point P=pA) {
  // Figures de base
  point pa=P, pb=shift((4,0))*pa, pc=rotate(60,pa)*pb;
  path tri=pa--pb--pc--cycle,
    carre=pa--pb--rotate(-90,pb)*pa--rotate(90,pa)*pb--cycle,
    losa=pa--reflect(line(pa,pb))*pc--pb--pc--cycle;
 
  // Un pavé
  path L1=rotate(30,pa)*losa;
  path L2=rotate(150,pa)*losa;
  path L3=rotate(270,pa)*losa;
  path C1=shift((rotate(210,pa)*pb-pa)+(pa-pb))*carre;
  path C2=shift(rotate(210,pa)*pb-pa+(pa-pc))*rotate(-30,pa)*carre;
  path C3=shift((rotate(270,pa)*pb-pa)+(pb-pc))*rotate(30,pa)*carre;
  path T1=shift(rotate(270,pa)*pb-pa+(pa-pc))*tri;
  path T2=shift((rotate(210,pa)*pb-pa)+(pa-pb))*rotate(-60,pa)*tri;
  filldraw(L1,cyan,black);
  filldraw(L2,magenta,black);
  filldraw(L3,yellow,black);
  filldraw(C1,lightblue,black);
  filldraw(C2,blue,black);
  filldraw(C3,deepblue,black);
  filldraw(T1,lightgreen,black);
  filldraw(T2,lightred,black);
}
 
// Translations du pavage
vector u=rotate(-30,pA)*(pB-pA)+(pB-pA)+rotate(30,pA)*(pB-pA), v=rotate(60,pA)*u;
 
// Remplissage
for(int i=0; i<3; ++i){
  for(int j=0; j<4; ++j){
    Pave((i-quotient(j,2))*u+j*v);
  }
}
 
path pageA4=(0,0)--(21,0)--(21,29.7)--(0,29.7)--cycle;
clip(pageA4);

[GM]

Merci pour la participation.

Plutôt que :

Code : Tout sélectionner

Pave(point P=pA)

avec un argument par défaut qui ne devrait pas dépendre de la définition d'un point pA
et la nécessité de faire ensuite une double boucle imbriquée

... je verrai plutôt :

Code : Tout sélectionner

Pavage(point P=(0,0),int nh=1,int nv=1,bool crop=true)

avec les nombres nh et nv spécifiant les nombres de "pavés" à mettre horizontalement et verticalement,
et un booléen crop pour limiter à un rectangle qui tient compte de nh et nv.

[mumblee]

Bonjour,

je verrai plutôt :

Code : Tout sélectionner

Pavage(point P=(0,0),int nh=1,int nv=1,bool crop=true)

avec les nombres nh et nv spécifiant les nombres de "pavés" à mettre horizontalement et verticalement,
et un booléen crop pour limiter à un rectangle qui tient compte de nh et nv.

Merci de tes remarques. Ci-dessous, une première tentative d'adaptation. J'ai préféré sortir le crop suite à la possibilité de choisir la direction du tracé. C'est mieux ?

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
unitsize(1cm);
 
// Un pavé
picture Pave(vector u=(1,0), real taille=1) {
  picture pic;
  // Figures de base
  point pa=(0,0), pb=scale(taille,pa)*shift(u)*pa, pc=rotate(60,pa)*pb;
  path tri=pa--pb--pc--cycle,
    carre=pa--pb--rotate(-90,pb)*pa--rotate(90,pa)*pb--cycle,
    losa=pa--reflect(line(pa,pb))*pc--pb--pc--cycle;
  // Figures constituant un pavé
  path L1=losa;
  path L2=rotate(120,pa)*losa;
  path L3=rotate(240,pa)*losa;
  path C1=shift(pa-pc)*reflect(line(pa,pb))*carre;
  path C2=shift(pa-pc)*rotate(120,pa)*carre;
  path C3=shift(pa-pb)*rotate(60,pa)*carre;
  path T1=shift(pa-pc)*rotate(210,pa)*tri;
  path T2=shift(pa-pb)*rotate(150,pa)*tri;
  // Tracé
  filldraw(pic,L1,cyan,black);
  filldraw(pic,L2,magenta,black);
  filldraw(pic,L3,yellow,black);
  filldraw(pic,C1,lightblue,black);
  filldraw(pic,C2,blue,black);
  filldraw(pic,C3,deepblue,black);
  filldraw(pic,T1,lightgreen,black);
  filldraw(pic,T2,lightred,black);
  return pic;
}
 
// Un pavage
picture Pavage(point pP=(0,0), vector u=(1,0), real taille=1, int nh=1, int nv=1) {
  picture pic;
  // Vecteurs de translations du pavé
  point pa=(0,0), pb=scale(taille)*shift(u)*pa, pc=rotate(60,pa)*pb;
  vector vv=(rotate(90,pa)*(pb-pa))+(pc-pa)+(pc-pb), vh=rotate(-60,pa)*vv;
  // Remplissage
  for(int i=0; i<nh; ++i){
    for(int j=0; j<nv; ++j){
      add(pic,shift(i*vh+(j-quotient(i,2))*vv+pP)*Pave(u,taille));
    }
  }
  return pic;
}
 
// Tracé du pavage dans currentpicture
real t=1;
point pA=(0,0);
add(Pavage(pA,(1,0),taille=t,nh=3,nv=4));
 
// // Obtention d'une page A5
// path pageA5=(0,0)--(14.85,0)--(14.85,21)--(0,21)--cycle;
// clip(pageA5);