Nombre dérivé et courbe.
Règles du forum
Pour toute demande d'aide pour la conception (ou la confirmation d'un code) d'une figure Asymptote, c'est ici.
J'invite ceux qui ont régulièrement des questions à poser à aller dans leur panneau de l'utilisateur pour indiquer dans la signature de leurs messages :
On va gagner du temps dans les réponses !
Pour toute demande d'aide pour la conception (ou la confirmation d'un code) d'une figure Asymptote, c'est ici.
J'invite ceux qui ont régulièrement des questions à poser à aller dans leur panneau de l'utilisateur pour indiquer dans la signature de leurs messages :
- Nom du système d'exploitation (W7 ou Ubuntu 12.04 ou ...)
- Version d'Asymptote et éditeur utilisé pour les figures Asymptote
- Distribution LaTeX et éditeur utilisé pour les tex.
On va gagner du temps dans les réponses !
Nombre dérivé et courbe.
Bonjour,
J'ai abordé la notion de nombre dérivé, et je suis amené à tracer de nombreuses courbes (trop !!)pour entraîner les élèves à lire les nombres dérivés. Je fais cela un peu à tâtons pour faire en sorte que la lecture du coefficient directeur soit facilitée par la grille.
Imaginons que je veuille tracer une courbe où : f'(0)=-2, f'(-1)=-0.25 et f'(2)=0. Quelle est la méthode la "plus rapide" ?
Merci.
J'ai abordé la notion de nombre dérivé, et je suis amené à tracer de nombreuses courbes (trop !!)pour entraîner les élèves à lire les nombres dérivés. Je fais cela un peu à tâtons pour faire en sorte que la lecture du coefficient directeur soit facilitée par la grille.
Imaginons que je veuille tracer une courbe où : f'(0)=-2, f'(-1)=-0.25 et f'(2)=0. Quelle est la méthode la "plus rapide" ?
Merci.
Debian Strech + Asymptote 2.42-12 + Emacs24 + TeXLive 2017
Re: Nombre dérivé et courbe.
Bonjour,
Voilà peut-être une source d'inspiration :
Pour la grille, j'ai peut-être fait un peu compliqué.
Voilà peut-être une source d'inspiration :
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- import graph;
- import interpolate;
- import geometry;
- unitsize(2cm,2cm);
- //------ Une grille -----------------
- int xmin=-2, xmax=3, ymin=-2, ymax=3;
- pen p=linetype("0 " + string(1mm), offset=0, scale=false, adjust=false);
- add(shift(xmin,ymin)*grid(xmax-xmin,ymax-ymin,1bp+p));
- add(shift(xmin-.5,ymin-.5)*grid(xmax-xmin+1,ymax-ymin+1,1bp+gray));
- xlimits(xmin,xmax,Crop);
- ylimits(ymin,ymax,Crop);
- //------ Les données -----------------
- real[] xpt={-2,-1,0,1,2,3};
- real[] ypt={3,1,0,.5,2,1};
- real[] dy={-2,-0.25,1,-2,0,1}; // << nombres dérivés
- // ----- les fonctions utiles
- real f(real t){ return pwhermite(xpt,ypt,dy)(t); }
- void tangente(int k,real lg=1,real ld=lg, pen p=dashed, arrowbar arr=None) {
- draw(((xpt[k],ypt[k])-lg*unit((1,dy[k])))--((xpt[k],ypt[k])+ld*unit((1,dy[k]))),p,arr);
- }
- // ----- les constructions
- path Cf=graph(f,-2,3);
- draw(Cf, 1bp+blue);
- tangente(0,lg=0,ld=2,p=.8bp+red,Arrow(SimpleHead));
- tangente(1,ld=2);
- tangente(2,lg=2,Arrows);
- tangente(3,lg=2,p=.8bp+purple,Arrow);
- tangente(4,lg=1,ld=1,p=.8bp+red,Arrows(HookHead));
Pour la grille, j'ai peut-être fait un peu compliqué.
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' : http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Re: Nombre dérivé et courbe.
Une variante
- exploitant graph_pi pour "l'enrobage"
- et automatisant un peu les choses : en changeant les données... le reste devrait à peu près s'adapter.
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***
- CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
- import graph_pi;
- import interpolate;
- usepackage("mathrsfs");
- //------ Les données -----------------
- real[] xpt={-2,-1,0,1,2,3};
- real[] ypt={3,1,0,.5,2.5,1};
- real[] dy={-2,-0.25,1,-2,0,1}; // << nombres dérivés
- //------ et les "fonctions" utiles (qui en sont dépendantes)
- real f(real t){ return pwhermite(xpt,ypt,dy)(t); }
- void tangente(int k,real lg=1,real ld=lg, pen p=dashed, arrowbar arr=None) {
- draw(((xpt[k],ypt[k])-lg*unit((1,dy[k])))--((xpt[k],ypt[k])+ld*unit((1,dy[k]))),p,arr);
- }
- real xmin=min(xpt), xmax=max(xpt), ymin=min(ypt)-1, ymax=max(ypt)+1;
- graphicrules(xunit=2cm, yunit=2cm, xmin=xmin, xmax=xmax,ymin=ymin,ymax=ymax);
- grid(xStep=1, xstep=.5,
- yStep=1, ystep=.5,
- pTick=.8red,
- ptick=linetype("0 " + string(1mm), offset=0, scale=false, adjust=false)+.7bp+.4white,
- above=false
- );
- cartesianaxis(
- p=currentpen,
- xticks=RightTicks(Label(currentpen+fontsize(8),
- Fill(white)),
- Step=2,
- NoZero,
- pTick=.5mm+blue,ptick=grey),
- yticks=RightTicks(Label(currentpen+fontsize(8),
- align=NE),
- Step=2,
- NoZero,
- pTick=.5mm+blue,ptick=grey),
- viewxaxis=true,
- viewyaxis=true,
- above=true,
- arrow=Arrow
- );
- labeloij(p=1.4bp+.5*red,arrow=Arrow(SimpleHead,8bp),dot);
- // ----- les constructions
- path Cf=graph(f,min(xpt),max(xpt));
- draw(Cf, 1bp+blue);
- for(int k=0; k<xpt.length; ++k) tangente(k,lg=2);
- real marge=.5;
- xlimits(xmin-marge,xmax+marge,Crop);
- ylimits(ymin-marge,ymax+marge,Crop);
- label("$\mathscr{C}_f$",(max(xpt),f(max(xpt))),N);
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' : http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !
Re: Nombre dérivé et courbe.
Bonjour,
Désolé pour la réponse tardive, mais je n'avais pas accès à mon ordinateur.
Ce code va me permettre d'aller plus vite dans la réalisation de mes figures.
Merci beaucoup (et aussi à OG pour ce module).
PS : j'y mettrai un peu moins de couleur !
Désolé pour la réponse tardive, mais je n'avais pas accès à mon ordinateur.
Ce code va me permettre d'aller plus vite dans la réalisation de mes figures.
Merci beaucoup (et aussi à OG pour ce module).
PS : j'y mettrai un peu moins de couleur !
Debian Strech + Asymptote 2.42-12 + Emacs24 + TeXLive 2017