Import graph_pi et problèmes avec la 3D

[jmbdeblois]

OK, je vois maintenant à quoi cela correspond.
La première image m'intéressait car en la travaillant, ça peut ressembler à un infini !

[GM]

car en la travaillant, ça peut ressembler à un infini !

Si cela peut t'intéresser :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import three;
size(200);
 
currentprojection=perspective(100,100,200,up=Y);
currentlight=Headlamp;
 
draw(scale3(4)*extrude("$\infty$",3Z),orange);

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import three;
size(200);
 
currentprojection=perspective(-100,100,200,up=Y);
currentlight=Viewport;
 
draw(scale3(6)*extrude("$\infty$",2Z),.5green);

[jmbdeblois]

Excellent !!!
J'achète...!
Pour l'intégrer sur mon site...

[GM]

Excellent !!!

La galerie officielle sur le site de Philippe te donne cet exemple là :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import three;
 
currentprojection=perspective(100,100,200,up=Y);
currentlight=Headlamp;
 
draw(scale3(4)*extrude("$\displaystyle\int_{-\infty}^{+\infty}
e^{-\alpha x^2}\,dx=\sqrt{\frac{\pi}{\alpha}}$",2Z),blue);
 

Un autre pour la route que l'on trouve ici :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph3; 
size(7.5cm,0); 
 
currentprojection=perspective(100,100,50); 
 
draw(rotate(90,X)*extrude("ABC",Z),orange); 
 
limits(O,15X+10Y+7Z);
xaxis3(Label("$x$",1),blue,arrow=Arrow3);
yaxis3(Label("$y$",1),blue,arrow=Arrow3);
zaxis3(Label("$z$",1),blue,arrow=Arrow3);

Je crois que l'on s'est un peu écarté du sujet.

[jmbdeblois]

Oui on s'écarte mais on reste dans les maths !
Je vais me faire : \sum_1^{+\infty} {\frac{1}{n^2} = \frac{\pi^2}{6} !!

[GM]

Je vais me faire : \sum_1^{+\infty} {\frac{1}{n^2} = \frac{\pi^2}{6} !!

J'ose alors te proposer cela :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph_pi;
import patterns;
usepackage("mathrsfs");
usepackage("icomma");
 
size(250,0);
 
graphicrules(xunit=1cm, yunit=8cm,
             xmin=-1, xmax=8,
             ymin=-.2, ymax=1.2,
             crop=Crop
             );
// Définition et tracé de la grille
grid(xStep=1, xstep=.5,
     yStep=.2, ystep=.1,
     pTick=.7bp+.7white, 
     ptick=.7bp+dotted+.7white,
     above=false
     );
// Définition et tracé des axes
cartesianaxis(
    xticks=Ticks(Label(NoFill),
                 Step=1, step=.5,
                 NoZero,
                                 ptick=grey),
    yticks=Ticks(Label(NoFill),
                 Step=.2, step=.1,
                 NoZero,
                 ptick=grey),
    Arrow
    );
// Définition de la fonction
real f(real x) {return 1/x^2;}
 
// Les rectangles
int a=1, b=8;
for(int i=a; i <= b; ++i) {
  if(i < b) filldraw(box((i,f(i)),(i+1,0)),lightgray);
  dot((i,f(i)));
} 
// Les hachures.
path zonehachuree=buildcycle((8,1)--(8,0)--(1,0)--(1,1),graph(f,1,8));
add("hachure",hatch(H=3mm,dir=NE,red));
fill(zonehachuree,pattern("hachure"));
 
// Tracé de courbe
path Cf=graph(f,.5,8,n=400);
draw(Cf,linewidth(1bp)+blue);
xlimits(-1.5,8.5,Crop);
ylimits(-.3,1.3,Crop);
label("$\mathscr{C}_f : y=\displaystyle\frac{1}{x^2}$",(1,f(1)),NE);  
 
labeloij(p=1.4bp+.5*red,
         arrow=Arrow(SimpleHead,8bp),
         dot
         );
 
arrow("$\displaystyle\int_{1}^{+\infty}\left(\frac{1}{x^2}\right)$d$x=1$",
          (3.5,0.05),NE,1.5cm,red,Margin(0,0.5));
arrow("$\displaystyle\sum_{k=1}^{+\infty}\left(\frac{1}{k^2}\right)
           =\frac{\pi^2}{6}$",(1.5,0.8),E,1.5cm,blue,Margin(0,0.5));

[jmbdeblois]

Je l'ai déjà récupérée pour l'intégrer dans mon cours sur le lien entre intégrales généralisées et séries !
D'ailleurs il y a une petite faute : pas de dx pour la série.

[GM]

Je l'ai déjà récupérée pour l'intégrer dans mon cours sur le lien entre intégrales généralisées et séries !

Tâche de bien le faire... ma fille ne rentre qu'en première S mais dans 2 ans, je risque d'être en quête de cours de prépa.

D'ailleurs il y a une petite faute : pas de dx pour la série.

Ahhh, depuis le temps que l'exemple est en ligne... personne ne m'a signalé l'erreur de copier-coller.
Je vais aller le modifier de suite... (sous réserve que mon problème d'adresse temporairement indisponible ne m'empêche de synchroniser la galerie).

[GM]

Je vais aller le modifier de suite... (sous réserve que mon problème d'adresse temporairement indisponible ne m'empêche de synchroniser la galerie).

C'est fait.
J'en ai profité pour mettre un d droit aussi.

Autre remarque par rapport à l'exemple :

je n'aime pas les pointillés (problème de régularité des points... qui, s'ils était convenablement espacés, permettraient de lire les dixièmes)
et il y a des suggestions dans les exemples de cette page pour obtenir des points espacés d'un 1mm.
Il peut être utile d'avoir un fichier de commandes personnelles que l'on charge avec import... dans lequel on pourra trouver notamment :

Code : Tout sélectionner

pen monjolistyledepointilles=linetype("0 " + string(1mm), offset=0, scale=false, adjust=false);

pour utiliser monjolistyledepointilles plutôt que dotted, sans devoir le redéfinir à chaque fois.

[jmbdeblois]

Oui, bonne remarque sur les pointillés.
De même pour les hachures, les miennes sont bien moins belles que sur ton dessin ! Elles sont toutes crénelées.