Bizarrerie à la sortie de l'impression.

[Fabrice]

Bonsoir,
Je ne pense pas que le problème est lié à Asymptote, mais comme la figure a été construite avec, je pose ma question sur ce forum.
Le code est le suivant :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
usepackage("mathrsfs,esvect,fourier");
arrowhead guillaumetellHead=HookHead(dir=10); 
guillaumetellHead.size=new real(pen p)
{
  static real hcoef=5;
  return hcoef*arrowtexfactor*linewidth(p);
};
arrowbar guillaumetell=Arrow(guillaumetellHead);
unitsize(1cm,1cm);
real f (real x){return exp(x);}
draw(graph(f,-4,5),0.8bp+black);
xlimits(-5,5,Crop);
ylimits(-1,4,Crop);
pen ptick=gray(0.9);
pen pTick=gray(0.7);
pen p=fontsize(9pt);
xequals(0,-1,4,0.8bp+black);
yequals(0,-5,5,0.8bp+black);
draw((0,0)--(1,0),linewidth(1.1bp),guillaumetell);
draw((0,0)--(0,1),linewidth(1.1bp),guillaumetell);
labelx("$O$",-0.2);
label("$y=e^{x}$",(-2.5,f(-2.5)),2N);
label("$\vv{i}$",(0.5,0),1.1*S);
label("$\vv{j}$",(0,0.5),1.1*W);

Si j'imprime le document,j'obtiens une figure qui ressemble à peu de chose près à la suivante

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
usepackage("mathrsfs,esvect,fourier");
arrowhead guillaumetellHead=HookHead(dir=10);
guillaumetellHead.size=new real(pen p)
{
  static real hcoef=5;
  return hcoef*arrowtexfactor*linewidth(p);
};
arrowbar guillaumetell=Arrow(guillaumetellHead);
unitsize(1cm,1cm);
real f (real x){return exp(x);}
draw(graph(f,-4,5),0.8bp+black);
 
draw((-4,f(-4))--(-4,f(log(4)))--(log(4),f(log(4)))); // Ligne ajoutée pour simuler le problème rencontré
 
xlimits(-5,5,Crop);
ylimits(-1,4,Crop);
pen ptick=gray(0.9);
pen pTick=gray(0.7);
pen p=fontsize(9pt);
xequals(0,-1,4,0.8bp+black);
yequals(0,-5,5,0.8bp+black);
draw((0,0)--(1,0),linewidth(1.1bp),guillaumetell);
draw((0,0)--(0,1),linewidth(1.1bp),guillaumetell);
labelx("$O$",-0.2);
label("$y=e^{x}$",(-2.5,f(-2.5)),2N);
label("$\vv{i}$",(0.5,0),1.1*S);
label("$\vv{j}$",(0,0.5),1.1*W);

Merci.

[GM]

Si j'imprime le document,j'obtiens une figure qui ressemble à peu de chose près à la suivante

J'ai déjà eu le problème aussi avec une figure l'année dernière... et je suis resté aussi perplexe que toi. Et j'ai zappé....

[chellier]

Bonsoir,

J'ai aussi eu le problème. Je l'ai résolu en changeant de lecteur pdf... mais je suis sous linux, à voir sous windows.

Christophe

[maurice]

Bonsoir, j'ai eu quelquefois des soucis d'impression de ce type mais jamais avec l'imprimante installée par défaut sur mon ordi personnel.
Souvent au lycée avec des pdf à imprimer qui se trouvaient sur clé usb.
Autre problème récurrent (toujours au lycée), les grilles ne sont pas imprimées.
J'en avais conclu que les ordinateurs utilisés n'avait pas tous les drivers installés ou des choses dans ce style ...?
Du coup, j'imprime chez moi ou j'emmène mon portable au lycée (ça marche dans ce cas).

Maurice

[Fabrice]

Bonjour,
J'ai zappé également !

[GM]

Si j'imprime le document,j'obtiens une figure qui ressemble à peu de chose près à la suivante

J'ai déjà eu le problème aussi avec une figure l'année dernière... et je suis resté aussi perplexe que toi. Et j'ai zappé....

L'exemple donné par Fabrice a ce problème chez moi (sous W7) avec AdobeReaderX mais pas avec Sumatra.

Il est vrai qu'il faudrait peut-être remonter l'information... pour avoir une petite chance qu'il se règle... sous réserve que le problème soit effectivement du côté d'Asymptote, et que JCBowman retrouve un peu de disponibilité pour répondre à nos difficultés.

[GM]

Il est vrai qu'il faudrait peut-être remonter l'information... pour avoir une petite chance qu'il se règle... sous réserve que le problème soit effectivement du côté d'Asymptote, et que JCBowman retrouve un peu de disponibilité pour répondre à nos difficultés.

En attendant, une solution :

Code : Tout sélectionner

import graph;
usepackage("mathrsfs,esvect,fourier");
arrowhead guillaumetellHead=HookHead(dir=10);
guillaumetellHead.size=new real(pen p)
{
  static real hcoef=5;
  return hcoef*arrowtexfactor*linewidth(p);
};
arrowbar guillaumetell=Arrow(guillaumetellHead);
unitsize(1cm,1cm);
real f (real x){return exp(x);}

real xmin=-4, xmax=5, ymin= -1, ymax=4;
bool3 cond(real x) { return ((f(x)>ymin)&&(f(x)<ymax)) ? true : false; }
draw(graph(f,xmin,xmax,cond),0.8bp+black);
pen ptick=gray(0.9);
pen pTick=gray(0.7);
pen p=fontsize(9pt);
xequals(0,-1,4,0.8bp+black);
yequals(0,-5,5,0.8bp+black);
draw((0,0)--(1,0),linewidth(1.1bp),guillaumetell);
draw((0,0)--(0,1),linewidth(1.1bp),guillaumetell);
labelx("$O$",-0.2);
label("$y=e^{x}$",(-2.5,f(-2.5)),2N);
label("$\vv{i}$",(0.5,0),1.1*S);
label("$\vv{j}$",(0,0.5),1.1*W);

[maurice]

Bonsoir,

du coup j'ai regardé la définition de graph :

Code : Tout sélectionner

guide[] graph(picture pic=currentpicture, real f(real), real a, real b,
int n=ngraph, real T(real)=identity, bool3 cond(real),
interpolate join=operator --);

La doc dit :

Returns a graph using the scaling information for picture pic of the function f on the interval [T(a),T(b)], sampling at n points evenly
spaced in [a,b], optionally restricted by the bool3 function cond on [a,b]. If cond is:
• true, the point is added to the existing guide;
• default, the point is added to a new guide;
• false, the point is omitted and a new guide is begun.

Si j'ai bien compris, la valeur de cond passe de default à true si et de default à false sinon et cela résoud le problème ... ?

Peux tu éclairer ma lanterne sur les différentes options "added to the existing guide", "added to a new guide" et " a new guide is begun".

Merci

Bruno

[GM]

Quand le booléen trois-état renvoie false le pair n'est pas ajouté au guide courant, ni à un nouveau guide !
Et le pair suivant, sous réserve qu'il satisfasse la condition du booléen, sera le premier pair d'un nouveau guide.

Un exemple : ceci est le tracé des courbes représentatives des fonctions et sur l'intervalle ,
limitées à la bande de plan d'inéquations par un appel spécial de la fonction graph, avec un paramètre de type bool3.

Le nombre de points définissant les path/guide a été choisis pour n'avoir que des pairs d'abscisse entière et faciliter la compréhension de ce qui s'affiche en console.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(300,IgnoreAspect);
import graph;
real f (real x){return x^2;}
real g (real x){return 100-x^2;}
int xmin=-15, xmax=15, ymin= -50, ymax=50;
bool3 condf(real x) { return ((f(x)>ymin)&&(f(x)<ymax)) ? true : false; }
bool3 condg(real x) { return ((g(x)>ymin)&&(g(x)<ymax)) ? true : false; }
guide[] Cf=graph(f,xmin,xmax,n=xmax-xmin,condf),
        Cg=graph(g,xmin,xmax,n=xmax-xmin,condg);
draw(Cf,blue,dot());
draw(Cg,red,dot());
xaxis(xmin=xmin,xmax=xmax,Ticks(Step=5));
yaxis(ymin=ymin,ymax=ymax,Ticks(Step=10));
write("Cf=",Cf);
write('\n'+"Cg=",Cg);

Cela donne cela en console :

Cf=(-7,49)
{curl 1}..{curl 1}(-6,36)
{curl 1}..{curl 1}(-5,25)
{curl 1}..{curl 1}(-4,16)
{curl 1}..{curl 1}(-3,9)
{curl 1}..{curl 1}(-2,4)
{curl 1}..{curl 1}(-1,1)
{curl 1}..{curl 1}(0,0)
{curl 1}..{curl 1}(1,1)
{curl 1}..{curl 1}(2,4)
{curl 1}..{curl 1}(3,9)
{curl 1}..{curl 1}(4,16)
{curl 1}..{curl 1}(5,25)
{curl 1}..{curl 1}(6,36)
{curl 1}..{curl 1}(7,49)

Cg=(-12,-44)
{curl 1}..{curl 1}(-11,-21)
{curl 1}..{curl 1}(-10,0)
{curl 1}..{curl 1}(-9,19)
{curl 1}..{curl 1}(-8,36)
^^(8,36)
{curl 1}..{curl 1}(9,19)
{curl 1}..{curl 1}(10,0)
{curl 1}..{curl 1}(11,-21)
{curl 1}..{curl 1}(12,-44)

Dans le premier cas, on a un guide[] de longueur 1.
Dans le second cas, on a un guide[] de longueur 2.

[GM]

J'ai oublié de dire que :

• les fonctions choisies ci-dessus n'ont pas de valeurs interdites, donc il suffirait de deux états pour le booléen : un pair qui ne satisfait pas la condition n'est simplement pas tracé... et le premier pair qui suit et qui satisfait la condition débute nécessairement un nouveau guide ;
  
• l'intérêt d'un booléen trois états est pour moi dans le tracé de la courbe d'une fonction ayant une valeur interdite, car il faut alors pouvoir écrire une condition de test fonctionnant ainsi :
  
  • si l'état est true, le pair testé est ajouté au guide courant ;
  • si l'état est default, le pair testé est le premier pair d'un nouveau guide qui devient le guide courant ;
  • si l'état est false, le pair testé n'est à ajouter à aucun guide et le prochain pair qui vérifiera la condition débutera un nouveau guide.

J'espère que j'ai été clair.