Pour toute demande d'aide sur des exemples non finalisés, c'est ici.
Les exemples aboutis et intéressants seront ajoutés aux sous-forums qui suivent.
Règles du forum
Pour toute demande d'aide pour la conception (ou la confirmation d'un code) d'une figure Asymptote, c'est ici.
J'invite ceux qui ont régulièrement des questions à poser à aller dans leur panneau de l'utilisateur pour indiquer dans la signature de leurs messages :
- Nom du système d'exploitation (W7 ou Ubuntu 12.04 ou ...)
- Version d'Asymptote et éditeur utilisé pour les figures Asymptote
- Distribution LaTeX et éditeur utilisé pour les tex.
On va gagner du temps dans les réponses !
-
YoungFrog
- Messages : 14
- Enregistré le : mar. 11 sept. 2012, 15:46
Message non lu
par YoungFrog » ven. 20 déc. 2013, 18:08
Hello,
Le code suivant devrait si je ne m'abuse afficher un vecteur tangent + un vecteur normal en plusieurs points (je sais qu'il y a des exemples de ça dans les superbes docs des habitués de ce forum, mais j'aimerais comprendre pourquoi moi je me goure !). Or on peut remarquer qu'il y a comme un décalage : les vecteurs tangents sont pas toujours super super tangents, et les vecteurs normaux de même.
On pourrait croire que la formule ignoble pour les vecteurs normaux est responsable d'erreurs de calculs, mais en fait le vecteur normal me semble effectivement orthogonal au vecteur "tangent", le problème c'est que c'est ce dernier qui n'est pas vraiment tangent. Comme si le vecteur était juste attaché au mauvais endroit.
Vous voyez ? Hm... Je suis pas sûr que je suis très clair, n'hésitez pas à me le dire, et déjà merci pour votre aide.
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
import graph;
size(6cm,6cm);
real x(real t) { return t^2*cos(t); }
real y(real t) { return t^2*sin(t); }
real min = -1, max = 1;
path p = graph(x,y,min,max);
draw(p);
// vecteurs normaux (formule obtenue de manière automatisée...)
picture vf = vectorfield(new path(real t) {
real t = interp(min,max,t);
// dot((x(t),y(t)));
return (0,0)--unit(((t^2*sin(t) - 2*t*cos(t))*((t^2*cos(t) + 4*t*sin(t) - 2*cos(t))*(t^2*sin(t) - 2*t*cos(t)) - (t^2*cos(t) + 2*t*sin(t))*(t^2*sin(t) - 4*t*cos(t) - 2*sin(t)))/(abs(t^2*cos(t) + 2*t*sin(t))^2 + abs(t^2*sin(t) - 2*t*cos(t))^2)^(3/2) - (t^2*cos(t) + 4*t*sin(t) - 2*cos(t))/sqrt(abs(t^2*cos(t) + 2*t*sin(t))^2 + abs(t^2*sin(t) - 2*t*cos(t))^2), -(t^2*cos(t) + 2*t*sin(t))*((t^2*cos(t) + 4*t*sin(t) - 2*cos(t))*(t^2*sin(t) - 2*t*cos(t)) - (t^2*cos(t) + 2*t*sin(t))*(t^2*sin(t) - 4*t*cos(t) - 2*sin(t)))/(abs(t^2*cos(t) + 2*t*sin(t))^2 + abs(t^2*sin(t) - 2*t*cos(t))^2)^(3/2) - (t^2*sin(t) - 4*t*cos(t) - 2*sin(t))/sqrt(abs(t^2*cos(t) + 2*t*sin(t))^2 + abs(t^2*sin(t) - 2*t*cos(t))^2)));
},p, 10,red+opacity(0.3));
add(vf);
// vecteurs tangents
picture vf = vectorfield(new path(real t) {
real t = interp(min,max,t);
// dot((x(t),y(t)));
return (0,0)--unit((2t*cos(t)-t^2*sin(t),t^2*cos(t)+2t*sin(t)));
},p, 10,red+opacity(0.3));
add(vf);
axes("$x$","$y$",Arrow);
Gentoo GNU/Linux -- Asymptote 2.24svn avec Emacs -- TeXlive 2012
-
GM
- Administrateur du site
- Messages : 1512
- Enregistré le : dim. 7 mars 2010, 14:50
Message non lu
par GM » ven. 20 déc. 2013, 19:43
Bonsoir,
je ne connais pas vectorfield, ne suis pas sûr qu'il est adapté... et il ne me serait pas venu à l'idée de l'utiliser.
Quand on me parle de tangente à un path, moi je pense à
dir.
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
import graph;
size(6cm,6cm);
real x(real t) { return t^2*cos(t); }
real y(real t) { return t^2*sin(t); }
int n=300;
path p = graph(x,y,-1,1,n);
draw(p);
for (real t=0; t <= n; t += n/10){
path ftan=point(p,t)--point(p,t)+dir(p,t)/2,
fnor=point(p,t)--point(p,t)+rotate(90)*dir(p,t)/2;
draw(Label(format("%f",t),EndPoint, fontsize(8pt)),ftan,red, Arrow);
draw(fnor,blue, Arrow);
}
axes("$x$","$y$",Arrow);
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' :
http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 24/02/21) :
PC n°1 :
Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 :
Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur :
Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
-
YoungFrog
- Messages : 14
- Enregistré le : mar. 11 sept. 2012, 15:46
Message non lu
par YoungFrog » ven. 20 déc. 2013, 22:08
Bon sang mais c'est bien sûr : en relisant ce que fait dir(), je comprends mon erreur : le temps 't' passé par vectorfield à son premier argument (en fait, la distance entre le début de la courbe et le point considéré [*]) n'a rien à voir avec le paramètre t de *ma* paramétrisation (x(t),y(t)), et ma tentative d'interpoler via interp(min,max,t) n'y change rien. En l'écrivant j'aurais dû me dire que c'était bizarre...
Voici le code corrigé. Et merci pour ta version, qui est très claire !
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
import graph;
size(6cm,6cm);
real x(real t) { return t^2*cos(t); }
real y(real t) { return t^2*sin(t); }
real min = -1, max = 1;
path p = graph(x,y,min,max,500);
draw(p);
// vecteurs normaux
picture vf = vectorfield(new path(real t) {
real t = reltime(p,t);
return (0,0)--(I*dir(p,t));
},p, 6,blue+opacity(0.3));
add(vf);
// vecteurs tangents
picture vf = vectorfield(new path(real t) {
real t = reltime(p,t);
return (0,0)--dir(p,t);
},p, 6,red+opacity(0.3));
add(vf);
axes("$x$","$y$",Arrow);
[*] edit : plus précisément la fraction (entre 0 et 1) de la distance par rapport à la distance totale.
Modifié en dernier par
YoungFrog le sam. 21 déc. 2013, 12:25, modifié 1 fois.
Gentoo GNU/Linux -- Asymptote 2.24svn avec Emacs -- TeXlive 2012
-
YoungFrog
- Messages : 14
- Enregistré le : mar. 11 sept. 2012, 15:46
Message non lu
par YoungFrog » ven. 20 déc. 2013, 23:40
Je voulais juste signaler que si on s'intéresse spécifiquement à la direction de l'accélération, il faut être prudent et ne pas prendre I*dir(...) comme vecteur normal : cela ne marche pas si la courbe est orientée dans le "mauvais" sens. Voici une version qui fonctionne même si on modifie le sens de la courbe :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus :
Tout sélectionner
import graph;
size(6cm,6cm);
real x(real t) { return t^2*cos(t); }
real y(real t) { return t^2*sin(t); }
real min = -1, max = 1;
path p = graph(x,y,min,max,500);
draw(p);
pair normal(path p,real t) {
real eps = 1;
real before = t-eps, after = t+eps;
if (before <= 0) { before = t; };
if (after >= length(p)) { after = t; };
return unit(dir(p,after) - dir(p,before));
}
// vecteurs normaux
picture vf = vectorfield(new path(real t) {
real t = reltime(p,t);
return (0,0)--normal(p,t)/2;
},p, 6,blue+opacity(0.3));
add(vf);
// vecteurs tangents
picture vf = vectorfield(new path(real t) {
real t = reltime(p,t);
return (0,0)--dir(p,t)/2;
},p, 6,red+opacity(0.3));
add(vf);
axes("$x$","$y$",Arrow);
Gentoo GNU/Linux -- Asymptote 2.24svn avec Emacs -- TeXlive 2012