OmitTick avec graph3

[etienne25]

Bonjour,

Je souhaite enlever des graduations sur un axe 3D. En 2D, il y a OmitTick qu'on peut utiliser quand on spécifie les graduations dans la commande xaxis. Mais on dirait qu'on ne peut pas faire de même dans xaxis3.

1) Est-ce bien le cas?

2) Si non, un exemple svp!

3) Si oui, y a-t-il moyen de lister les graduations qu'on souhaite voir (si je ne peux décider quoi enlever, puis-je décider plutôt quoi mettre )

Merci à l'avance!

[etienne25]

J'ai Asymptote 2.21

[GM]

Bonjour,

as-tu essayé ton idée ?

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import grid3; 
 
size3(150,IgnoreAspect);
 
limits((0,0,0),(10,10,6));
currentprojection=perspective(camera=(20,16,7),target=(5,5,3));
viewportmargin=(10mm,10mm);
 
grid3(XYZgrid,Step=5,step=1);
 
xaxis3(Label("$x$",MidPoint,align=Y-Z),
       Bounds(Both,Min),OutTicks(OmitTick(2,8)),p=blue); 
yaxis3(Label("$y$",MidPoint,align=X-Z),
       Bounds(Both,Min),OutTicks(endlabel=false),p=red); 
zaxis3(Label("$z$",MidPoint,align=X-Y),
       Bounds(Both,Min),InTicks(),p=1bp+.5green);

[etienne25]

Pas encore, la commande OutTicks me cause encore des soucis. Voici la commande qui génère l'axe que je veux produire:

Code : Tout sélectionner

size(4.8cm);
import solids;
currentprojection=orthographic(1,1,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
	0,13,
	OutTicks(Label(fontsize(6)),NoZero,Step=5,step=1),
	Arrow3(8bp));

J'aimerais retirer les graduations pour 12 et 13.

Lorsque j'ajoute le OmitTick dans le OutTicks, le code ne compile plus. J'essaie de changer l'ordre des paramètres dans OutTick, en vain. Et je ne trouve pas dans la doc officielle d'Asymptote la synthaxe complète de OutTicks (est-ce que ça se trouve qqpart??). Des suggestions? Merci à l'avance!!!

[maurice]

Bonjour, à la place du NoZero :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(4.8cm);
import solids;
currentprojection=orthographic(1,1,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
   0,15,
   OutTicks(Label(fontsize(6)),OmitTick(0,12,13),Step=1,step=0, end=false, endlabel=false),
   Arrow3(8bp));

Par contre, j'ai du "alonger" l'axe jusqu'à 15 ; sinon :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(4.8cm);
import solids;
currentprojection=orthographic(1,1,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
   0,13,
   OutTicks(Label(fontsize(6)),OmitTick(12,13),Step=1,step=0),
   Arrow3(8bp));

J'ai aussi changer les valeurs de Step et step.

Peut-être existe-t-il une solution plus élégante ?

Bruno

[GM]

Bonjour,

Plutôt que cela

Code : Tout sélectionner

end=false, endlabel=false

,
il suffit d'ajouter la valeur que l'on veut masquer dans OmitTick.

[GM]

Et si on commence à vouloir des graduations pour tous les entiers et que seules quelques étiquettes manquent, il va falloir deux commandes xaxis3 pour gérer séparément axe+graduations d'une part et étiquettes d'autre part.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(300);
import solids;
currentprojection=orthographic(1,2,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
       -1,16,
       red,
       OutTicks("%",end=false,Step=1),
       Arrow3(8bp));
xaxis3(-1,16,
       nullpen,
       OutTicks(Label(fontsize(6)),OmitTickInterval(9,13),endlabel=false,Step=1));

Au passage, je rappelle l'existence de OmitTickInterval.
Mais on peut en rester à OmitTick pour cet exemple simple.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(300);
import solids;
currentprojection=orthographic(1,2,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
       -1,16,
       red,
       OutTicks("%",end=false,Step=1),
       Arrow3(8bp));
xaxis3(-1,16,
       nullpen,
       OutTicks(Label(fontsize(6)),OmitTick(-1,0,12,13,16),Step=1));

[etienne25]

Ah excellent!! C'est effectivement un "conflit" entre OmitTick et NoZero. J'arrive maintenant à faire exactement ce que je veux.

Par curiosité, je reviens à mon idée 3) au début de cette discussion: comment ferait-on pour produire un axe avec une liste de graduations fournies dans une liste? Autrement dit, comment faire qqchose comme ci-dessous, mais en 3D. J'ai fait quelques essais, sans succès.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
unitsize(1cm);
xaxis(axis=YEquals(-2),
      Label("$x_2$",align=N),
      xmin=-1,xmax=3,blue,
      Ticks("%", 
            new real[]{0,1,sqrt(2)},Size=1mm,1bp+red),
      Arrow);

[GM]

J'ai fait quelques essais, sans succès.

Il faut bien lire les messages d'erreur pour comprendre... et chercher dans l'index, pour savoir quels paramètres sont attendus.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(300);
import solids;
currentprojection=orthographic(1,2,1);
xaxis3(Label("$x$",position=EndPoint,align=W,fontsize(8)),
       -1,16,
       red,
       OutTicks("%",new real[]{2,3,5,6,8,9,11.33}),
       Arrow3(8bp));
xaxis3(-1,16,
       nullpen,
       OutTicks(Label(fontsize(6)),new real[]{3,5,8,11.33}));

[etienne25]

Ah, j'avais fait qqchose de semblable, mais en mettant le tableau directement dans le OutTick, sans le "new"

Je viens de découvrir à l'instant l'index. Il faut que j'apprenne comment lire ces syntaxes générales de commandes. Et plus généralement, il me faut améliorer mes bases "théoriques" sur Asymptote. Je bloque souvent sur des détails par manque de compréhension... Par exemple, le rôle du "new" n'est pas tout à fait clair dans mon esprit, je le rencontre souvent dans les exemples que je trouve, mais disons que les présentations n'ont pas été faites entre lui et moi!

Merci encore pour l'aide apportée!