ASY-Forum

Bonsoir, j'ai récupéré un code sur la galerie, j'aimerai l'adapter mais je n'y arrive pas.
Beaucoup de lignes restent mystérieuse et j'ai beau chercher, je ne comprends pas...
Mon but est d'illustrer les 4 premiers termes de la suite puis u_{n-1} et u_n en faisant apparaître des pointillés entre u_3 et u_n et en faisant une grande flèche entre u_0 et u_n comme j'ai pu le faire.
J'aimerai aussi pouvoir avoir une flèche polygonale (vers le haut, puis vers la droite, puis vers le bas).
Merci d'avance pour votre aide!
Nico

Figure asymptote 236604d2741395ddc3c4a05c15325cbe
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
unitsize(0.5cm);
real u0=0, r=3;
int n=8;
object objtemp, ui[];
pair   z[];
for(int k=0; k<=n; ++k){
  z.push(u0+k*r); // je ne comprends pas cette ligne...
  objtemp = draw(Label(format("$u_%i$",k),align=N),ellipse,z[k],nullpen); // Comment est créé z[k]? 
  ui.push(objtemp); // je ne comprends pas cette ligne...
}
 
// Du "deferred drawing" pour le tracé des flèches entre les "objects".
add(new void(picture pic, transform t) {
         draw(pic,Label("$+n\times r$",align=LeftSide),
                  point(ui[0],SSE,t){SE}..{NE}point(ui[n],SSW,t),
                  Arrow);
         draw(pic,Label("$+r$",align=LeftSide),
                  point(ui[n-1],NE,t){N}..{S}point(ui[n],N,t),
                  Arrow);
     for(int k=0; k<n/2; ++k) 
         draw(pic,Label("$+r$",align=LeftSide),
                  point(ui[k],NE,t){N}..{S}point(ui[k+1],N,t),
                  Arrow);
});
xaxis(Ticks("%",Step=3,step=0,Size=1mm));

Figure asymptote 490d62b0babccbadff7a9ac5d19877a5
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
unitsize(0.5cm);
 
real u(int n){return 3*n;}
 
object objtemp, up[], ud[];
real termes[];
 
int    listeIND[][] = {{0,1,2,3,4},{5,6},{7,8,9}};
string listeLAB[]   =                    {"n-1","n","n+1"};
 
for(int k=0; k<listeIND[0].length; ++k){
  int rang=listeIND[0][k];
  termes.push(u(rang));
  objtemp = draw(Label(format("$u_{%i}$",rang),align=N),ellipse,(u(rang),0),nullpen);
  up.push(objtemp);
}
 
for(int k=0; k<listeIND[2].length; ++k){
  int rang=listeIND[2][k];
  termes.push(u(rang));
  objtemp = draw(Label("$u_{"+listeLAB[k]+"}$",align=N),ellipse,(u(rang),0),nullpen);
  ud.push(objtemp);
}
 
// Du "deferred drawing" pour le tracé des flèches entre les "objects".
add(new void(picture pic, transform t) {
     for(int k=0; k<up.length-1; ++k)
         draw(pic,Label("$+r$",align=LeftSide),
                  point(up[k],NNE,t){N}..{S}point(up[k+1],N,t),
                  Arrow);
     for(int k=0; k<ud.length-1; ++k)
         draw(pic,Label("$+r$",align=LeftSide),
                  point(ud[k],NNE,t){N}..{S}point(ud[k+1],N,t),
                  Arrow);
 
     draw(pic,Label("$+n\times r$",align=LeftSide),
              point(up[0],SSE,t){SE}..{NE}point(ud[ud.length-2],SSW,t),
              Arrow);
});
xaxis(Ticks("%",termes,Size=1mm));

Version provisoire... mais j'ai trop de boulot pour terminer l'exemple maintenant.

A noter les lignes :

Code : Tout sélectionner

real u(int n){return 3*n;}

Je définis une fonction pour le terme général de la suite (plutôt que u0 et r)... pour qu'il y ait peu de modifications à apporter, si on décide de représenter les termes d'une suite non arithmétique.

Code : Tout sélectionner

int    listeIND[][] = {{0,1,2,3,4},{5,6},{7,8,9}};
string listeLAB[]   =                    {"n-1","n","n+1"};

listeIND[0] est la liste des indices des premiers termes.
listeIND[1] ne sert à rien pour l'instant mais pour pourrait servir à préciser où créer une rupture dans l'axe des abscisses.
listeIND[2] est la liste des indices des derniers termes... qui sont remplacés à l'affichage par les valeurs de listeLAB.

Suggestion : comme je n'ai pas eu le temps de répondre aux questions du premier script... et comme il pourrait y en avoir d'autres supplémentaires sur le second, je rappelle une astuce :

Quand on ne comprend pas ce que fait une ligne comme celle ci :

Code : Tout sélectionner

z.push(u0+k*r);

on demande d'afficher en console, le contenu de la variable concernée :

Code : Tout sélectionner

write("avant : z=",z);
z.push(u0+k*r);
write("après : z=",z);

ou alors, on fait une recherche sur push dans la doc Asymptote :

Merci pour ces réponses! Je vais éplucher ça ce soir.

ASY-Forum

Illustration suite arithmétique

Illustration suite arithmétique

Re: Illustration suite arithmétique

Re: Illustration suite arithmétique

Re: Illustration suite arithmétique