ASY-Forum

Un bout du paraboloïde hyperbolique d'équation z=xy

Figure asymptote 57515ae4a5c8eb4c6ee0cf3e505e3139
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

 
import graph3;
import grid3;
import contour;
size(10cm,IgnoreAspect);
real f(pair z) {
  return z.x*z.y;
}
real[] lignesniveaux={25,50,75,100,125};
currentprojection=orthographic(-15,-25,200);
limits((0,0,0),(12,12,150));
grid3(new grid3routines [] {XYXgrid, ZXgrid(12), ZYgrid(12)},
      Step=50,
      step=25,
      pGrid=new pen[] {red, blue, blue},
      pgrid=new pen[] {0.5red, orange, orange});
xaxis3(Label("$x$",position=MidPoint,align=SE),
       Bounds(Min,Min),
       OutTicks(Step=2));
yaxis3(Label("$y$",position=MidPoint,align=SW),
       Bounds(Min,Min),
       OutTicks(Step=2));
zaxis3(Bounds(Max,Both));
zaxis3(Label("$z=xy$",position=EndPoint,align=3N+E),
       XYEquals(0,12),
       OutTicks(beginlabel=false,Step=50,step=25,Label(align=Y)));
draw(surface(f,(0,0),(12,12),nx=12,Spline),
     lightgray+white,meshpen=black+thick(),nolight);
Label [] L=sequence(new Label(int i) {
    return scale(0.9)*Label(format("$z=%g$",lignesniveaux[i]),
                            align=NW,BeginPoint);
  },5);
draw(L,lift(f,contour(f,(0,0),(12,12),lignesniveaux)),1.5bp+.7red);