ASY-Forum

Bonjourn, suite à une demande d'aide ici, j'ai fait ça :

Figure asymptote f4dd56b98168f0453d40f72409976545
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
unitsize(1cm);
 
// Les axes
limits((0,5), (0,5));
xaxis(Label("$x$", align=N), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
yaxis(Label("$y$", align=W), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
 
// La zone verte
path p=box((0,2.5), (5,3.5));
filldraw(p, green, green);
 
// pointillés et labels
draw((0,3)--(5,3), blue+dashed);
draw((2,3.5)--(2,0), blue+dashed);
draw((0,2)--(2,2), blue+dashed);
draw((3,2.5)--(3,3.5), Arrows);
label("\small $f(2)+\varepsilon$", (3, 3.25), E);
label("\small $f(2)-\varepsilon$", (3, 2.75), E);
 
// La fonction
pair p1=(0,1), p2=(2,2), p3=(2,3), p4=(5,5);
draw(p1--p2^^p3--p4, bp+red);
dot(p1^^p3^^p4, 8bp+red);
dot(p2, 2bp+red, UnFill);

je ne crois pas qu'il y ai une fonction pré-définie pour faire un crochet auvert au bout du premier segment... mais je crois en avoir entendu parler...

peut-être en modifiant bar de plain_arrow.asy :

Code : Tout sélectionner

void bar(picture pic, pair a, pair d, pen p=currentpen)
{
  picture opic;
  Draw(opic,-0.5d--0.5d,p+solid);
  add(pic,opic,a);
}

???

Bruno

Edit : je me pose par ailleurs des questiosn sur la taille des points dans :

Code : Tout sélectionner

dot(p1^^p3^^p4, 8bp+red);
dot(p2, 2bp+red, UnFill);

Si je mets 8bp+red dans la 2e ligne, le point devient ENORME...?

Petit rappel d'une contribution d'OG :

Figure asymptote b0248785a03404d57dfb2c20f0bf5086
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

// OG.asy est, comme son nom l'indique, un fichier de contributions d'O.G..
// téléchargeable ici : <asyxml><html><a href="http://svn.noordover.org/filedetails.php?repname=depot_public_asymptote&path=%2Fdivers%2FOG.asy">OG.asy</a></html></asyxml>
 
import graph;
import OG; // pour profiter de "Bras" : extrémités de segment en forme de crochets.
 
size(10cm,0);
 
real f (real x)
  {
  return cos(x);
  }
 
ylimits(-.3,1.5);
xaxis("$x$",EndArrow);
yaxis("$y$",EndArrow);
 
draw(graph(f,-.5,2,operator ..));
 
real x0=1;
real delta=.4;
 
path hline1=(x0-delta,0)--graph(f,x0-delta,x0+delta)--(x0+delta,0)--cycle,
     hline2=(0,f(x0-delta))--graph(f,x0-delta,x0+delta)--(0,f(x0+delta))--cycle;
 
fill(hline1^^hline2,gray+opacity(.5));
draw(hline1^^hline2,blue);
 
draw((x0-delta,0)--(x0+delta,0),blue+bp,Bras); //
draw((0,f(x0+delta))--(0,f(x0-delta)),blue+bp,Bras);
draw(graph(f,x0-delta,x0+delta),red+2bp,Bras);

Ta question m'a permis de me demander pourquoi cela n'est pas pris en compte ici : http://www.marris.org/asymptote/Courbes_fonctions/index.html#fig_ia01_150210_fonction_intervalle

Je regarderai ce problème demain car aujourd'hui... très grosse journée au lycée, avec premier cours d'ISN (montage d'un pc avec les élèves).

GM a écrit :Petit rappel d'une contribution d'OG

J'avais vu ça ici ; mais le lien est cassé !

merci

Bruno

GM a écrit :Je regarderai ce problème demain car aujourd'hui...

Problème identifié mais pas résolu : j'ai un problème si j'utilise opacity. Je l'ai supprimé dans l'exemple en attendant de trouver un parade.

maurice a écrit :J'avais vu ça ici ; mais le lien est cassé !

Il est réparé. Merci de l'avoir signalé.

ASY-Forum

Crochets sur un segment

Crochets sur un segment

Re: Crochets sur un segment

Re: Crochets sur un segment

Re: Crochets sur un segment

Re: Crochets sur un segment