Loi Normale dans les nouveaux programmes de terminale

Règles du forum
ATTENTION ! Il est demandé de ne déposer dans ce forum que des exemples en langage Asymptote
  • finalisés
  • que l'on pense intéressants et optimisés
  • et qui se rapportent au thème du forum.
Si certains exemples déposés donnent lieu à de nombreuses modifications, ils seront déplacés et remplacés par un nouveau sujet dans ce forum avec la ou les meilleures propositions.
Pour les demandes d'aide ... il y a un forum spécifique !
Avatar du membre
GM
Administrateur du site
Administrateur du site
Messages : 1512
Enregistré le : dim. 7 mars 2010, 14:50

Loi Normale dans les nouveaux programmes de terminale

Message non lu par GM » mar. 3 avr. 2012, 23:47

Rappel de la partie Probabilités/Statistique du nouveau programme de terminale S, pour la rentrée 2012 :
bo_probabililtes_statistique_ts_2012.pdf
(192.54 Kio) Téléchargé 1259 fois

Au programme, notamment :
  • Loi normale centrée réduite \mathcal{N}(0,1)
  • Loi normale \mathcal{N} (\mu ,\sigma^2)

--------------------------------------

Pour préparer de jolis cours sur le sujet avec le tandem LATEX/ASYMPTOTE, signalons une fonction peut-être méconnue : erf.

Code : Tout sélectionner

// Notons F la fonction de répartition de la loi normale centrée réduite N(0,1)
// dont l'expression F(x) = 1/sqrt(2\pi) * (intégrale de -inf à x de exp(-t^{2}/2) dt)
// peut s'exprimer aussi à l'aide de la fonction d'erreur de Gauss, notée erf.
// erf(x) = 2/sqrt(\pi) * (intégrale de 0 à x de exp(-t^) dt)
// F(x) est la moyenne de 1 et erf(x/sqrt(2))
// ou encore : erf(x)= 2 F(x sqrt(2)) - 1

real F(real x){ return (1+erf(x/sqrt(2)))/2; }

real x=1.96;
write(F(x));            // donne 0.975 (0.97500210485178)
write(F(-x));           // donne 0.025 (0.0249978951482204)
write(F(x)-F(-x));      // donne 0.95  (0.950004209703559)
write(erf(x/sqrt(2)));  // donne 0.95  (0.950004209703559)

real x=2.58;
write(F(x));            // donne 0.995 (0.950004209703559)
write(F(-x));           // donne 0.005 (0.00494001575777064)
write(F(x)-F(-x));      // donne 0.99  (0.990119968484459)
write(erf(x/sqrt(2)));  // donne 0.99  (0.990119968484459)


On vérifie ci-dessus avec Asymptote les deux valeurs de u_{\alpha} à connaitre (spécifiées dans le nouveau programme de TS).
Image

----------

Application : pour obtenir une table numérique de la fonction de répartition associée à la Loi Normale centrée réduite, telle qu'évoquée ici, voilà :

Figure asymptote c91cd22be816d218c2e204c50c5964a4
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
  1. usepackage("amsmath");
  2. //// Valeurs susceptibles d'êtres modifiées :
  3. real x = 0;
  4. int subdivisions = 10,
  5. nbrlignes = 30;
  6.  
  7. //// Lignes qui ne devraient pas être à modifier :
  8. defaultpen(fontsize(8pt)+.5green);
  9. real y, pas=.1/subdivisions;
  10. int nbrvaleurs = nbrlignes*subdivisions;
  11. size(40*subdivisions,10*(nbrlignes+2),IgnoreAspect);
  12. for(int k=0; k<subdivisions; ++k) label(format("%#.3f",k*pas),(k,subdivisions*2),blue);
  13.  
  14. for(int k=0; k<nbrvaleurs; ++k){
  15. y=(1+erf(x/sqrt(2)))/2;
  16. label(format("%#.5f",y),(k%subdivisions,k%subdivisions-k));
  17. if(k/subdivisions==floor(k/subdivisions)) label(format("%#.1f",x),(-1,k%subdivisions-k),blue);
  18. x=x+pas;
  19. }
  20. label("Exemple : $\displaystyle
  21. \int_{-\infty}^{1,7+0,03}\frac{1}{\sqrt{2\pi}}\text{e}^{-\frac{t^{2}}{2}}dt\approx 0.95818$",
  22. truepoint(S),S,red);


-----------------------

NB :

  • Les exemples précédents atterriront vraisemblablement dans la sous-galerie des fonctions mathématiques.
  • Le sujet est lancé... d'autres messages viendront à la suite de celui-ci sur le même thème de la Loi Normale. Bientôt...
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' : http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !

Avatar du membre
GM
Administrateur du site
Administrateur du site
Messages : 1512
Enregistré le : dim. 7 mars 2010, 14:50

Re: Loi Normale dans les nouveaux programmes de terminale

Message non lu par GM » jeu. 5 avr. 2012, 11:55

Loi Normale centrée réduite : sa fonction densité et la fonction de répartition


Figure asymptote bec09830661ad5de0c36dd35dcdf2e78
*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner
  1. settings.tex="pdflatex";
  2. usepackage("amsmath,amssymb");
  3.  
  4. import geometry;
  5. import graph;
  6. unitsize(2cm,8cm);
  7.  
  8. real mu=0, sig=1;
  9. real b=3.3, a=-b;
  10. real t=95/100,
  11. p1=50/100-t/2,
  12. p2=50/100+t/2;
  13.  
  14. real f(real x){ return 1/(sig*sqrt(2*pi))*exp(-.5*((x-mu)/sig)^2); }
  15. real F(real x){ return (1+erf(x/sqrt(2)))/2; }
  16.  
  17. point[] t1=intersectionpoints(line(0,p1),(path)graph(F,a,b));
  18. point[] t2=intersectionpoints(line(0,p2),(path)graph(F,a,b));
  19.  
  20. fill((graph(f,t1[0].x,t2[0].x,1000))--(t2[0].x,0)--(t1[0].x,0)--cycle,lightblue+opacity(.3));
  21. draw(graph(f,a,b,1000),blue);
  22. draw(graph(F,a,b,1000),dashed+gray);
  23. draw((0,t1[0].y)--t1[0]--(t1[0].x,0),.7bp+blue+linetype("2 2"));
  24. draw((0,t2[0].y)--t2[0]--(t2[0].x,0),.7bp+blue+linetype("2 2"));
  25.  
  26. defaultpen(fontsize(8pt));
  27. label(format("$ %.1f $",p1*100)+"\%",(0,t1[0].y),E,blue);
  28. label(format("$ %.1f $",p2*100)+"\%",(0,t2[0].y),W,blue);
  29. label(format("$\approx %.3f$",t1[0].x),(t1[0].x,0),S,blue);
  30. label(format("$\approx %.3f$",t2[0].x),(t2[0].x,0),S,blue);
  31.  
  32. xaxis(Ticks(NoZero));
  33. yaxis(ymax=1.09,Ticks(NoZero,Step=.5,step=.1));
  34.  
  35. label("$\displaystyle
  36. p\left("+format("%.3f",t1[0].x)+"\leqslant X\leqslant "+format("%.3f",t2[0].x)+"\right)=
  37. F("+format("%.3f",t2[0].x)+")-F("+format("%.3f",t1[0].x)+")=
  38. \int_{"+format("%.3f",t1[0].x)+"}^{"+format("%.3f",t2[0].x)+"}
  39. \tfrac{1}{\sqrt{2\pi}}\text{e}^{-\frac{t^{2}}{2}}\text{d}t\approx "+
  40. format("%.1f",100*t)+"\%$",(0,.25),red);
  41. label("Fonction de r\'epartition $\displaystyle F: x\mapsto \int_{-\infty}^{\,x}f(t)\text{d}t$",
  42. truepoint(NE),SW,gray);
  43. label(minipage("\fbox{Loi Normale centr\'ee r\'eduite $\mathcal{N}(0,1)$}\\[1cm]
  44. $X\hookrightarrow \mathcal{N}(0,1)$\\[1cm]
  45. $X$ suit la loi $\mathcal{N}(\mu ,\sigma^2)$, avec $\mu=0$ et $\sigma=1$\\
  46. de fonction densit\'e $f:x\mapsto \tfrac{1}{\sqrt{2\pi}}\text{e}^{-\frac{x^{2}}{2}}$",
  47. 200pt),truepoint(NW),SE,blue);
Index des fonctions - Exemple de lien donnant le résultat d'une recherche sur les mots 'arc' et 'triple' : http://asy.marris.fr/indexasy/?filtre=arc triple
Mes configurations (le 24/02/21) :
PC n°1 :Windows 10 - Asymptote(2.82)+MikTeX2.9 - Editeurs : Notepad++, TeXworks, Visual Studio Code.
PC n°2 : Ubuntu 20.04LTS - Asymptote(2.67-?? git) + TexLive2020
Mon serveur : Debian Stretch- Asymptote(2.68-16 git) + TexLive2018
Merci de préciser la votre !

StephaneD
Messages : 7
Enregistré le : ven. 2 avr. 2010, 12:35

Re: Loi Normale dans les nouveaux programmes de terminale

Message non lu par StephaneD » jeu. 9 mai 2013, 12:21

Juste un gros merci pour la découverte de la fonction erf, la table et ce superbe dessin (c'est exactement ce que je voulais faire, en mieux :) )!
Stéphane Dutailly

Configuration: Ubuntu 12.04, Emacs 24.2.1, Asymptote 2.16 (installé depuis la logithèque Ubuntu), TexLive 2012

Répondre