Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE
POLYGONES (23)
Liste des figures
Figure fig_aa01_150208_quadrilatere
figure 0001
Figure fig_aa02_150208_quadrilatere
figure 0002
Figure fig_aa03_290208_quadrilatere
figure 0003
Figure fig_aa04_290208_quadrilatere
figure 0004
Figure fig_ab01_150208_quadrilatere
figure 0005
Figure fig_ab02_290208_quadrilatere
figure 0006
Figure fig_ab03_120308_quadrilatere_hachure
figure 0007
Figure fig_ac01_290208_quadrilatere
figure 0008
Figure fig_ac02_290208_quadrilatere
figure 0009
Figure fig_ca01_080209_carre
figure 0010
Figure fig_ca02_080209_carre
figure 0011
Figure fig_ca03_040409_carre
figure 0012
Figure fig_cc01_080209_carre
figure 0013
Figure fig_pa01_290208_polygones_reguliers
figure 0014
Figure fig_pa02_290208_polygones_reguliers
figure 0015
Figure fig_po01_290208_pentagone
figure 0016
Figure fig_po02_290208_polygones_reguliers
figure 0017
Figure fig_po03_290208_polygones
figure 0018
Figure fig_po04_290208_hexagone
figure 0019
Figure fig_po05_290208_dodecagone
figure 0020
Figure fig_po06_290208_hexadecagone
figure 0021
Figure fig_qa01_290208_pentagramme
figure 0022
Figure fig_qa02_290208_decagramme
figure 0023
Asymptote - Figure 0001: fig_aa01_150208_quadrilatere.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_aa01_150208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(5cm,0);

// On trace le quadrilatère. 
draw ((0,0)--(4,1)--(3.5,3)--(1,4)--cycle);
Asymptote - Figure 0002: fig_aa02_150208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa02_150208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);

// On définit les sommets du quadrilatère.
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);

// On trace le quadrilatère.
draw (A--B--C--D--cycle);
Asymptote - Figure 0003: fig_aa03_290208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa03_290208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);

// On définit les sommets du quadrilatère...
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);
// et le "chemin" définissant le quadrilatère.
path quadri=A--B--C--D--cycle;

// On trace le quadrilatère...
draw(quadri,linewidth(.8bp));
// et on place un point à chaque sommet
dot(quadri,4bp+blue);
Asymptote - Figure 0004: fig_aa04_290208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa04_290208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);

// On définit les sommets du quadrilatère...
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);
// et le "chemin" définissant le quadrilatère.
path quadri=A--B--C--D--cycle;

// On trace le quadrilatère...
draw(quadri,dashed+.8bp+orange);
// et on place un point à chaque sommet
dot(quadri,6bp+.6red);
Asymptote - Figure 0005: fig_ab01_150208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ab01_150208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);

// On définit les sommets du quadrilatère.
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);

// On trace le quadrilatère.
fill(A--B--C--D--cycle,green);
Asymptote - Figure 0006: fig_ab02_290208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ab02_290208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);

// On définit les sommets du quadrilatère.
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);

// On trace le quadrilatère de deux couleurs.
filldraw(A--B--C--D--cycle,lightgreen,2bp+.8blue);
Asymptote - Figure 0007: fig_ab03_120308_quadrilatere_hachure.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ab03_120308_quadrilatere_hachure 
import patterns; // extension pour les hachures
size(6cm,0);

// On définit un stylo que l'on utilisera pour les côtés.
pen p=1.5bp+.9blue;

// On définit les sommets du quadrilatère.
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);

// On trace le quadrilatère ABCD 
// en utilisant le stylo p pour les côtés
// et en coloriant l'intérieur en gris clair.
filldraw(A--B--C--D--cycle,lightgray,p);

// On définiti un style de hachures...
add("hachures",hatch(H=3mm,dir=SE,blue));
// ... et on hachure le triangle ABC
// en utilisant le même stylo p pour ses côtés.
filldraw(A--B--C--cycle,pattern("hachures"),p);
Asymptote - Figure 0008: fig_ac01_290208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ac01_290208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);
// On définit les sommets...
pair A=(0,0), B=(4,1), C=(3.5,2), D=(1,2.5);
// On trace le quadrilatère ...
draw(A--B--C--D--cycle);
// et on "étiquette" les sommets suivant la direction
// des bissectrices des angles aux sommets.
dot("$A$",A,dir(D--A,B--A));  
dot("$B$",B,dir(C--B,A--B));  
dot("$C$",C,dir(B--C,D--C));
dot("$D$",D,dir(A--D,C--D));
Asymptote - Figure 0009: fig_ac02_290208_quadrilatere.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ac02_290208_quadrilatere 
// On définit la largeur de l'image ;
// la hauteur va s'adapter pour garder les proportions.
size(6cm,0);
// On définit les sommets...
pair pA=(0,0), pB=(4,1), 
    pC=(3.5,2), pD=(1,2.5);
// On trace le quadrilatère ...
draw(pA--pB--pC--pD--cycle);
// et on "étiquette" deux sommets
label("$A$",pA,dir(pD--pA,pB--pA));  
label("$C$",pC,dir(pB--pC,pD--pC));
// et placement d'un point pour les deux autres.
dot(pB--pD);
Asymptote - Figure 0010: fig_ca01_080209_carre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca01_080209_carre 
unitsize(1cm); 

// Construction du centre du repère
dot(Label,(0,0),SW);

// Un carré de côté 1 
draw(unitsquare,red); 

// un autre décalé de deux horizontalement
draw(shift(2,0)*unitsquare,blue); 

// Ajout d'un cadre blanc, distant des bords de l'image de 5mm
shipout(bbox(5mm,white));
Asymptote - Figure 0011: fig_ca02_080209_carre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca02_080209_carre 
unitsize(1cm); 

// Construction du centre du repère
dot(Label,(0,0),SW);

// Un carré de côté 5 
path carre=scale(5)*unitsquare;
draw(carre); 

// Ajout d'un cadre blanc, distant des bords de l'image de 5mm
shipout(bbox(5mm,white));
Asymptote - Figure 0012: fig_ca03_040409_carre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca03_040409_carre 
import geometry;
unitsize(1cm); 

// Un carré défini par deux points, dans le sens direct
path carre=square((0,0),(5,-1));
draw(carre,1bp+yellow);

// Mise en évidence des deux points définissant le carré
dot((0,0)^^(5,-1));

// Fond bleu + Bordure de 5mm
shipout(bbox(5mm,Fill(paleblue)));
Asymptote - Figure 0013: fig_cc01_080209_carre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cc01_080209_carre 
// Nommer en une seule fois tous les points
// Nouveauté de la version SVN 1.62

unitsize(1cm); 
 
path carre=scale(5)*unitsquare;

draw(carre); 
dot(new Label[] {"A","B","C","D"},carre);

// Ajout d'un cadre blanc, distant des bords de l'image de 5mm
shipout(bbox(5mm,white));
Asymptote - Figure 0014: fig_pa01_290208_polygones_reguliers.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_pa01_290208_polygones_reguliers 
/* Un exemple d'emploi du type **guide** car pour tracer des polygones,
  il y a la fonction polygon utilisée dans les exemples qui suivent. */
size(6cm,0);
path polygone_regulier(int n)
{
  guide chemin;
  for (int i=1; i<=n; ++i)
    chemin=chemin--rotate((i-1)*360/n)*E;
  return chemin--cycle;
}
draw(polygone_regulier(3));
draw(shift(2.5,0)*polygone_regulier(4));
draw(shift(0,-2.5)*polygone_regulier(5));
draw(shift(2.5,-2.5)*polygone_regulier(6));
Asymptote - Figure 0015: fig_pa02_290208_polygones_reguliers.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_pa02_290208_polygones_reguliers 
/* Un exemple d'emploi du type **guide** car pour tracer des polygones,
  il y a la fonction polygon utilisée dans les exemples qui suivent. */
size(6cm,0);
path polygone_regulier(int n)
{
  guide chemin;
  for (int i=1; i<=n; ++i)
    chemin=chemin--rotate((i-1)*360/n)*E;
  return chemin--cycle;
}
draw(polygone_regulier(7));
draw(shift(2.5,0)*polygone_regulier(8));
draw(shift(0,-2.5)*polygone_regulier(9));
draw(shift(2.5,-2.5)*polygone_regulier(10));
Asymptote - Figure 0016: fig_po01_290208_pentagone.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po01_290208_pentagone 
size(6cm);
draw(polygon(5)); 
// 5 pour un pentagone régulier... 
// n pour un polygone régulier à n côtés
Asymptote - Figure 0017: fig_po02_290208_polygones_reguliers.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po02_290208_polygones_reguliers 
size(7.5cm);
transform Tx=shift(2.25,0), T;
for (int i=3; i <= 5; ++i) {
  draw(T*polygon(i));
  draw(shift(0,-2.25)*T*polygon(i+3));
  T *= Tx;
}
Asymptote - Figure 0018: fig_po03_290208_polygones.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po03_290208_polygones 
size(7.5cm);
transform Tx=shift(2.25,0), T;
for (int i=3; i <= 5; ++i) {
  draw(T*cross(i,round=false,r=0.5));
  draw(shift(0,-2.25)
       *T*cross(i+3,round=false,r=0.5));
  T *= Tx;
}
Asymptote - Figure 0019: fig_po04_290208_hexagone.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po04_290208_hexagone 
size(6cm);
path p=polygon(6);  
path triangle=point(p,1)--point(p,3)
              --point(p,5)--cycle;
draw(p,1.5bp+blue);
draw(triangle,1bp+red+dashed);
Asymptote - Figure 0020: fig_po05_290208_dodecagone.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po05_290208_dodecagone 
size(6cm);
path p=polygon(12);  
guide chemin;
for (int i=1; i<=12; ++i)
    chemin=chemin--point(p,5*i);
path etoile=chemin--cycle;
draw(p,1.5bp+blue);
draw(etoile,1bp+green);
Asymptote - Figure 0021: fig_po06_290208_hexadecagone.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_po06_290208_hexadecagone 
size(6cm);
path p=polygon(16);  
path c=scale(.9)*cross(16,round=true,r=0.5);  
filldraw(p,fillpen=red,
           drawpen=linewidth(1mm)+orange);
draw(c,1bp+orange);
Asymptote - Figure 0022: fig_qa01_290208_pentagramme.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_qa01_290208_pentagramme 
size(6cm);
guide chemin;
for (int i=1; i<=5; ++i)
    chemin=chemin--point(polygon(5),2*i);
path pentagramme=chemin--cycle;
draw(pentagramme,1bp+.5green);
Asymptote - Figure 0023: fig_qa02_290208_decagramme.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_qa02_290208_decagramme 
size(6cm);
guide chemin;
for (int i=1; i<=10; ++i)
    chemin=chemin--point(polygon(10),3*i);
path decagramme=chemin--cycle;
draw(decagramme,1bp+.5blue);
Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE

Dernière modification le Fri Oct 28 12:59:56 CEST 2011 par G.Marris       Valide XHTML