ASY-Forum

Voilà ce que je souhaitais, c'est un peu tiré par les cheveux mais à priori ça fonctionne !

Figure asymptote 8817b4449066b8b26148469568b345ea
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
 
unitsize(1cm);
 
// Les axes///////////////////////////////////////////
draw((-0.5,0)--(5,0),0.5bp+black,Arrow);  //horiz
draw((0,-1)--(0,8),0.5bp+black,Arrow);   //vert
//////////////////////////////////////////////////////
 
 
//Graduations verticales/////////////
label("$1$",(0,1),W);
draw((-0.1,1)--(0.1,1));
 
label("$2$",(0,2),W);
draw((-0.1,2)--(0.1,2));
 
label("$3$",(0,3),W);
draw((-0.1,3)--(0.1,3));
 
label("$4$",(0,4),W);
draw((-0.1,4)--(0.1,4));
 
label("$5$",(0,5),W);
draw((-0.1,5)--(0.1,5));
 
label("$6$",(0,6),W);
draw((-0.1,6)--(0.1,6));
 
////////////////////////////////////
 
 
//Graduations horizontales/////////
label("$1$",(1,0),2S);
draw((1,0.1)--(1,-0.1));
 
label("$2$",(2,0),2S);
draw((2,0.1)--(2,-0.1));
 
label("$3$",(3,0),2S);
draw((3,0.1)--(3,-0.1));
 
label("$4$",(4,0),2S);
draw((4,0.1)--(4,-0.1));
//////////////////////////////////
 
 
 
typedef real fonction_avec_parametre(real);
 
fonction_avec_parametre F(int k) {
       return new real(real x) {
           return
            3+sum(sequence(new real(int m){
              return 12*(-1)^m*cos(((2*m+1)*2*pi*x)/4)/((2*m+1)*pi);
              },
            k));
            };
       }
 
draw(graph(F(5),0,4,300), 1bp+red);
 
shipout(bbox(0mm,white,FillDraw(rgb(0.86,0.90,0.80))));

La première solution fonctionne... sous réserve de ne pas oublier qu'il faut un "format" par "%i".

Code : Tout sélectionner

import graph;

unitsize(1cm);

int n=15;
string fx="3",sfx;
for(int k=0; k<=n; ++k)
{
fx += format("+12*(-1)^%i",k)+format("*cos(((2*%i+1)*2*pi*x)/4)",k)+format("/((2*%i+1)*pi)",k);
}
write(fx);
sfx = "real f(real x) { return "+fx+"; }";

eval(sfx,true);

draw(graph(f,0,4,300), 1bp + rgb(0,0,1));

Et la seconde n'a rien de tiré par les cheveux : j'ai dit dans mon premier message que j'avais deux solutions en tête.
J'avais retenu le choix qui me permettait de ré-évoquer "eval" dont on n'avais plus parlé depuis longtemps... avec l'idée d'avoir une chaine qui permettait aussi d'écrire l'expression sur la figure : mais pour ce dernier point... il est vrai que si cela allait avec la simple somme de x^k que tu donnais au départ... on manque un peu de place et c'est peu lisible avec celle qui a suivi.

NB : je rappelle que $\pi$ a sa notation pi qui évite le 3.14.

Cette première solution ne manque pas d'ingéniosité, je prends !
Merci pour tout !
Bonne journée.

Une suggestion pour améliorer la solution 1 :

"format" est inutile puisque que finalement, on prend l'entier sans chercher à l'écrire sous une forme particulière.

Il sera avantageusement remplacé par ceci :

Code : Tout sélectionner

string K;
for(int k=0; k<=n; ++k)
{
   K=string(k);
   fx += "+12*(-1)^"+K+"*cos(((2*"+K+"+1)*2*pi*x)/4)/((2*"+K+"+1)*pi)";
}

On gagne en clarté du code.

ASY-Forum

somme de fonctions

Re: somme de fonctions

Re: somme de fonctions

Re: somme de fonctions

Re: somme de fonctions