ASY-Forum

Bonjour,

Je cherche à faire un repère comme celui-ci (page 4):
https://docs.google.com/viewer?url=http ... pt2009.pdf

(annexe sujet CGRH, Antilles sept 2009)
Mon problème, c'est que je ne sais pas comment faire démarrer mes graduations à 4800.
J'ai bien essayé ceci

// DEBUT

settings.outformat='pdf';

import geometry;
import graph_pi;
usepackage("mathrsfs");

unitsize(1cm);

real xmin=-0.1, xmax=15.5, ymin=4800, ymax=8000;

real ech=1;

graphicrules(xunit=1cm, yunit=0.001cm,
xmin=xmin, xmax=xmax,
ymin=ymin, ymax=ymax,
crop=Crop
);

// Définition et tracé de la grille

grid(xmin, xmax, ymin, ymax,
xStep=1, xstep=1,
yStep=1000, ystep=250,
pTick=0.5bp+.4white,
ptick=0.3bp+.8white,
above=true
);

// Définition et tracé des axes

cartesianaxis(xticks=Ticks(scale(ech)*Label(fontsize(10),Fill(white)),
Step=1, step=1,
Size=0.75mm, size=.5mm,
NoZero,
pTick=1bp+black, ptick=grey),
yticks=Ticks(scale(ech)*Label(fontsize(10),Fill(white)),
Step=500, step=500,
Size=0.75mm, size=.5mm,
NoZero,
pTick=1bp+black, ptick=grey),
Arrow);

// La figure

point ja = (1, 5000);
dot("", ja, S, 6bp+blue);

// Les limites du dessin

real factxmin=0.1;
real factxmax=0.05;
real factymin=0.1;
real factymax=0.5;

xlimits(xmin-factxmin*(xmax-xmin),xmax+factxmax*(xmax-xmin),Crop);
ylimits(ymin-factymin*(ymax-ymin),ymax+factymax*(ymax-ymin),Crop);

shipout(bbox(1mm,Fill(white)));

// FIN

mais alors je n'ai plus d'axe des abscisses.
Quelqu'un aurait-il une idée?
Merci d'avance pour toute piste.

Je vais y réfléchir... mais ce sera une solution sans graph_pi car cartesianaxis ne me semble pas prévu pour.

Voilà... avec volontairement certains traits (par exemple ceux en orange) dont le style sera à changer... mais c'était pour montrer qu'il y a différents lieux de réglages.

Figure asymptote 0571f7207b12767b13c0099576cfb29b
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
 
//unitsize(1cm,0.01cm);
unitsize(.5cm,0.005cm);
 
real xmin=0, xmax=13, xstep=1;
real ymin=4800, ymax=6800, ystep=100;
real[] xi={1,2,3,4,5,6,7,8,9,10};
int[]  yi={5000,5150,5300,5430,5570,5740,5860,6000,6120,6260};
path polygone=graph(xi,yi);
 
marker croix=marker(scale(2)*rotate(45)*cross(4),.6bp+blue);
// draw(polygone,croix);      // points + polygone
draw(polygone,nullpen,croix); // uniquement les points marqués d'une croix
 
// La grille
xlimits(xmin,xmax);
ylimits(ymin,ymax);
pen pTick=orange;
xaxis(BottomTop,pTick,Ticks("%",Step=5,    step=1,
                                pTick=gray,ptick=dotted,
                            extend=true));
yaxis(LeftRight,pTick,Ticks("%",Step=500,  step=100,
                                pTick=gray,ptick=dotted,
                            extend=true));
// Les axes
pen stylo=fontsize(8pt);
xequals(0,   ymin,ymax+ystep,stylo,RightTicks(Size=1,end=false,endlabel=false,Step=ystep),Arrow);
yequals(4800,xmin,xmax+xstep,stylo,LeftTicks(Size=1,end=false,endlabel=false,Step=xstep),Arrow);
label("$x_i$ (rang)",(xmax+xstep,ymin),SE,stylo);
label("$y_i$ (montant des charges en centaines d'euros)",(xmin,ymax+ystep),E,stylo);

Super!! Merci beaucoup

PS: en plus ça me donne plein d'idées à essayer!

J'ai ajouté deux exemples dans la galerie :

http://www.marris.org/asymptote/Grilles_Reperes/index.html#fig_gr01_180213_grille_avec_axe_decale

GM a écrit :J'ai ajouté deux exemples dans la galerie :

http://www.marris.org/asymptote/Grilles_Reperes/index.html#fig_gr01_180213_grille_avec_axe_decale

Je viens de modifier le premier des deux... pour y remplacer un style de pointillés :

Code : Tout sélectionner

linetype("4 4")

par un autre

Code : Tout sélectionner

.2mm+linetype("0 "+ string(1mm),offset=0,scale=false,adjust=false)

Le nombre de points est ainsi adapté aux graduations.

Figure asymptote 05147a5b88033816707ef87804662094
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
 
//unitsize(1cm,0.01cm);
unitsize(.5cm,0.005cm);
 
real xmin=0, xmax=12, xstep=1;
real ymin=4800, ymax=6500, ystep=100;
real[] xi={1,2,3,4,5,6,7,8,9,10};
int[]  yi={5000,5150,5300,5430,5570,5740,5860,6000,6120,6260};
path polygone=graph(xi,yi);
 
marker croix=marker(scale(2)*cross(4),.6bp+blue);
// draw(polygone,croix);      // points + polygone
draw(polygone,nullpen,croix); // uniquement les points marqués d'une croix
 
// La grille
xlimits(xmin,xmax);
ylimits(ymin,ymax);
pen pBord=nullpen,
    pGrille=.2mm+linetype("0 "+ string(1mm),offset=0,scale=false,adjust=false);
xaxis(BottomTop,pBord,Ticks("%",Step=5,    step=1,
                                pTick=gray,ptick=pGrille,
                            extend=true));
yaxis(LeftRight,pBord,Ticks("%",Step=500,  step=100,
                                pTick=gray,ptick=pGrille,
                            extend=true));
// Les axes
pen stylo=fontsize(8pt);
xequals(0,   ymin,ymax+ystep,stylo,RightTicks(Size=1,end=false,endlabel=false,Step=ystep),Arrow);
yequals(4800,xmin,xmax+xstep,stylo,LeftTicks(Size=1,end=false,endlabel=false,Step=xstep),Arrow);
label("$x_i$ (rang)",(xmax+xstep,ymin),SE,stylo);
label("$y_i$ (montant des charges en centaines d'euros)",(xmin,ymax+ystep),E,stylo);

ASY-Forum

graduer les axes en ne commençant pas à zéro

graduer les axes en ne commençant pas à zéro

Re: graduer les axes en ne commençant pas à zéro

Re: graduer les axes en ne commençant pas à zéro

Re: graduer les axes en ne commençant pas à zéro

Re: graduer les axes en ne commençant pas à zéro

Re: graduer les axes en ne commençant pas à zéro