triangleABc

[Francky]

Dans l'extension geometry,
j'ai bien trouvé triangleabc, et triangleAbc,
mais rien concernant un hypothétique triangleABc.

L'objet étant de construire un triangle connaissant une longueur et deux angles.

Je vous propose cela,

Code : Tout sélectionner

import geometry;
import markers;
import math;
size(9cm);
add(grid(9,5,lightgray));
point B=(1,1);
point C=B+(7,0);
point A=B+(7*cos(radians(53))*cos(radians(53)),7*cos(radians(53))*sin(radians(53)));
triangle T;
T.init(A,B,C);
show(LA="",LB="",LC="",La="7 cm",Lb="",Lc="",T,1bp+black);
markangle("$37^\circ$",1,radius=1cm,T.A,T.C,T.B);
markangle("$53^\circ$",2,radius=.7cm,T.C,T.B,T.A);
line BA=line(B, false, A);
line CA=line(C, false, A);
line BC=line(B, C);
draw(BA,dashed+.4bp);
draw(CA,dashed+.4bp);
draw(BC,dashed+.4bp);
marker croix=marker(scale(3)*cross(4),1bp+black);
draw("$C$",C,NE,croix);
draw("$B$",B,NW,croix);
marker croix=marker(scale(3)*rotate(45)*cross(4),1bp+black);
draw("$A$",A,2*N,croix);

fig-solution.pdf

la figure en pdf

(7.08 Kio) Téléchargé 344 fois

Mais si vous avez mieux, je suis preneur.

Merci.

[GM]

Cela me semble plus naturel ainsi :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
import markers;
import math;
size(200);
add(grid(9,5,lightgray));
point B=(1,1), 
        C=B+(7,0);
line BC=line(B, C),
      BA=line(B, false, rotate(53,B)*C),
      CA=line(C, false, rotate(-37,C)*B);
point A=intersectionpoint(BA,CA);
triangle T=triangle(A,B,C);
show(LA="",LB="",LC="",La="7 cm",Lb="",Lc="",T,1bp+black);
markangle("$37^\circ$",1,radius=1cm,T.A,T.C,T.B);
markangle("$53^\circ$",2,radius=.7cm,T.C,T.B,T.A);
draw(BA,dashed+.4bp);
draw(CA,dashed+.4bp);
draw(BC,dashed+.4bp);
marker croix=marker(scale(3)*cross(4),1bp+black);
draw("$C$",C,NE,croix);
draw("$B$",B,NW,croix);
marker croix=marker(scale(3)*rotate(45)*cross(4),1bp+black);
draw("$A$",A,2*N,croix);