Graduations et parallèles

[Viserion]

Bonsoir Gaëtan,
L'idée est de reproduire la figure en sachant, sauf erreur de ma part, que les abscisses des points U et P sont respectivement et .
Mon problème est de tracer les deux parallèles rouges à partir de deux graduations.
Merci.
Fabrice

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
 
settings.tex="pdflatex";
 
size(10cm,0);
 
point pA=(-1,0),pB=(sqrt(13),0), pC=(0,0),
pD=(1,0), pE=(0,-3), pF=(2,-3), pG=(2,0),
pH=(-5/7,0), pI=(2,-2);
 
line d1=line(pE,pF);
line d2=line(pG,pF);
line d3=line(pA,pB);
line d4=line(pG,pF);
line d5=line(pC,pE);
line d6=line(pC,pI);
 
perpendicularmark(d1,d2,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(d2,d3,Fill(green),quarter=4,size=0.2cm);
perpendicularmark(d1,d5,Fill(green),quarter=1,size=0.2cm);
perpendicularmark(d3,d5,Fill(green),quarter=4,size=0.2cm);
 
draw(pC--pE--pF--pG);
draw(d3);
 
draw(arc(pC,sqrt(13),-56.3099,0));
draw(pC--pF,orange);
draw(d6,blue+white);
transform t=shift(pC-pI);
path q = pC -- t*pC;
 
draw(q,invisible,StickIntervalMarker(7,1,blue,angle=-15,size=1mm,space=1mm));
label("3",(pC+pE)/2,W);
label("2",(pF+pE)/2,S);
dot("$O$",pC,N);
dot("$I$",pD,N);
dot("P",pB,N);
dot("U",pH,SE);
dot("$-1$",pA,SW);
 
linemargin =-2cm;
addMargins(.5cm,.5cm);

[GM]

Bonsoir,
est-il possible d'avoir une copie du texte de l'énoncé ?
car la reproduction ci-dessus des graduations me semble bizarre
et j'ai besoin de m'approprier le sujet avant de regarder ton code.

[GM]

Bonsoir,
est-il possible d'avoir une copie du texte de l'énoncé ?
car la reproduction ci-dessus des graduations me semble bizarre
et j'ai besoin de m'approprier le sujet avant de regarder ton code.

Je crois deviner que ce sont des points de la droite d'équation
mais quel est censé être l'espacement des points sur cette droite : l'info ne me semble pas y être.

[Viserion]

Bonsoir,
Je ne crois pas que l'énoncé va aider, mais le voici :

"La droite graduée suivante est munie d'un repère (O ; I) et les droites rouges sont parallèles. Déterminer les abscisses des points U et P."

Merci.
Fabrice

[GM]

Bonsoir,
Je ne crois pas que l'énoncé va aider, mais le voici :

"La droite graduée suivante est munie d'un repère (O ; I) et les droites rouges sont parallèles. Déterminer les abscisses des points U et P."

Merci.
Fabrice

Si, cela me permet de comprendre que l'on peut faire n'importe quoi comme espacement de graduation.
Je te prépare une réponse.

[GM]

Je te prépare une réponse.

... mais je change tout car

1. ceci est très perturbant :

   Code : Tout sélectionner

   dot("$O$",pC,N);
   dot("$I$",pD,N);
   dot("P",pB,N);
   dot("U",pH,SE);

   Pourquoi pB n'est pas B, pI n'est pas I, etc...
2. Je me dis que c'est un exercice où il faut construire U et P, sans avoir calculé préalablement leurs abscisses, et sans avoir calculé manuellement l'angle de l'arc de cercle !
3. On peut en faire une figure qui dépendra de paramètres pour pouvoir faire plusieurs versions différentes du même exercice.

[GM]

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
settings.tex="pdflatex";
 
size(8cm,0);
 
// Paramètres  de la figure
real theta = 135; // Angle de la droite bleue
real esp = 0.25;   // Espacement des graduations
 
point pO =(0,0), pA=(0,-3), pB=(2,-3), pC=(2,0), pE=(-1,0);
path rect  =  pO--pA--pB--pC--cycle;
 
line dOA=line(pO,pA), dAB=line(pA,pB), dBC=line(pB,pC), dCO=line(pC,pO),
      droitebleue = line(pO,dir(theta)),
      drouge1 = line(pE,7*esp*dir(theta)),
      drouge2 = parallel(5*esp*dir(theta),drouge1);
 
point pU=intersectionpoint(drouge2,dCO);
 
circle c = circle (pO, abs(pB-pO));
point pP = intersectionpoints(c,dCO)[1];
 
draw(rect);
perpendicularmark(dOA,dAB,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dAB,dBC,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dBC,dCO,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dCO,dOA,Fill(green),quarter=2,size=0.2cm);
draw(dCO);
draw(droitebleue,blue+white);
 
draw(pO--pC,invisible,StickIntervalMarker(2,2,red,angle=-15,size=1mm,space=1mm));
 
// Points de la droite bleue        
for(int k=0; k<=7; ++k) dot(k*esp*dir(theta));
// et le codage
draw(pO--7*esp*dir(theta),invisible,StickIntervalMarker(7,1,blue,angle=-15,size=1mm,space=1mm));
 
draw(arccircle(pO,pB,aTan(3/2)));
draw(pO--pB,orange);
draw(drouge1^^drouge2,red);
 
dot("$O$",pO,N);
dot("$I$",(pO+pC)/2,N);
dot("P",pP,N);
dot("U",pU,SE);
dot("$-1$",pE,SW);
label("3",(pO+pA)/2,W);
label("2",(pA+pB)/2,S);
 
linemargin =-0.5cm;
addMargins(.5cm,.5cm);

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
settings.tex="pdflatex";
 
size(8cm,0);
 
// Paramètres  de la figure
real theta = 80; // Angle de la droite bleue
real esp = 0.4;   // Espacement des graduations
 
point pO =(0,0), pA=(0,-3), pB=(2,-3), pC=(2,0), pE=(-1,0);
path rect  =  pO--pA--pB--pC--cycle;
 
line dOA=line(pO,pA), dAB=line(pA,pB), dBC=line(pB,pC), dCO=line(pC,pO),
      droitebleue = line(pO,dir(theta)),
      drouge1 = line(pE,7*esp*dir(theta)),
      drouge2 = parallel(5*esp*dir(theta),drouge1);
 
point pU=intersectionpoint(drouge2,dCO);
 
circle c = circle (pO, abs(pB-pO));
point pP = intersectionpoints(c,dCO)[1];
 
draw(rect);
perpendicularmark(dOA,dAB,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dAB,dBC,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dBC,dCO,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dCO,dOA,Fill(green),quarter=2,size=0.2cm);
draw(dCO);
draw(droitebleue,blue+white);
 
draw(pO--pC,invisible,StickIntervalMarker(2,2,red,angle=-15,size=1mm,space=1mm));
 
// Points de la droite bleue        
for(int k=0; k<=7; ++k) dot(k*esp*dir(theta));
// et le codage
draw(pO--7*esp*dir(theta),invisible,StickIntervalMarker(7,1,blue,angle=-15,size=1mm,space=1mm));
 
draw(arccircle(pO,pB,aTan(3/2)));
draw(pO--pB,orange);
draw(drouge1^^drouge2,red);
 
dot("$O$",pO,N);
dot("$I$",(pO+pC)/2,N);
dot("P",pP,N);
dot("U",pU,SE);
dot("$-1$",pE,SW);
label("3",(pO+pA)/2,W);
label("2",(pA+pB)/2,S);
 
linemargin =-0.5cm;
addMargins(.5cm,.5cm);

[GM]

On pourrait faire mieux en mettant en paramètres les nombres 5 et 7 pour modifier le rapport 5/7.

[GM]

Avant de supprimer l'exemple de mon PC, j'ai ajouté deux paramètres de réglage :

• le choix de l'abscisse de U à trouver :
• les dimensions du rectangle

ainsi que quelques commentaires pour expliquer.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
settings.tex="pdflatex";
 
size(8cm,0);
 
//---------------------------------------------------
//--------- Paramètres  de la figure
//---------------------------------------------------
real theta = 140;      // Angle de la droite bleue
real esp = 0.4;       // Espacement des graduations
int a=4, b=3;         // Rapport a/b relatif aux graduations, avec a>b
real larg=2, haut=4;  // Dimensions du rectangle
//---------------------------------------------------
 
// Définition des points O, A, B, C et E
point pO =(0,0), pA=(0,-haut), pB=(larg,-haut), pC=(larg,0), pE=(-1,0);
 
// Définition du rectangle OABC
path rectOABC  =  pO--pA--pB--pC--cycle;
 
// Définition des droites relatives au rectangle OABC
line dOA=line(pO,pA), dAB=line(pA,pB), dBC=line(pB,pC), dCO=line(pC,pO);
// La droite bleue passant par le point O est le point de coordonnées polaires (1;theta)
line droitebleue = line(pO,dir(theta));
 
// La droite rouge 1 qui passe par le point E(-1,0) et le point de coordonnées polaires (a*esp;theta)
line drouge1 = line(pE,a*esp*dir(theta));
// La droite rouge 2 qui est parallèle à drouge1 et passe par point de coordonnées polaires (b*esp;theta)
line drouge2 = parallel(b*esp*dir(theta),drouge1);
 
// Le point U à l'intersection des droites "drouge1" et (OC)
point pU=intersectionpoint(drouge2,dCO);
 
// Définition de P à l'intersection du cercle de centre O passant par B
//                                  et de la droite (OC)
circle c = circle (pO, abs(pB-pO));
point pP = intersectionpoints(c,dCO)[1]; // [0] ou [1] selon le point d'intersection voulu
 
draw(rectOABC);
perpendicularmark(dOA,dAB,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dAB,dBC,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dBC,dCO,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dCO,dOA,Fill(green),quarter=2,size=0.2cm);
draw(dCO);
draw(droitebleue,blue+white);
 
draw(pO--pC,invisible,StickIntervalMarker(2,2,red,angle=-15,size=1mm,space=1mm));
 
// Points de la droite bleue        
for(int k=0; k<=a; ++k) dot(k*esp*dir(theta));
// et le codage des espacements égaux entre les points
draw(pO--a*esp*dir(theta),invisible,StickIntervalMarker(a,1,blue,angle=-15,size=1mm,space=1mm));
 
draw(arccircle(pO,pB,aTan(haut/larg)));
draw(pO--pB,orange);
draw(drouge1^^drouge2,red);
 
dot("$O$",pO,N);
dot("$I$",(pO+pC)/2,N);
dot("P",pP,N);
dot("U",pU,SE);
dot("$-1$",pE,SW);
label(format(haut),(pO+pA)/2,W);
label(format(larg),(pA+pB)/2,S);
 
label(format("$x_U=-\frac{%i}",b)+format("{%i}$",a)
      +format(" et $x_P=\sqrt{%f}$",larg^2+haut^2),
      truepoint(NE),NW);
 
linemargin =-0.5cm;
addMargins(.5cm,.5cm);

[GM]

J'ai rajouté l'affichage des valeurs des deux abscisses (calculées selon les paramètres) :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
settings.tex="pdflatex";
 
size(8cm,0);
 
//---------------------------------------------------
//--------- Paramètres  de la figure
//---------------------------------------------------
real theta = 140;       // Angle de la droite bleue
real esp = 0.4;          // Espacement des graduations
int a=7, b=5;            // Rapport a/b relatif aux graduations, avec a>b
real larg=3, haut=2;  // Dimensions du rectangle
//---------------------------------------------------
 
// Définition des points O, A, B, C et E
point pO =(0,0), pA=(0,-haut), pB=(larg,-haut), pC=(larg,0), pE=(-1,0);
 
// Définition du rectangle OABC
path rectOABC  =  pO--pA--pB--pC--cycle;
 
// Définition des droites relatives au rectangle OABC
line dOA=line(pO,pA), dAB=line(pA,pB), dBC=line(pB,pC), dCO=line(pC,pO);
// La droite bleue passant par le point O est le point de coordonnées polaires (1;theta)
line droitebleue = line(pO,dir(theta));
 
// La droite rouge 1 qui passe par le point E(-1,0) et le point de coordonnées polaires (a*esp;theta)
line drouge1 = line(pE,a*esp*dir(theta));
// La droite rouge 2 qui est parallèle à drouge1 et passe par point de coordonnées polaires (b*esp;theta)
line drouge2 = parallel(b*esp*dir(theta),drouge1);
 
// Le point U à l'intersection des droites "drouge2" et (OC)
point pU=intersectionpoint(drouge2,dCO);
 
// Définition de P à l'intersection du cercle de centre O passant par B
//                                  et de la droite (OC)
circle c = circle (pO, abs(pB-pO));
point pP = intersectionpoints(c,dCO)[1]; // [0] ou [1] selon le point d'intersection voulu
 
draw(rectOABC);
perpendicularmark(dOA,dAB,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dAB,dBC,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dBC,dCO,Fill(green),quarter=2,size=0.2cm);
perpendicularmark(dCO,dOA,Fill(green),quarter=2,size=0.2cm);
draw(dCO);
draw(droitebleue,blue+white);
 
draw(pO--pC,invisible,StickIntervalMarker(2,2,red,angle=-15,size=1mm,space=1mm));
 
// Points de la droite bleue        
for(int k=0; k<=a; ++k) dot(k*esp*dir(theta));
// et le codage des espacements égaux entre les points
draw(pO--a*esp*dir(theta),invisible,StickIntervalMarker(a,1,blue,angle=-15,size=1mm,space=1mm));
 
draw(arccircle(pO,pB,aTan(haut/larg)));
draw(pO--pB,orange);
draw(drouge1^^drouge2,red);
 
dot("$O$",pO,N);
dot("$I$",(pO+pC)/2,N);
dot("P",pP,N);
dot("U",pU,SE);
dot("$-1$",pE,SW);
 
// Affichage de la hauteur et de largeur du rectangle
label(format(haut),(pO+pA)/2,W);
label(format(larg),(pA+pB)/2,S);
 
// Affichage des valeurs des abscisses de U et P
label(format("$x_U=-\frac{%i}",b)+format("{%i}$",a)
      +format(" et $x_P=\sqrt{%f}$",larg^2+haut^2),
      truepoint(NE),NW);
 
linemargin =-0.5cm;
addMargins(.5cm,.5cm);