Page 1 sur 2
path, subpath ...
Posté : mer. 15 août 2012, 11:30
par Coyote
Bonjour,
je suis désolé de poser cette question qui doit paraitre toute bete, mais là j'ai cherché partout et je deviens fou .
Je m'explique, j'ai deux chemins qui s'intersectent.
Je définis donc les 2 points d'intersections, puis sur le deuxième chemin je veux tracer la partie qui n'est pas contenue dans l'intersection !
Hors j'ai celle qui est justement dedans !!!
Je ne sais pas comment faire pour avoir l'autre ...
Je vous donne mon code (dont le départ revient à GM, un grand merci à lui pour son site) :
Code : Tout sélectionner
size(7.8cm,0);
// Je définis un chemin c1 et un second c2 déduit par translation.
path c1=(0,0)..(1.5,0)..(2,1.5)..(-1,1)..cycle,
c2=shift(-1.5,.6)*c1 ;
real[][] intt=intersections(c2,c1) ;
draw(subpath(c2, intt[0][0], intt[1][0]), 2bp+black);
draw(c1) ;
Je voudrais donc le complémentaire du chemin en gras ....
Merci d'avance.
Re: path, subpath ...
Posté : mer. 15 août 2012, 13:36
par OG
Comme il y a du cyclic dans l'air
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
size(7.8cm,0);
// Je définis un chemin c1 et un second c2 déduit par translation.
path c1=(0,0)..(1.5,0)..(2,1.5)..(-1,1)..cycle,
c2=shift(-1.5,.6)*c1 ;
real[][] intt=intersections(c2,c1) ;
draw(subpath(c2, length(c2)+intt[0][0], intt[1][0]), 1bp+black);
draw(c1) ;
O.G.
Re: path, subpath ...
Posté : mer. 15 août 2012, 15:22
par GM
Une variante avec des couteaux :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
size(7.8cm,0);
path c1=(0,0)..(1.5,0)..(2,1.5)..(-1,1)..cycle,
c2=shift(-1.5,.6)*c1,
p[]=firstcut(c2,c1).before^^lastcut(c2,c1).after;
draw(c1,red+2bp);
draw(c2,blue+2bp);
draw(p,green+1bp);
Re: path, subpath ...
Posté : mer. 15 août 2012, 16:00
par Coyote
Un grand merci ....
Dans le but de comprends, que rajoute le "length(c2)+", pour moi length(c2) représente la longueur du chemin ?
Re: path, subpath ...
Posté : mer. 15 août 2012, 16:10
par GM
Un exemple qui explique notamment la différence entre size et length :
http://www.marris.org/asymptote/Lignes/index.html#fig_ta01_010808_arctime--------
Edition : un exemple spécifique a été ajouté depuis : voir ci-dessous.
Re: path, subpath ...
Posté : mer. 15 août 2012, 16:14
par OG
Coyote a écrit :Un grand merci ....
Dans le but de comprends, que rajoute le "length(c2)+", pour moi length(c2) représente la longueur du chemin ?
length(c2) représente le nbre de segments (au sens courbe de Bézier bicubique) du chemin. Je n'ai pas testé sur un exemple de chemins
non cycliques afin de savoir si c'est spécifique ou non (en même temps sur un chemin non cyclique
il y a un début et une fin, c'est plus simple).
O.G.
Re: path, subpath ...
Posté : mer. 15 août 2012, 16:18
par GM
Je vais le modifier car il n'est pas assez clair : les at1, at2, ... semblent parachutés, alors que... non.
--------
Edition : j'ai modifié l'ordre de certaines lignes de code pour que cela soit plus facile à lire par rapport à la figure et j'ai ajouté des commentaires.
J'ai ajouté aussi un exemple plus simple pour montrer spécifiquement la différence entre size, length et arclength :
http://www.marris.org/asymptote/Lignes/index.html#fig_si01_160812_size_length
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
// Ne pas confondre size, length et arclength !
size(7.5cm,0);
path chemin=(-3,1)..(-1,2)..(4,0)..(5,3);
draw(chemin,blue,dot);
label(format("size(chemin) = %i",size(chemin)),truepoint(S),S);
label(format("length(chemin) = %i",length(chemin)),truepoint(S),S);
label(format("arclength(chemin) = %f",arclength(chemin)),truepoint(S),S);
shipout(bbox(3mm,white));
Re: path, subpath ...
Posté : mer. 15 août 2012, 16:49
par Coyote
Un grand merci à tous les deux, cela me semble un peu plus clair !
Dans tous les cas cela resout mon problème.
Re: path, subpath ...
Posté : jeu. 16 août 2012, 09:15
par GM
Coyote a écrit :cela me semble un peu plus clair !
Pour que cela le soit beaucoup plus, un exemple spécifique a été ajouté.
Cf. message édité ci-dessus.Et je rajoute une image supplémentaire pour rappeler l'usage de la fonction write pour des affichages en console (d'un éditeur qui en possède une,
comme notepad++ pour les utilisateurs de windows) :
Re: path, subpath ...
Posté : ven. 17 août 2012, 09:15
par Coyote
Merci encore.
Tant que je suis dedans, j'ai repris tes exemples sur buildcycle et je ne comprends absolument pas pourquoi un coup il prend l'intersection et un coup il prend la réunion.
Asymptote est encore bien mystérieux pour moi
.
