size(7.5cm,0);

import flowchart;

block b1=rectangle("Dimanche",(0,3));
block b2=diamond(Label("Copies ?",blue),(0,2),palegreen,red);
block b3=roundrectangle("Corriger",(-1,1));
block b4=bevel("Buller",(1,1));
block b5=circle("Dodo",(0,0));

draw(b1);
draw(b2);
draw(b3);
draw(b4);
draw(b5);

add(new void(frame f, transform t) {
    picture pic;
    draw(pic,
         path(new pair[]{b1.bottom(t),b2.top(t)},Horizontal),
         Arrow,PenMargin);
    draw(pic,Label("Oui",0.5,NW),
         path(new pair[]{b2.left(t),b3.top(t)},Horizontal),
         Arrow,PenMargin);
    draw(pic,Label("Non",0.5,NE),
         path(new pair[]{b2.right(t),b4.top(t)},Horizontal),
         Arrow,PenMargin);
    draw(pic,
         path(new pair[]{b3.bottom(t),b5.left(t)},Vertical),
         Arrow,PenMargin);
    draw(pic,
             path(new pair[]{b4.bottom(t),b5.right(t)},Vertical),
         Arrow,PenMargin);

    add(f,pic.fit());
  });

// REPRISE DE L'EXEMPLE PRECEDENT
// pour simplification de la syntaxe si on compile 
// avec une version 1.91 ou ultérieure d'Asymptote

size(7.5cm,0);

import flowchart;

block b1=rectangle("Dimanche",(0,3));
block b2=diamond(Label("Copies ?",blue),(0,2),palegreen,red);
block b3=roundrectangle("Corriger",(-1,1));
block b4=bevel("Buller",(1,1));
block b5=circle("Dodo",(0,0));

draw(b1);
draw(b2);
draw(b3);
draw(b4);
draw(b5);

add(new void(picture pic, transform t) {
    blockconnector operator --=blockconnector(pic,t);

    b1--Down--Arrow--b2;
    b2--Label("Yes",0.5,NW)--Left--Down--Arrow--b3;
    b2--Right--Label("No",0.5,NE)--Down--Arrow--b4;
    b4--Down--Left--Arrow--b5;
    b3--Down--Right--Arrow--b5;
  });