Problème avec la fonction fit()

[dohtreb]

Hello,

Quelqu'un peut-il m'expliquer pourquoi la courbe n'apparaît pas dans le deuxième graphique (cf. code ci-dessous)? J'ai besoin d'utiliser la deuxième méthode pour pouvoir combiner plusieurs graphiques dans une même image en suivant par exemple http://www.marris.org/asymptote/Sciences_physiques/index.html#fig_er10_221109_errorbars.

Merci!

[Asymptote 2.13 sur mac (10.7.3) avec texlive 2011]

Code : Tout sélectionner

\documentclass{article}
\usepackage{asymptote}
\begin{document}

\begin{asy}
import graph;
real f(real x) {return (1+x^2)/(1+227*x^2+x^4);}
size(200,250,IgnoreAspect);
scale(Log,Log);
draw(graph(f,0.001,1000),linewidth(2bp)+red);
xlimits(0.001,1000,Crop);
ylimits(1e-6,1,Crop);
xaxis("$x$",BottomTop,LeftTicks);
yaxis("$y$",LeftRight,RightTicks);
\end{asy}

\begin{asy}
import graph;
real f(real x) {return (1+x^2)/(1+227*x^2+x^4);}
picture p1;
size(p1,200,250,IgnoreAspect);
scale(p1,Log,Log);
draw(p1,graph(f,0.001,1000),linewidth(2bp)+red);
xlimits(p1,0.001,1000,Crop);
ylimits(p1,1e-6,1,Crop);
xaxis(p1,"$x$",BottomTop,LeftTicks);
yaxis(p1,"$y$",LeftRight,RightTicks);
add(p1.fit());
\end{asy}

\end{document}

[GM]

Quelqu'un peut-il m'expliquer pourquoi la courbe n'apparaît pas dans le deuxième graphique

oui

Remplacer

Code : Tout sélectionner

draw(p1,graph(f,0.001,1000),linewidth(2bp)+red);

par

Code : Tout sélectionner

draw(p1,graph(p1,f,0.001,1000),linewidth(2bp)+red);

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
real f(real x) {return (1+x^2)/(1+227*x^2+x^4);}
picture p1;
size(p1,200,250,IgnoreAspect);
scale(p1,Log,Log);
draw(p1,graph(p1,f,0.001,1000),linewidth(2bp)+red);
xlimits(p1,0.001,1000,Crop);
ylimits(p1,1e-6,1,Crop);
xaxis(p1,"$x$",BottomTop,LeftTicks);
yaxis(p1,"$y$",LeftRight,RightTicks);
add(p1.fit());

[dohtreb]

Merci
On ne m'y prendra plus...

[GM]

J'ai besoin d'utiliser la deuxième méthode pour pouvoir combiner plusieurs graphiques dans une même image

A ce propos, un peu de lecture.

Comme je l'ai écrit dans le txt à côté du pdf, j'avais des intentions d'ajouts... et je n'ai jamais trouvé le temps. Et c'est pas à l'heure où je dois prévoir ce que j'exposerai en juin 2012 que je vais avoir le temps de le faire.