3 graphiques cote à cote

Pour toute demande d'aide sur des exemples non finalisés, c'est ici.
Les exemples aboutis et intéressants seront ajoutés aux sous-forums qui suivent.

Règles du forum
Pour toute demande d'aide pour la conception (ou la confirmation d'un code) d'une figure Asymptote, c'est ici.

J'invite ceux qui ont régulièrement des questions à poser à aller dans leur panneau de l'utilisateur pour indiquer dans la signature de leurs messages :

  1. Nom du système d'exploitation (W7 ou Ubuntu 12.04 ou ...)
  2. Version d'Asymptote et éditeur utilisé pour les figures Asymptote
  3. Distribution LaTeX et éditeur utilisé pour les tex.


On va gagner du temps dans les réponses !
Nico56
Messages : 52
Enregistré le : lun. 12 janv. 2015, 16:06

3 graphiques cote à cote

Message non lu par Nico56 » jeu. 14 avr. 2016, 08:16

Bonjour, je voudrais tracer 3 graphiques cote à cote (3 propositions de dérivées pour une fonction) directement dans une seule figure asymptote (donc sans en faire 3 puis les mettre cote à cote dans mon document latex).
Est-ce possible? Si oui quelle procédure pour faire ça? J'ai regardé les exemples des diagrammes ensemblistes, j'y ai trouvé des idées mais sans succès (avec picture, clip...).
Merci d'avance!
Nico
Windows 10 - Asymptote(2.32)+texlive - Editeur: texmaker (4.5)

Avatar du membre
GM
Administrateur du site
Administrateur du site
Messages : 1328
Enregistré le : dim. 7 mars 2010, 14:50

Re: 3 graphiques cote à cote

Message non lu par GM » jeu. 14 avr. 2016, 10:02

Bonjour,

quelque chose comme cela ?

Figure asymptote c5ca4471fdb4158afc06b5f6d0180bfe
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
  1. import graph;
  2.  
  3. real margin=4mm;
  4. real unite=8mm;
  5.  
  6. transform h=scale(.7);
  7.  
  8. picture pic1;
  9. real xmin=-3,xmax=3;
  10. real ymin=0,ymax=9;
  11. real f(real x) {return x^2;}
  12. path Cf=graph(f,xmin,xmax,n=100);
  13. draw(pic1,Cf,1bp+red);
  14. xaxis(pic1,Label("$x$",position=EndPoint, align=NE),xmax=xmax+.4,
  15. Ticks(h*Label(),Size=.8mm, size=.4mm),Arrow());
  16. yaxis(pic1,Label("$y$",position=EndPoint, align=NE),ymin,ymax=ymax+.4,
  17. Ticks(h*Label(),NoZero,Size=.8mm, size=.4mm),Arrow());
  18. label(pic1,"\fbox{$f_1$}",(1,8));
  19. unitsize(pic1,unite);
  20. frame f1=pic1.fit();
  21. add(f1);
  22.  
  23. picture pic2;
  24. real xmin=-1.6,xmax=3.5;
  25. real ymin=-1,ymax=4.5;
  26. real f(real x) {return (x^3-3x^2-x+2)/3;}
  27. path Cf=graph(f,xmin,xmax,n=100);
  28. draw(pic2,Cf,1bp+blue);
  29. xaxis(pic2,Label("$x$",position=EndPoint, align=NE),xmax=xmax+.4,
  30. Ticks(h*Label(),NoZero,Size=.8mm, size=.4mm));
  31. yaxis(pic2,Label("$y$",position=EndPoint, align=NE),
  32. Ticks(h*Label(),NoZero,Size=.8mm, size=.4mm));
  33. label(pic2,"\fbox{$f_2$}",(2,3));
  34. unitsize(pic2,unite);
  35. frame f2=pic2.fit();
  36. f2=shift(max(f1).x-min(f2).x+margin)*f2;
  37. add(f2);
  38.  
  39. picture pic3;
  40. real xmin=-4.5,xmax=1.5;
  41. real ymin=-.5,ymax=4.5;
  42. real f(real x) {return exp(x);}
  43. path Cf=graph(f,xmin,xmax,n=100);
  44. draw(pic3,Cf,1bp+green);
  45. xaxis(pic3,Label("$x$",position=EndPoint, align=NE),xmax=xmax+.4,
  46. Ticks(h*Label(),Size=.8mm, size=.4mm));
  47. yaxis(pic3,Label("$y$",position=EndPoint, align=NE),
  48. Ticks(h*Label(),NoZero,Size=.8mm, size=.4mm));
  49. label(pic3,"\fbox{$f_3$}",(2,3));
  50. unitsize(pic3,unite);
  51. frame f3=pic3.fit();
  52. f3=shift(max(f2).x-min(f3).x+margin)*f3;
  53. add(f3);
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' : http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 10/10/17) :
PC n°1 :Windows 10 - Asymptote(2.41)+MikTeX2.9 - Editeurs : Notepad++ et TeXworks.
Mes autres PC :Ubuntu 16.04LTS - Asymptote(2.42 git) + TexLive2017 - Editeur : TeXworks.
Merci de préciser la votre pour faciliter l'aide des autres !

Nico56
Messages : 52
Enregistré le : lun. 12 janv. 2015, 16:06

Re: 3 graphiques cote à cote

Message non lu par Nico56 » jeu. 14 avr. 2016, 10:08

Exactement!
Merci!
Windows 10 - Asymptote(2.32)+texlive - Editeur: texmaker (4.5)

Répondre