ASY-Forum

Bonjour,
sur la figure ci-dessous, je veux avoir -i,i,2i... à la place des ordonnées réelles.
Que dois-je faire?

Figure asymptote 09cc31bb1935847c832439497d7ca7ff
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

//import graph;
import graph_pi; 
import geometry;
//usepackage("amsmath"); 
unitsize(1cm);
real xmin = -5.8, xmax = 4.5, ymin = -6.5, ymax = 6.8;
pen gridstyle = linewidth(0.3) + gray + linetype("10 10"),
 stylo1 = defaultpen+black+linewidth(1.2),
 stylo2 = linewidth(2)+blue;
limits((xmin,ymin),(xmax,ymax));
xaxis(BottomTop,Ticks("%",extend=true, Step = 1, gridstyle));
yaxis(LeftRight,Ticks("%",extend=true, Step = 1, gridstyle));
Label laxis; laxis.p = fontsize(15);
xaxis(xmin, xmax, stylo1, Ticks(laxis,NoZero, Step = 1,Size = 2,begin=false) ,Arrow(HookHead,5));
yaxis(ymin, ymax, stylo1, Ticks(laxis,NoZero, Step = 1,Size = 2,begin=false) ,Arrow(HookHead,5));
//labeloij(p=1.4bp+black,arrow=Arrow(HookHead,5bp),dot);
//%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
draw((2.5,1)--(1.5,3.5),1.5bp+purple,Arrow(HookHead,5)); 
label("$\overrightarrow{w}$",(1.6,3.6),SE); 
draw((3,2)--(0.5,-3.5),red+linewidth(1.5)); 
draw((0.5,-3.5)--(-5,-1),red+linewidth(1.5)); 
//draw((-5,-1)--(3,2),brown+linewidth(1.5)); 
draw((-5,-1)--(-2.5,4.5),red+linewidth(1.5)); 
draw((-2.5,4.5)--(3,2),red+linewidth(1.5)); 
draw((1.5,-6)--(0.5,-3.5),1.5bp+purple,Arrow(HookHead,5)); 
draw((-2.5,4.5)--(1.5,6.),blue+linewidth(1.5)); 
draw((1.5,6)--(3,2),blue+linewidth(1.5)); 
//%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
dot((1.5,6),5bp+blue); 
label("A", (1.5,6), NE ); 
dot((1.5,-6),5bp+blue); 
label("B", (1.5,-6), SE ); 
label("C", (-3,-0.25), NW ); 
dot((3,2),5bp+blue); 
label("P", (3,2), E ); 
dot((2.5,1),5bp+.5blue); 
dot((1.5,3.5),5bp+.5blue);
dot((-5,-1),5bp+blue);
label("R", (-5,-1), W );
dot((0.5,-3.5),5bp+blue);
label("Q", (0.5,-3.5), E );
dot((-2.5,4.5),5bp+blue);
label("S", (-2.5,4.5), NW );
dot((0,0),5bp+black); 
label("O", (-.25,0), S );  
draw(arc((1.5,6),4.25,0,-180),1bp+blue+dashed);
draw((2.5,1)--(1.5,-6),purple+dashed+linewidth(1));
draw((1.5,3.5)--(0.5,-3.5),purple+dashed+linewidth(1));
//%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Codage Angle droit
path carre=square((1.5,6),(1.15,5.87));
draw(carre,1bp+blue);
//dot((1.5,6)^^(1.15,5.87));
//Homothétie
draw((-3,-0.25)--(3,2),1.5bp+brown,Arrow(HookHead,5)); 
draw((-3,-0.25)--(-5,-1),1.5bp+brown,Arrow(HookHead,5));
dot((-3,-0.25),5bp+blue); //point C
clip((xmin,ymin)--(xmin,ymax)--(xmax,ymax)--(xmax,ymin)--cycle);

Bonsoir,

J'ai modifié les lignes 14 et 15 (passage xaxis et yaxis --> yequals et xequals) et ajouter la ligne 16 :

Code : Tout sélectionner

 for(int k=floor(ymin); k<=floor(ymax); ++k) if (k!=0) labely(format("$%i \mathrm{i}$", k), k, W, fontsize(15pt));

Il y a sans doute d'autres solutions sans doute plus élégantes ...

Figure asymptote a1153d915ba507ea3b4970cee010129e
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

//import graph;
        import graph_pi;
        import geometry;
        //usepackage("amsmath");
        unitsize(1cm);
        real xmin = -5.8, xmax = 4.5, ymin = -6.5, ymax = 6.8;
        pen gridstyle = linewidth(0.3) + gray + linetype("10 10"),
        stylo1 = defaultpen+black+linewidth(1.2),
        stylo2 = linewidth(2)+blue;
        limits((xmin,ymin),(xmax,ymax));
        xaxis(BottomTop,Ticks("%",extend=true, Step = 1, gridstyle));
        yaxis(LeftRight,Ticks("%",extend=true, Step = 1, gridstyle));
        Label laxis; laxis.p = fontsize(15);
        yequals(0,xmin, xmax, stylo1, Ticks(laxis,NoZero, Step = 1,Size = 2,begin=false) ,Arrow(HookHead,5));
        xequals(0, ymin, ymax, stylo1, Ticks("%",NoZero, Step = 1,Size = 2,begin=false) ,Arrow(HookHead,5));
        for(int k=floor(ymin); k<=floor(ymax); ++k) if (k!=0) labely(format("$%i \mathrm{i}$", k), k, W, fontsize(15pt));
        //labeloij(p=1.4bp+black,arrow=Arrow(HookHead,5bp),dot);
        //%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
        draw((2.5,1)--(1.5,3.5),1.5bp+purple,Arrow(HookHead,5));
        label("$\overrightarrow{w}$",(1.6,3.6),SE);
        draw((3,2)--(0.5,-3.5),red+linewidth(1.5));
        draw((0.5,-3.5)--(-5,-1),red+linewidth(1.5));
        //draw((-5,-1)--(3,2),brown+linewidth(1.5));
        draw((-5,-1)--(-2.5,4.5),red+linewidth(1.5));
        draw((-2.5,4.5)--(3,2),red+linewidth(1.5));
        draw((1.5,-6)--(0.5,-3.5),1.5bp+purple,Arrow(HookHead,5));
        draw((-2.5,4.5)--(1.5,6.),blue+linewidth(1.5));
        draw((1.5,6)--(3,2),blue+linewidth(1.5));
        //%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
        dot((1.5,6),5bp+blue);
        label("A", (1.5,6), NE );
        dot((1.5,-6),5bp+blue);
        label("B", (1.5,-6), SE );
        label("C", (-3,-0.25), NW );
        dot((3,2),5bp+blue);
        label("P", (3,2), E );
        dot((2.5,1),5bp+.5blue);
        dot((1.5,3.5),5bp+.5blue);
        dot((-5,-1),5bp+blue);
        label("R", (-5,-1), W );
        dot((0.5,-3.5),5bp+blue);
        label("Q", (0.5,-3.5), E );
        dot((-2.5,4.5),5bp+blue);
        label("S", (-2.5,4.5), NW );
        dot((0,0),5bp+black);
        label("O", (-.25,0), S );
        draw(arc((1.5,6),4.25,0,-180),1bp+blue+dashed);
        draw((2.5,1)--(1.5,-6),purple+dashed+linewidth(1));
        draw((1.5,3.5)--(0.5,-3.5),purple+dashed+linewidth(1));
        //%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
        //Codage Angle droit
        path carre=square((1.5,6),(1.15,5.87));
        draw(carre,1bp+blue);
        //dot((1.5,6)^^(1.15,5.87));
        //Homothétie
        draw((-3,-0.25)--(3,2),1.5bp+brown,Arrow(HookHead,5));
        draw((-3,-0.25)--(-5,-1),1.5bp+brown,Arrow(HookHead,5));
        dot((-3,-0.25),5bp+blue); //point C
        clip((xmin,ymin)--(xmin,ymax)--(xmax,ymax)--(xmax,ymin)--cycle);

Bruno

PS : graph_pi ne sert à rien ici, l'extension graph suffit !

Merci c'est ce que je voulais avoir.

Bonsoir,
Comment faire disparaitre le coefficient 1 ou -1 devant

?

boubamane a écrit :Bonsoir,
Comment faire disparaitre le coefficient 1 ou -1 devant ?

Bonsoir

sans avoir tester (et en ayant fermé les yeux sur tout le reste du code) :

Remplacer :

Code : Tout sélectionner

for(int k=floor(ymin); k<=floor(ymax); ++k) if (k!=0) labely(format("$%i \mathrm{i}$", k), k, W, fontsize(15pt));

par

Code : Tout sélectionner

for(int k=floor(ymin); k<=floor(ymax); ++k)
{
    if (abs(k)>1)
        labely(format("$%i \mathrm{i}$", k), k, W, fontsize(15pt));
    else if (abs(k)==1)
    {
        string sign = (k==-1)?"$-$":"";
        labely(sign+"$\mathrm{i}$", k, W, fontsize(15pt));
    }
}

Bonjour,
Ca marche merci.
Que faut-il apprendre pour faire soit-même ce type de programme?

boubamane a écrit :Que faut-il apprendre pour faire soit-même ce type de programme?

Je ne suis pas sûr de comprendre la question.

Il faut penser d'abord ce que l'on veut faire en langage naturel !

C'est ainsi que, pour la modification, je me suis dit que j'allais remplacer la ligne qui écrivait systématiquement

Code : Tout sélectionner

%i \mathrm{i}

(où %i est un entier (integer) prenant toutes les valeurs de k)

par :

si la valeur absolue de k est plus grande que 1
alors on laisse inchangé l'affichage prévu
sinon
si la valeur absolue de k est 1,
on définit une chaine de caractère sign qui est "-" ou "" (suivant que k=-1 ou k=1) et on affiche la concaténation de sign et \mathrm{i}.
finsi

finsi

puis il ne reste plus qu'à coder.

Merci !!!

ASY-Forum

Plan complexe

Plan complexe

Re: Plan complexe

Re: Plan complexe

Re: Plan complexe

Re: Plan complexe

Re: Plan complexe

Re: Plan complexe

Re: Plan complexe