ASY-Forum

Bonsoir !
Quelqu'un (je devine déjà qui) pourrait-il m'éclairer sur la notion de "guide" ?
Merci !

Bonsoir,

path
Une variable de ce type est une courbe de Bézier spline cubique résolue.
guide
Une variable de ce type est une courbe de Bézier spline cubique non résolue : les points de contrôle ne sont pas tous déterminés, la résolution est différée.

Dans certaines situations, on ne voit pas de différence :

Figure asymptote 75c923ed01eddf130a503f76750ab4cd
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(100);
path p=(0,0)..(0,-1)..(2,1)..(4,0);
draw(p,blue,dot());

Figure asymptote 38bfdf158a95c6343f7e6a356580e8d5
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(100);
guide p=(0,0)..(0,-1)..(2,1)..(4,0);
draw(p,blue,dot());

mais en voilà un autre qui montre la différence :

Figure asymptote 5a9b7c241f1adcc3e4e7054c58fc9db2
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(100);
path p1=(1,0)..(0,1),
     p2=(-1,0)..(0,-1),
     p3=p1..p2;
draw(p1,3bp+red);
draw(p2,3bp+green);
draw(p3,blue);

Figure asymptote d247a0364a011801ab6813b15896ec05
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(100);
guide p1=(1,0)..(0,1),
       p2=(-1,0)..(0,-1),
       p3=p1..p2;
draw(p1,3bp+red);
draw(p2,3bp+green);
draw(p3,blue);

je vais travailler cette notion ... et chercher aussi son intérêt !
MERCI, bonne journée.

zariski a écrit : et chercher aussi son intérêt !

On est amené parfois à devoir définir un chemin point par point... et il faut différer le calcul des points de contrôle si on ne veut pas avoir ce qu'il se passe pour la courbe bleue ci-dessous :

Figure asymptote fe16b4a160edde66ea4e96a02527a573
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

size(300);
guide g=(1,0);
path  p=(1,0);
transform t;
for(int k=0; k<6; ++k)
{
 t=scale((k%2==0)?1.1:0.9)*rotate(30+k); // on définit une similitude directe de centre O
                                         // de rapport 1,1 ou 0,9 (selon la parité de k) et d'angle de mesure (30+k)°.
 p=p..t*relpoint(p,1); // on applique t au dernier point du path pour obtenir un nouveau point que l'on ajoute au path.
 g=g..t*relpoint(g,1); // on applique t au dernier point du guide pour obtenir un nouveau point que l'on ajoute au guide.
}
draw(p,blue,dot());
draw(g,red);

j'entrevois le truc ... mais il faut encore que je saisisse bien la chose par de multiples exemples.
J'avoue que depuis que je travaille Asymptote, mes notions deviennent plus solides.
Il me faisait peine mais la beauté des constructions et les possibilités le valent bien .
Merci encore pour ces réponses rapides et relativement limpides, c'est vraiment sympa !
A bientôt pour d'autres questions car je n'ai pas encore fini mon travail sur Asymptote.

Bonne soirée

zariski a écrit :je n'ai pas encore fini mon travail sur Asymptote.

Tu fais une galerie d'exemples ou tu écris un livre ? :mrgreen:

Plutôt une "galerie" d'exemples. Disons que je souhaite connaitre tous les dessous d'asymptote.
Mais dis moi, tu ne serais pas un tantinet moqueur ?

zariski a écrit :Plutôt une "galerie" d'exemples. Disons que je souhaite connaitre tous les dessous d'asymptote.
Mais dis moi, tu ne serais pas un tantinet moqueur ?

Pas du tout mais le dernier que j'ai rencontré qui, comme toi, passait en revue ainsi toutes les fonctions d'Asymptote pour apprendre en faisant une galerie d'exemples, c'était moi. Donc j'ai un sentiment de déjà vu :lol:

même si je posais nettement moins de questions que toi à Philippe ! :lol:

Mais tu as bien de raison d'en poser car tu y perdras moins de temps que moi... et puis cela fait vivre le forum. ;-)

ahh ok !!
Ben effectivement c'est le but que je me suis donné, apprendre le fonctionnement d'Asymptote.
Le hic c'est que ça me prend pas mal de temps, mais bon...
Et en effet j'ai pas fini de poser des questions.

Bonne journée.

ASY-Forum

guide

guide

Re: guide

Re: guide

Re: guide

Re: guide

Re: guide

Re: guide

Re: guide

Re: guide