arctime
Pour toute demande d'aide pour la conception (ou la confirmation d'un code) d'une figure Asymptote, c'est ici.
J'invite ceux qui ont régulièrement des questions à poser à aller dans leur panneau de l'utilisateur pour indiquer dans la signature de leurs messages :
- Nom du système d'exploitation (W7 ou Ubuntu 12.04 ou ...)
- Version d'Asymptote et éditeur utilisé pour les figures Asymptote
- Distribution LaTeX et éditeur utilisé pour les tex.
On va gagner du temps dans les réponses !
Re: arctime
Il y a un exemple explicatif dans la galerie et je crois bien qu'il en a déjà été question sur le forum.
Mais voilà un nouvel exemple :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- size(400);
- marker croix=marker(scale(2)*cross(4),1bp+green);
- real a = 2, longueur = 5;
- path p1=(0,0)--(1,0)--(longueur,0),
- p2=(0,0)--(4,0)--(longueur,0);
- transform t = shift(0,-a);
- draw(p1,red,dot(10bp+black));
- draw(t*p2,blue,dot(10bp+black));
- for (real k=0; k<=length(p1); k+=0.5) {
- draw(Label(format("%.1f",k)),point(p1,k),2N,red,croix);
- draw(Label(format("%.1f",k)),t*point(p2,k),2S,blue,croix);
- }
- pair centreimage = (longueur/2,-a/2);
- label("2 chemins de même longueur (L="+string(arclength(p1))+") d\'efinis par 3 points noirs diff\'erents.",centreimage,N);
- label("Les nombres color\'es sont le \textit{time} des points marqu\'es d'une croix.",centreimage,S);
- label("Le milieu du premier segment a pour \textit{time} : "+string(arctime(p1,longueur/2)),centreimage,10N,red);
- label("Le milieu du second segment a pour \textit{time} : "+string(arctime(p2,longueur/2)),centreimage,10S,blue);
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Re: arctime
J'ai longtemps réflêchi à cette notion d'arctime ... Je pense avoir compris; quant à l'utilité, y en a surement une ...
Voici un petit topo de mon cru, corrigez moi svp si j'ai dit des bêtises.
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- unitsize(1cm);
- marker croix=marker(scale(2)*cross(4),1bp+green),
- tiret=marker((0,-1)--(0,1),black);
- real L=10;
- path p1=(0,0)--(2,0)--(6,0)--(L,0),
- p2=(0,0)--(4,0)--(7,0)--(L,0);
- transform t = shift(0,-2);
- draw(p1,red,dot(6bp+black));
- draw(t*p2,blue,dot(6bp+black));
- for (real k=0; k<=length(p1); k+=1) {
- draw(Label(format("%.1f",k)),point(p1,k),2N,red,croix);
- draw(Label(format("%.1f",k)),t*point(p2,k),2N,blue,croix);
- }
- for (real k=0; k<=L; k+=1) {
- draw(Label(format("%.1f",k)),(k,0),2S,tiret);
- draw(Label(format("%.1f",k)),t*(k,0),2S,tiret);
- }
- label(scale(0.8)*("Deux chemins de m\^eme longueur (L="+string(arclength(p1))+") d\'efinis par 4 points noirs diff\'erents."),(0,-3.4),E);
- label(scale(0.8)*(string(arctime(p1,0)) + " est le time du point de p1 \`a la distance " + string(arclength((0,0)-(0,0)))),(5,-4),W,red);
- label(scale(0.8)*(string(arctime(p1,L/2)) + " est le time du point de p1 \`a la distance " + string(arclength(scale(0.5)*p1))),(5,-5),W,red);
- label(scale(0.8)*(string(arctime(p1,0.8*L)) + " est le time du point de p1 \`a la distance " + string(arclength(scale(0.8)*p1))),(5,-6),W,red);
- label(scale(0.8)*(string(arctime(p1,L)) + " est le time du point de p1 \`a la distance " + string(arclength(scale(1)*p1))),(5,-7),W,red);
- label(scale(0.8)*(string(arctime(p2,0)) + " est le time du point de p2 \`a la distance " + string(arclength(scale(0)*p2))),(5,-4),E,blue);
- label(scale(0.8)*(string(arctime(p2,L/2)) + " est le time du point de p2 \`a la distance " + string(arclength(scale(0.5)*p2))),(5,-5),E,blue);
- label(scale(0.8)*(string(arctime(p2,0.8*L)) + " est le time du point de p2 \`a la distance " + string(arclength(scale(0.8)*p2))),(5,-6),E,blue);
- label(scale(0.8)*(string(arctime(p2,L)) + " est le time du point de p2 \`a la distance " + string(arclength(scale(1)*p2))),(5,-7),E,blue);
- shipout(bbox(0.5mm,white));
Re: arctime
zariski a écrit :corrigez moi svp si j'ai dit des bêtises.
Je conseillerai plutôt d'écrire : ... le time du point de p1 à une distance curviligne 5 de son point origine.
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- import markers;
- unitsize(100);
- path p=unitcircle;
- draw(p,dot);
- pair pM=point(p,arctime(p,1));
- dot(string(arctime(p,1)),pM,5bp+red);
- draw((1,0)--(0,0)--pM{dir(-I*pM)}..{-I}cycle,StickIntervalMarker(3,2,blue,dotframe(.8green)));
- label("$\frac{2}{\pi} \approx$ "+string(2/pi),truepoint(NE),NW);
unitcircle (de longueur théorique ) étant défini par 4 "noeuds" et formé de ce que je vais appeler 4 "sections",
le point rouge correspondant à une distance curviligne de 1 depuis le point de coordonnées (1;0) (et permettant donc de définir un secteur angulaire de 1 radian) a un time d'environ 0,6395 : il est situé à 63,95% de la première section depuis le point (1;0).
On constatera que l'on n'obtient pas une valeur approchée aussi proche de la valeur théorique de qu'on aurait pu l'imaginer.
J'imagine qu'une partie de l'erreur est imputable au fait que unitcircle manque de précision avec ses (seulement) 4 noeuds.
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Re: arctime
GM a écrit :On constatera que l'on n'obtient pas une valeur approchée aussi proche de la valeur théorique de qu'on aurait pu l'imaginer.
J'imagine qu'une partie de l'erreur est imputable au fait que unitcircle manque de précision avec ses (seulement) 4 noeuds.
On augmente la précision en définissant le cercle avec huit points :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- import graph;
- import markers;
- unitsize(100);
- int n0=8;
- path p=Circle(c=(0,0),r=1,n=4*n0);
- draw(p,dot);
- pair pM=point(p,arctime(p,1));
- dot(string(arctime(p,1)),pM,5bp+red);
- draw((1,0)--(0,0)--pM{dir(-I*pM)}..{-I}cycle,StickIntervalMarker(3,2,blue,dotframe(.8green)));
- label(format("$\frac{2}{\pi}\times %i \approx$ ",n0)+string(2/pi*n0),truepoint(NE),NW);
... et là, on constate que l'écart entre le time effectif et sa valeur théorique est plus petit.
Et avec 10 fois plus de points, on gagne encore en précision :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- import graph;
- import markers;
- unitsize(100);
- int n0=80;
- path p=Circle(c=(0,0),r=1,n=4*n0);
- draw(p,dot);
- pair pM=point(p,arctime(p,1));
- dot(string(arctime(p,1)),pM,5bp+red);
- draw((1,0)--(0,0)--pM{dir(-I*pM)}..{-I}cycle,StickIntervalMarker(3,2,blue,dotframe(.8green)));
- label(format("$\frac{2}{\pi}\times %i \approx$ ",n0)+string(2/pi*n0),truepoint(NE),NW);
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Re: arctime
Merci^10