question du forum asy

[GM]

pouvoir écarter les flèches des segments mesurés, d'une distance donnée, en toutes circonstances...

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geometry;
size(5cm);
 
pair pA=(0,0), pB=(10,0);
 
draw(pA--pB,blue);
distance("x",pA,pB);
 
picture pic1;
draw(pic1,pA--pB,blue);
distance(pic1,"x",pA,pB);
add(pic1.fit(1cm),(0,2));
add(pic1.fit(2cm),(0,4));

... ce qu'il faudrait pouvoir faire aussi avec les accolades.

Mais je me dis que j'ai dû à un moment donné avoir la solution dans mes tests (que je reprendrai) et que je suis probablement tombé sur une situation telle que celle là qui m'a fait croire que je n'avais pas la solution, en ayant crû le positionnement de point(SE) incorrect. Il faudrait peut-être poser la question à ce propos sur le forum officiel.

[OG]

Hello Gaëtan

Bah cette histoire de deferred drawing est toujours délicate à comprendre et à implémenter.
Dans le cas de geometry, le truc style distance n'existant pas il fallait utiliser le deferred drawing.
En reprenant ta 1ère méthode et en ajoutant une boîte qui ne tient uniquement compte du chemin
et pas du label (ce que tu voulais hormis la non prise en compte du label) le point se n'est pas bon non plus.
Ferais-tu une fixation sur point, Truepoint ?

O.G.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

void cotationaccolade(picture pic=currentpicture,
                      pair pA, pair pB,
                      Label L = "", bool Lrot=false,
                      pen p=currentpen)
{
    path brace=(0,0).. controls (3,4) and (5,4) ..(10,4)
                   --(40,4).. controls (45,4) and (48,4) ..(50,6);
         brace=brace--reverse(reflect((50,0),(50,10))*brace);
         brace=shift(pA)*rotate(degrees(pB-pA))*scale(abs(pB-pA)/100)*brace;
 
         //draw(pic,L,brace,p,align=N);
       pic.add(new void(frame f, transform t)
	{
        transform T = Lrot ? rotate(degrees(pB - pA)) : identity();
        draw(f,t*brace,p);
        if(L.s != "") {
            frame fr;
            add(fr,T*L);
            pair pos=point(t*brace,L.relative()*length(brace));
            add(f,fr,pos,align=N);
        }
    },true);
 
 //pic.addPath(brace,p);
 pic.addBox(min(brace), max(brace), min(p), max(p));
 
}
unitsize(2cm);
 
draw((0,0)--(5,2));
 
picture pic;
pair z1=(0,0), z2=(5,-.25);
dot(pic,z1^^z2);
cotationaccolade(pic,z1,z2,L=Label("Text",Relative(.5),purple),2bp+green);
add(pic.fit(10cm),(1,-1));
 
 
picture pic1;
cotationaccolade(pic1,z1,z2,L=Label("Text",Relative(.5),purple),2bp+green);
add(pic1.fit(1cm),(0,1));
add(pic1.fit(2cm),(0,2));
 
dot("se",point(SE),NW,red);
dot("nw",point(NW),SE,red);
dot("SE",truepoint(SE),NW,blue);
dot("NW",truepoint(NW),SE,blue);

[GM]

le point se n'est pas bon non plus.

C'est parce que j'ai tenté ce genre de choses et qu'il y avait toujours quelque chose qui n'allait pas dans mes essais, que j'ai posé la question (indirectement) à JCBowman.
Mais depuis, tu as montré qu'il y a un problème sur ce que renvoie point(SE) avec une figure comportant un simple trait et l'ajout d'une picture décalée donc il n'est plus si étonnant que cela ne va pas avec ma fonction accolade.

Ferais-tu une fixation sur point, Truepoint ?

Disons que... quitte à l'utiliser dans certaines figures... autant essayer de comprendre comment cela fonctionne.
Moi j'aime bien ajouter un titre à une figure dans un coin... et truepoint(...) est pratique pour cela
donc je me sens obligé de proposer une fonction accolade qui ne fausse pas ce que renvoie truepoint(...)
et quand on s'y intéresse, on ne peut pas fermer les yeux sur point(...).

[OG]

Re

J'avais commencé à traduire en asymptote l'accolade de cmarrow (metapost), mais
par faute de temps j'ai laissé le truc à l'abandon. C'est un peu compliqué (je ne comprends
plus le code) et mettre un label + truepoint ok sera à mon avis super coton.

Ciao

[GM]

J'avais commencé à traduire en asymptote l'accolade de cmarrow (metapost)

Je viens d'y jeter un oeil. Comme je n'avais pas de grandes exigences pour la forme, je me suis dit que j'arriverais bien à trouver un path, défini avec un minimum de points, qui ferait un peu illusion.

[OG]

Re

J'ai regardé à nouveau le code : je ne comprends rien.
Disons que je ne vois surtout pas comment faire en sorte que truepoint
ou autre soient à peu près juste. Comme a priori la routine prend
en argument n'importe quel chemin pour en faire une accolade-chemin
il faudrait peut-être se limiter à faire une accolade droite.

O.G.

[GM]

Il semblerait que la diffusion du code sur mathematex était prématurée : il y a un gros bogue.

Olivier peux-tu, sur Mathematex, supprimer l'exemple... pour y mettre simplement un lien vers ce sujet, en précisant qu'on y travaille ?
Car je trouve gênant de donner en exemple quelque chose qui ne va pas du tout. Il suffit de mettre autre chose que (0,0) pour z1 pour s'en convaincre.

On pourra remettre un exemple sur Mathematex, quand cela aura été suffisamment testé pour être sûr que cela fonctionne.

[GM]

il y a un gros bogue

Il manque un "shift(pA)" que je vais ajouter à nos codes précédents.

[GM]

Il manque un "shift(pA)" que je vais ajouter à nos codes précédents.

Et il y a

Code : Tout sélectionner

draw(L,brace,p,align=N);

à remplacer par :

Code : Tout sélectionner

draw(L,brace,p,align=LeftSide);

Et... (sûrement encore d'autres choses).

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

void cotationaccolade(picture pic=currentpicture,
                      pair pA, pair pB,
                      Label L = "", bool Lrot=false,
                      pen p=currentpen)
{
    path brace=(0,0).. controls (3,4) and (5,4) ..(10,4)
                --(40,4).. controls (45,4) and (48,4) ..(50,6);
    brace=brace--reverse(reflect((50,0),(50,10))*brace);
    brace=shift(pA)*rotate(degrees(pB-pA))*scale(abs(pB-pA)/100)*brace;
    draw(L,brace,p,align=LeftSide);
}
///////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////
 
size(10cm);
pair z1=(1,0), z2=(5,-.25), z3=(4,-2);
dot(z1^^z2^^z3);
cotationaccolade(z1,z2,"AB",.2bp+green);
cotationaccolade(z2,z3,L=Label("BC",purple),.2bp+green);
cotationaccolade(z3,z1,L=Label("AC",Relative(.75),orange),.2bp+green);

Attention, ce qui est ci-dessus, est une version très provisoire, avec des défauts.

[GM]

Et... (sûrement encore d'autres choses).

... comme, par exemple, le booléen non pris en compte (dans cette version simplifiée temporaire ) pour la rotation du label.