Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE
GRILLES, REPERES (61)
Liste des figures
Figure fig_aa01_190208_grille
figure 0001
Figure fig_aa02_190208_grille
figure 0002
Figure fig_aa03_190208_grille
figure 0003
Figure fig_aa04_190208_grille
figure 0004
Figure fig_aa05_190208_grille
figure 0005
Figure fig_aa06_270109_grille
figure 0006
Figure fig_aa07_270109_grille
figure 0007
Figure fig_aa08_270109_grille
figure 0008
Figure fig_aa09_270109_grille
figure 0009
Figure fig_ga01_050509_grille
figure 0010
Figure fig_ga02_050509_grille
figure 0011
Figure fig_ga03_050509_grille
figure 0012
Figure fig_ga04_050509_grille
figure 0013
Figure fig_ga05_050509_grille
figure 0014
Figure fig_ga06_050509_grille
figure 0015
Figure fig_ga07_050509_grille
figure 0016
Figure fig_ga08_050509_grille
figure 0017
Figure fig_gp01_190208_grille
figure 0018
Figure fig_gp02_190208_grille
figure 0019
Figure fig_gp03_190208_grille
figure 0020
Figure fig_gp04_190208_grille
figure 0021
Figure fig_gp05_190208_grille
figure 0022
Figure fig_gp06_190208_grille
figure 0023
Figure fig_gr01_180213_grille_avec_axe_decale
figure 0024
Figure fig_gr02_180213_grille_avec_axe_decale
figure 0025
Figure fig_ra01_300109_axes
figure 0026
Figure fig_ra02_300109_axes
figure 0027
Figure fig_ra03_300109_axes
figure 0028
Figure fig_ra04_300109_axes
figure 0029
Figure fig_ra05_300109_axes
figure 0030
Figure fig_ra06_300109_axes
figure 0031
Figure fig_ra07_300109_axes
figure 0032
Figure fig_ra08_300109_axes
figure 0033
Figure fig_ra09_310109_axes
figure 0034
Figure fig_ra10_310109_axes
figure 0035
Figure fig_ra11_310109_axes
figure 0036
Figure fig_ra12_310109_axes
figure 0037
Figure fig_ra13_310109_axes
figure 0038
Figure fig_ra14_310109_axes
figure 0039
Figure fig_sa01_040309_axes
figure 0040
Figure fig_sa02_040309_axes
figure 0041
Figure fig_sa03_040309_axes
figure 0042
Figure fig_sa04_040309_axes
figure 0043
Figure fig_sa05_040309_axes
figure 0044
Figure fig_sa06_040309_axes
figure 0045
Figure fig_sa07_040309_axes
figure 0046
Figure fig_sa08_040309_axes
figure 0047
Figure fig_sa09_040309_axes
figure 0048
Figure fig_xa01_060210_xaxis
figure 0049
Figure fig_xa02_060210_xaxis
figure 0050
Figure fig_xa03_060210_xaxis
figure 0051
Figure fig_xa04_060210_xaxis
figure 0052
Figure fig_xa05_081211_xaxis
figure 0053
Figure fig_xa06_311212_xaxis
figure 0054
Figure fig_xb01_060210_xaxis_tickmodifier
figure 0055
Figure fig_xo01_231211_xaxis_object_label
figure 0056
Figure fig_xo02_231211_xaxis_object_label
figure 0057
Figure fig_xo03_231211_xaxis_object_label
figure 0058
Figure fig_ya01_060210_yaxis
figure 0059
Figure fig_ya02_060210_yaxis
figure 0060
Figure fig_ya03_060210_yaxis
figure 0061
Asymptote - Figure 0001: fig_aa01_190208_grille.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_aa01_190208_grille 
import math;
size(7cm,0);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(grid(7,3));
Asymptote - Figure 0002: fig_aa02_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa02_190208_grille 
import math;
unitsize(1cm,1cm);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(grid(5,3,1bp+red+dotted));

// Pour obtenir un point tous les mm, voir exemple fig_aa06_...
Asymptote - Figure 0003: fig_aa03_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa03_190208_grille 
import math;
size(7cm,0);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(grid(5,3,red+dashed));
Asymptote - Figure 0004: fig_aa04_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa04_190208_grille 
import math;
size(7cm,0);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(grid(5,3,.5bp+blue));

add(shift(4,-3)*grid(2,4,1.2bp+red));

dot("$(0,0)$",(0,0),S,green);
Asymptote - Figure 0005: fig_aa05_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa05_190208_grille 
import math;
size(7cm,0);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(shift(-4,-4)*grid(8,8,blue));

add(rotate(45)*grid(6,6,red));

dot("$(0,0)$",(0,0),S,green);
Asymptote - Figure 0006: fig_aa06_270109_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa06_270109_grille 
import math;
unitsize(1cm,1cm);

pen p=linetype("0 " + string(1mm), offset=0, scale=false, adjust=false);

// picture grid(int Nx, int Ny, pen p=currentpen)
// Return an Nx by Ny unit square lattice with lower-left corner at (0,0).

add(grid(5,3,p));
Asymptote - Figure 0007: fig_aa07_270109_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa07_270109_grille 
import math;
unitsize(1cm,1cm);

pen p(real a) {
    real b=1/a*mm;
    return a+linetype("0 " + string(b), offset=0, scale=true, adjust=false);
}
real a=.1mm;
add(grid(2,1,p(a)));

real a=.2mm;
add(shift((3,0))*grid(2,1,p(a)));

real a=.4mm;
add(shift((0,2))*grid(2,1,p(a)));

real a=.8mm;
add(shift((3,2))*grid(2,1,p(a)));

shipout(bbox(.5cm,Fill(white)));
Asymptote - Figure 0008: fig_aa08_270109_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa08_270109_grille 
import math;
unitsize(1cm,1cm);

pen p(real a) {
    return linetype("0 " + string(a), offset=0, scale=false, adjust=false);
}
real a=.5mm;
add(grid(2,1,p(a)));

real a=1mm;
add(shift((3,0))*grid(2,1,p(a)));

real a=2mm;
add(shift((0,2))*grid(2,1,p(a)));

real a=5mm;
add(shift((3,2))*grid(2,1,p(a)));

shipout(bbox(.5cm,Fill(white)));
Asymptote - Figure 0009: fig_aa09_270109_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa09_270109_grille 
import math;
unitsize(1cm);

pen p=linetype("0 "+ string(1mm),offset=0,scale=false,adjust=false);

add(grid(2,1,p));

add(shift((3,0))*grid(2,1,p+linewidth(.5mm)));

shipout(bbox(.5cm,Fill(white)));
Asymptote - Figure 0010: fig_ga01_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga01_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

// Pour y arriver, en comprenant l'incidence des différents paramètres utilisés
// voilà le premier de 4 exemples démonstratifs (par la couleur) fig_ga1, fig_ga2
// fig_ga3, fig_ga4. Cf. exemple fig_ga5 pour une grille finalisée.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

xaxis(Bottom,green,Ticks("%",extend=true,Step=1,pTick=1bp+red));
yaxis(paleblue);
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0011: fig_ga02_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga02_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

// Pour y arriver, en comprenant l'incidence des différents paramètres utilisés
// voilà le second de 4 exemples démonstratifs (par la couleur) fig_ga1, fig_ga2
// fig_ga3, fig_ga4. Cf. exemple fig_ga5 pour une grille finalisée.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

xaxis(Top,green,Ticks("%",extend=true,Step=1,pTick=1bp+red));
yaxis(Left,paleblue,Ticks("%",extend=true,Step=1,pTick=1bp+gray));
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0012: fig_ga03_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga03_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

// Pour y arriver, en comprenant l'incidence des différents paramètres utilisés
// voilà le troisième de 4 exemples démonstratifs (par la couleur) fig_ga1, fig_ga2
// fig_ga3, fig_ga4. Cf. exemple fig_ga5 pour une grille finalisée.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

xaxis(LeftRight,paleblue,Ticks("%",extend=true,Step=1,pTick=black));
yaxis(BottomTop,3bp+green,Ticks("%",extend=true,Step=1,pTick=2bp+red));
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0013: fig_ga04_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga04_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

// Pour y arriver, en comprenant l'incidence des différents paramètres utilisés
// voilà le quatrième de 4 exemples démonstratifs (par la couleur) fig_ga1, fig_ga2
// fig_ga3, fig_ga4. Cf. exemple fig_ga5 pour une grille finalisée.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

// Par rapport à l'exemple précédent, cette fois on définit d'abord yaxis
// avant xaxis pour montrer l'incidence de l'ordre.
yaxis(LeftRight,paleblue,Ticks("%",extend=true,Step=1,pTick=black));
xaxis(BottomTop,3bp+green,Ticks("%",extend=true,Step=1,pTick=2bp+red));
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0014: fig_ga05_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga05_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

pen p=1bp+gray;
xaxis(BottomTop,p,Ticks("%",extend=true,Step=1,pTick=p));
yaxis(LeftRight,Ticks("%",extend=true,Step=1,pTick=p));
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0015: fig_ga06_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga06_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

pen p=1bp+gray;
xaxis(BottomTop,p,Ticks("%",extend=true,Step=.5,pTick=p));
yaxis(LeftRight,Ticks("%",extend=true,Step=2,pTick=p));
dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0016: fig_ga07_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga07_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

import graph;

unitsize(1cm);
limits((-3,-2),(4,5));

pen p=1bp+gray;
xaxis(BottomTop,p,Ticks("%",extend=true,Step=1,pTick=p));
yaxis(LeftRight,Ticks("%",extend=true,Step=1,pTick=p));
yequals("$x$",0,red,Arrow(HookHead,3bp));
xequals("$y$",0,green,Arrow(HookHead,3bp));

dot((0,0),3bp+blue);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0017: fig_ga08_050509_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ga08_050509_grille 
// Pour réaliser une grille, une possibilité consiste à utiliser
// les commandes xaxis et y axis et l'option extend=true de Ticks
// pour étendre les graduations des axes.

import graph;

unitsize(1cm);

int a=7, b=4;

limits((0,0),(a,b));
pen p=1bp+gray;
xaxis(BottomTop,p,Ticks("%",extend=true,Step=1,pTick=p));
yaxis(LeftRight,Ticks("%",extend=true,Step=1,pTick=p));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0018: fig_gp01_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp01_190208_grille 
import graph_pi;

size(7cm);
scale(false);

grid(xmin=-1, xmax=8,
     ymin=-1, ymax=6,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+.6lightgray,
     ptick=dotted+.4bp+.5green,
     above=false
     );

labeloij(UnFill,dot);
Asymptote - Figure 0019: fig_gp02_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp02_190208_grille 
import graph_pi;

size(7cm);
scale(false);

grid(xmin=-2, xmax=4,
     ymin=-2, ymax=4,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+.6red, ptick=lightblue,
     above=false
     );
labeloij(scale(2)*Mark(5));
Asymptote - Figure 0020: fig_gp03_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp03_190208_grille 
import graph_pi;

size(7cm);
scale(false);

grid(xmin=-2, xmax=4,
     ymin=-2, ymax=4,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+.6red,
     ptick=dashed+.8orange,
     above=false
     );
labeloij(p=1.7bp+.5red,
         arrow=Arrow(7bp),
         dot(0.5*blue)
         );
Asymptote - Figure 0021: fig_gp04_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp04_190208_grille 
import graph_pi;

size(7cm);
scale(false);

real xmin=-2, xmax=4, ymin=-2, ymax=4;
grid(xmin, xmax, ymin, ymax,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+grey, ptick=grey,
     above=false
     );
draw((xmin,0)--(xmax,0)^^(0,ymin)--(0,ymax), 
      1.5bp+0.8*blue);
labeloij(p=1.8bp+.3*blue,
         arrow=Arrow(HookHead(dir=20),8bp,Fill),
         dot(.5*blue));
Asymptote - Figure 0022: fig_gp05_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp05_190208_grille 
import graph_pi;

unitsize(1cm);

// pour définir les pointillés (points espacés de 1mm)
pen p=.3mm+.5white+linetype("0 "+ string(1mm),offset=0,scale=false,adjust=false);

real xmin=-3, xmax=5, ymin=-2, ymax=4;
grid(xmin, xmax, ymin, ymax,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+.7white, 
     ptick=p,
     above=false
     );
draw((xmin,0)--(xmax,0)^^(0,ymin)--(0,ymax),
      1.2bp+0.5*blue);
labeloij(p=1.7bp+.5*red,
         arrow=Arrow(SimpleHead,8bp),
         scale(2)*Mark(5)
         );
Asymptote - Figure 0023: fig_gp06_190208_grille.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_gp06_190208_grille 
import graph_pi;

unitsize(2cm);

// pour définir les pointillés : points espacés de 2mm
// soit 10 points par unité de longueur.
pen p=.4mm+.5white+linetype("0 "+ string(2mm),offset=0,scale=false,adjust=false);

real xmin=-1, xmax=3, ymin=-1, ymax=3;
grid(xmin, xmax, ymin, ymax,
     xStep=1, xstep=.5,
     yStep=1, ystep=.5,
     pTick=.7bp+.7white, 
     ptick=p,
     above=false
     );
draw((xmin,0)--(xmax,0)^^(0,ymin)--(0,ymax),
      1.2bp+0.5*blue);
labeloij(p=1.7bp+.5*red,
         arrow=Arrow(SimpleHead,8bp),
         scale(2)*Mark(5)
         );
Asymptote - Figure 0024: fig_gr01_180213_grille_avec_axe_decale.asy
(Code compilé avec Asymptote version 2.22svn-r5538)
largeur320 Figure fig_gr01_180213_grille_avec_axe_decale 
import graph;
unitsize(.5cm,0.005cm);

real xmin=0,    xmax=12,   xstep=1;
real ymin=4800, ymax=6500, ystep=100;
real[] xi={1,2,3,4,5,6,7,8,9,10};
int[]  yi={5000,5150,5200,5430,5570,5740,5860,6100,6120,6260};
path polygone=graph(xi,yi);
marker croix=marker(scale(2)*cross(4),.6bp+blue);
// draw(polygone,croix);         // points + polygone
   draw(polygone,nullpen,croix); // uniquement les points marqués d'une croix

// La grille... sans les graduations !
xlimits(xmin,xmax);
ylimits(ymin,ymax);
pen pBord=nullpen,
    pGrille=.2mm+linetype("0 "+ string(1mm),offset=0,scale=false,adjust=false);
xaxis(BottomTop,pBord,Ticks("%",Step=5,    step=1,
                                pTick=gray,ptick=pGrille,
                            extend=true));
yaxis(LeftRight,pBord,Ticks("%",Step=500,  step=100,
                                pTick=gray,ptick=pGrille,
                            extend=true));
// Les axes
pen stylo=fontsize(8pt);
// axe horizontal d'équation y=4800
yequals(4800,xmin,xmax+xstep,stylo,
        Ticks(Size=1,end=false,endlabel=false,Step=xstep),
        Arrow);
// axe vertical d'équation x=0
xequals(0,   ymin,ymax+ystep,stylo+red,
        Ticks(Size=1,end=false,endlabel=false,Step=ystep),
        Arrow);

label("$x_i$",(xmax+xstep,ymin),S,stylo);
label("$y_i$",(xmin,ymax+ystep),E,stylo);
Asymptote - Figure 0025: fig_gr02_180213_grille_avec_axe_decale.asy
(Code compilé avec Asymptote version 2.22svn-r5538)
largeur320 Figure fig_gr02_180213_grille_avec_axe_decale 
import graph;

unitsize(.5cm,0.005cm);

real xmin=0, xmax=12, xstep=1;
real ymin=4800, ymax=6500, ystep=100;
real[] xi={1,2,3,4,5,6,7,8,9,10};
int[]  yi={5000,5150,5200,5430,5570,5740,5860,6100,6120,6260};
path polygone=graph(xi,yi);
marker croix=marker(scale(2)*cross(4),.6bp+blue);
draw(polygone,croix);         // points + polygone
// draw(polygone,nullpen,croix); // uniquement les points marqués d'une croix

// La grille... sans les graduations !
xlimits(xmin,xmax);
ylimits(ymin,ymax);
pen pTick=green;
xaxis(BottomTop,pTick,Ticks("%",Step=5,    step=1,
                                pTick=gray,ptick=gray+linetype("4 4"),
                            extend=true));
yaxis(LeftRight,pTick,Ticks("%",Step=500,  step=100,
                                pTick=gray,ptick=gray+linetype("4 4"),
                            extend=true));
// Les axes
pen stylo=fontsize(8pt);
// axe horizontal d'équation y=4700
yequals(4600,xmin,xmax+xstep,stylo,
        Ticks(Size=1,end=false,endlabel=false,Step=xstep),
        Arrow);
// axe vertical d'équation x=12
xequals(12,   ymin,ymax+ystep,stylo+red,
        Ticks(Label(align=E,stylo+purple),Size=1,end=false,endlabel=false,Step=ystep),
        Arrow);

label("$x_i$",(xmax+xstep,4600),S,stylo);
label("$y_i$",(12,ymax+ystep),E,stylo);
Asymptote - Figure 0026: fig_ra01_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra01_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$");

// void yaxis(picture pic=currentpicture, Label L="", axis axis=XZero,
//            real ymin=-infinity, real ymax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
yaxis();

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0027: fig_ra02_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra02_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",Ticks(modify=NoZero));

// void yaxis(picture pic=currentpicture, Label L="", axis axis=XZero,
//            real ymin=-infinity, real ymax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
yaxis("$y$",Ticks(format="%"));

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0028: fig_ra03_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra03_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,Ticks(NoZero));

// void yaxis(picture pic=currentpicture, Label L="", axis axis=XZero,
//            real ymin=-infinity, real ymax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
yaxis("$y$");

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0029: fig_ra04_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra04_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,blue,Ticks(NoZero),Arrow);

// void yaxis(picture pic=currentpicture, Label L="", axis axis=XZero,
//            real ymin=-infinity, real ymax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
yaxis("$y$",ymin=-4,
      Ticks(Ticks=new real[]{-1.7,0.6}));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0030: fig_ra05_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra05_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,blue,Ticks(NoZero,Step=2),Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis("$y$",ymin=-4,
      LeftTicks("%",Ticks=new real[]{-sqrt(2),1.5},Size=1mm,1bp+red));
labely("$-\sqrt2$",-sqrt(2));     
labely("$\frac32$",1.5);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0031: fig_ra06_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra06_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis(Label("$x$",align=Align),xmin=-1.5,blue,Ticks(NoZero,Step=2),Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis("$y$",ymin=-4,Ticks(NoZero,pTick=green));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0032: fig_ra07_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra07_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,blue,Ticks(NoZero,Step=2),Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis("$y$",ymin=-4,
      Ticks(NoZero,endlabel=false,end=false,
            Size=1mm,pTick=green,ptick=blue),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0033: fig_ra08_300109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra08_300109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,blue,Ticks(NoZero,Step=2,step=.25),Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis("$y$",ymin=-4,
      Ticks(NoZero,beginlabel=false,endlabel=false,
            Step=1,step=.25,
            end=false,
            Size=1mm,pTick=red,ptick=paleblue),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0034: fig_ra09_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra09_310109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis("$x$",xmin=-1.5,
      Ticks(NoZero,
            endlabel=false,   // ote le dernier label (5)
            Step=1,step=.25,
            begin=false, // ote la première graduation principale (celle de -1)
            end=false,   // ote la dernière graduation principale (celle de 5)
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
            Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis("$y$",ymin=-4,
      Ticks(NoZero,
            beginlabel=false, // ote le premier label (-4)
            endlabel=false,   // ote le dernier label (2)
            Step=2,step=.125,
            Size=1mm,size=.5mm,
            pTick=red,ptick=paleblue),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0035: fig_ra10_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra10_310109_axes 
/* Le même exemple que le précédent avec :
   - la graduation manquante (-1) restaurée,
   - les labels "x" et "y" repositionnés.   
*/
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)
xaxis(Label("$x$",position=EndPoint,align=Align),
      xmin=-1.5,
      Ticks(NoZero,
            endlabel=false,   // ote le dernier label (5)
            Step=1,step=.25,
            end=false,   // ote la dernière graduation principale (celle de 5)
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
            Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis(Label("$y$",position=EndPoint,align=Align),
      ymin=-4,
      Ticks(NoZero,
            beginlabel=false, // ote le premier label (-4)
            endlabel=false,   // ote le dernier label (2)
            Step=2,step=.125,
            Size=1mm,size=.5mm,
            pTick=red,ptick=paleblue),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0036: fig_ra11_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra11_310109_axes 
/* Le même exemple que le précédent avec :
   - une position différente des labels "x" et "y",
   - le rétablissement des étiquettes -4 et 2 sur (Oy),
   - des étiquettes plus petites sur (Ox).
*/
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xaxis(Label("$x$",position=EndPoint, align=NE),
      xmin=-1.5,
      Ticks(scale(.7)*Label(),
            NoZero,
            endlabel=false,   // ote le dernier label (5)
            Step=1,step=.25,
            end=false,   // ote la dernière graduation principale (celle de 5)
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
            Arrow);

yaxis(Label("$y$",position=EndPoint, align=NE),
      ymin=-4,
      Ticks(NoZero,
            Step=2,step=.125,
            Size=1mm,size=.5mm,
            pTick=red,ptick=paleblue),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0037: fig_ra12_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra12_310109_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xaxis(Label("$x$",position=EndPoint, align=NE),
      xmin=-1.5,
      Ticks(scale(.7)*Label(),
            NoZero,
            endlabel=false,   // ote le dernier label (5)
            Step=1,step=.25,
            end=false,   // ote la dernière graduation principale (celle de 5)
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
            Arrow);

yaxis(Label("$y$",position=EndPoint, align=NE),
      ymin=-3.5,ymax=3.5,
      Ticks(scale(.7)*Label(),
            NoZero,
            Step=1,step=.25,
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0038: fig_ra13_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra13_310109_axes 
// Reprise de l'exemple précédent...
// en passant les étiquettes de l'axe des abscisses au dessus.
// Conséquence : le label "x" est décalé.

import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xaxis(Label("$x$",position=EndPoint, align=NE),
      xmin=-1.5,
      Ticks(scale(.7)*Label(align=W),
            NoZero,
            endlabel=false,   // ote le dernier label (5)
            Step=1,step=.25,
            end=false,   // ote la dernière graduation principale (celle de 5)
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
            Arrow);

yaxis(Label("$y$",position=EndPoint, align=NE),
      ymin=-3.5,ymax=3.5,
      Ticks(scale(.7)*Label(),
            NoZero,
            Step=1,step=.25,
            Size=.8mm, size=.4mm,
            pTick=black,ptick=gray),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0039: fig_ra14_310109_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ra14_310109_axes 
// Reprise de l'exemple précédent... avec les modifications suivantes :
// - position rectifiée du label "x", 
// - des graduations un peu plus visibles.

import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xaxis(Label("$x$",position=EndPoint, align=SE),
      xmin=-1.5,
      Ticks(scale(.7)*Label(align=W),
            Ticks=new real[]{1.5,2.5},
            Size=1mm, size=.5mm,
            pTick=black,ptick=gray),
            Arrow);

yaxis(Label("$y$",position=EndPoint, align=NE),
      ymin=-3.5,ymax=3.5,
      Ticks(scale(.7)*Label(),
            NoZero,
            Step=1,step=.25,
            Size=1mm, size=.5mm,
            pTick=black,ptick=gray),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0040: fig_sa01_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa01_040309_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)

xaxis("$x$",BottomTop(),
            xmin=-1.5,blue,
            Ticks(Step=2),
            Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis(Left(),
      Ticks(Step=1));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0041: fig_sa02_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa02_040309_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// void xaxis(picture pic=currentpicture, Label L="", axis axis=YZero,
//            real xmin=-infinity, real xmax=infinity, pen p=currentpen,
//            ticks ticks=NoTicks, arrowbar arrow=None, bool above=false)

xaxis("$x$",BottomTop(),
            xmin=-1.5,xmax=5.5,blue,
            Ticks(Step=2),
            Arrow);

// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

yaxis(Left(),
      ymin=-3.5,ymax=4.5,red,
      Ticks(Step=1));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0042: fig_sa03_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa03_040309_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// Une reprise de l'exemple précédent
// mais avec inversion de xaxis et yaxis !!

// et on constate la différence...
// qui aide à comprendre le fonctionnement.

yaxis(Left(),
      ymin=-3.5,ymax=4.5,red,
      Ticks(Step=1));

xaxis("$x$",BottomTop(),
            xmin=-1.5,xmax=5.5,blue,
            Ticks(Step=2),
            Arrow);
      
shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0043: fig_sa04_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa04_040309_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// Exemple fig_sa02_040309_axes.asy avec utilisation de
// void ylimits(picture pic=currentpicture, 
//              real min=-infinity, real max=infinity,
//              bool crop=NoCrop)
// pour positionner l'axe des abscisses.

ylimits(min=-3.5,max=4);

xaxis("$x$",BottomTop(),
            xmin=-1.5,xmax=5.5,blue,
            Ticks(Step=2),
            Arrow);

yaxis(Left(),
      ymin=-3.5,ymax=4.5,red,
      Ticks(Step=1));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0044: fig_sa05_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa05_040309_axes 
import graph;

unitsize(1cm);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// Exemple fig_sa03_040309_axes.asy avec utilisation de
// void xlimits(picture pic=currentpicture, 
//              real min=-infinity, real max=infinity,
//              bool crop=NoCrop)
// pour positionner l'axe des ordonnées.

xlimits(min=0);

yaxis(Left(),
      ymin=-3.5,ymax=4.5,red,
      Ticks(Step=1));

xaxis("$x$",BottomTop(),
            xmin=-1.5,xmax=5.5,blue,
            Ticks(Step=2),
            Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0045: fig_sa06_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa06_040309_axes 
import graph;

size(7.5cm,0);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xlimits(min=-1,max=6);

yaxis("$y$",LeftRight(),
            ymin=-3.5,ymax=4.5,red,
            Ticks(Step=1));

xaxis(Bottom(),
      xmin=-1.5,xmax=5.5,blue,
      Ticks(Step=2),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0046: fig_sa07_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa07_040309_axes 
import graph;

size(7.5cm,0);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

xlimits(min=-1,max=6);

yaxis("$y$",LeftRight(),
            ymin=-3.5,ymax=4.5,red,
            Ticks(Step=1));

xaxis(Bottom(),
      xmin=-1.5,xmax=5.5,blue,
      Ticks(Step=2),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0047: fig_sa08_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa08_040309_axes 
import graph;

size(7.5cm,0);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

real minx=-2,maxx=5.5,miny=-3.5,maxy=4.5;

xlimits(min=minx,max=maxx);

yaxis("$y$",LeftRight(),
            ymin=miny,ymax=maxy,red,
            Ticks(Step=1));

xaxis(Bottom(),
      xmin=minx,xmax=maxx,blue,
      Ticks(Step=2),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0048: fig_sa09_040309_axes.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa09_040309_axes 
import graph;

size(7.5cm,0);

path courbe=(.5,2){dir(-30)}..{0}(2.5,-2)..{dir(30)}(5,3);
draw(courbe,red);

// Autre façon de faire : utilisation de LIMITS
// void limits(picture pic=currentpicture, 
//             pair min, pair max, 
//             bool crop=NoCrop)

limits((-2,-3.5),(5.5,4.5));

yaxis("$y$",LeftRight(),
            red,
            Ticks(Step=1));

xaxis(Bottom(),
      blue,
      Ticks(Step=2),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0049: fig_xa01_060210_xaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_xa01_060210_xaxis 
import graph;
unitsize(1cm);

xlimits(min=-3,max=4);

xaxis("$x_1$");

xaxis(axis=YEquals(-2),"$x_2$",Ticks());

xaxis(axis=YEquals(-4),"$x_3$",Ticks(modify=NoZero));

xaxis(axis=YEquals(-6),"$x_4$",RightTicks());

xaxis(axis=YEquals(-8),"$x_5$",LeftTicks(Step=2));

xaxis(axis=YEquals(-10),"$x_6$",LeftTicks(Step=3,step=.25,red));

xaxis(axis=YEquals(-12),"$x_7$",Ticks(Size=.8mm,size=.4mm,blue));

shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0050: fig_xa02_060210_xaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_xa02_060210_xaxis 
import graph;
unitsize(1cm);

xlimits(min=-3,max=3);

xaxis("$x_1$");

xaxis(axis=YEquals(-2),
      Label("$x_2$",align=N),
      Ticks());

xaxis(axis=YEquals(-4),
      Label("$x_3$",position=EndPoint, align=N),
      Ticks(modify=NoZero));

xaxis(axis=YEquals(-6),
      Label("$x_4$",position=EndPoint, align=NE),
      RightTicks());

xaxis(axis=YEquals(-8),
      Label("$x_5$",position=BeginPoint),
      LeftTicks(Step=2));

xaxis(axis=YEquals(-10),
      Label("$x_6$",position=BeginPoint, align=NW),
      LeftTicks(Step=1.5,step=.5,endlabel=false));

shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0051: fig_xa03_060210_xaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_xa03_060210_xaxis 
import graph;
unitsize(1cm);

xaxis("$x_1$",
      xmin=-3,xmax=2,
      Arrow);

xaxis(axis=YEquals(-2),
      Label("$x_2$",align=N),
      xmin=-1,xmax=3,blue,
      Ticks(),
      Arrow);

xaxis(axis=YEquals(-4),
      Label("$x_3$", align=N),
      xmin=-3,xmax=2,red,
      RightTicks(NoZero),
      Arrow);

xaxis(axis=YEquals(-6),
      Label("$x_4$", align=NE),
      xmin=-1,xmax=3,blue,
      RightTicks(Step=3,step=.5,end=false),
      Arrow);

xaxis(axis=YEquals(-8),
      Label("$x_5$", align=NE),
      xmin=-3,xmax=2,red,
      RightTicks(Step=2,step=.25,end=false),
      Arrow);

shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0052: fig_xa04_060210_xaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_xa04_060210_xaxis 
import graph;
unitsize(1cm);

xaxis("$x_1$",
      xmin=-3,xmax=2,
      Ticks(new real[]{0,1},Size=1mm,1bp+red),
      Arrow);

xaxis(axis=YEquals(-2),
      Label("$x_2$",align=N),
      xmin=-1,xmax=3,blue,
      Ticks("%", 
            new real[]{0,1,sqrt(2)},Size=1mm,1bp+red),
      Arrow);
labelx("$\sqrt{2}$",(sqrt(2),-2),N);
          
xaxis(axis=YEquals(-4),
      Label("$x_3$", align=N),
      xmin=-3,xmax=2,red,
      RightTicks("%",
                 new real[]{-1.5,0,1},Size=1mm,1bp+red),
      Arrow);
labelx("$-\frac32$",(-1.5,-4),N);

shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0053: fig_xa05_081211_xaxis.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_xa05_081211_xaxis 
// ticks Ticks(Label format="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             int N=0, int n=0, real Step=0, real step=0,
//             bool begin=true, bool end=true, tickmodifier modify=None,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)

// ticks Ticks(int sign, Label F="", ticklabel ticklabel=null,
//             bool beginlabel=true, bool endlabel=true,
//             real[] Ticks=new real[], real[] ticks=new real[], int N=1,
//             bool begin=true, bool end=true,
//             real Size=0, real size=0, bool extend=false,
//             pen pTick=nullpen, pen ptick=nullpen)
import graph;
unitsize(8cm,1cm);
                   // Par défaut dans graph_settings.asy :
ticksize=1mm;     // 1mm
Ticksize=1.5mm;   // 2*ticksize

real[] GradAvecLabel={0,1/3,2/3,1};
real[] GradSansLabel={1/12,2/12,3/12};

xlimits(min=0,max=1);
xaxis(blue,
      Ticks(ticklabel=Format("%.3f"),
            Ticks=GradAvecLabel,
            ticks=GradSansLabel
           )
);
xaxis(axis=YEquals(-2),
      .9red,
      Ticks(ticklabel=Format("\scriptsize [%.2f]"),
            Ticks=GradAvecLabel,
            ticks=new real[]{5/12,6/12,7/12}
           )
);                   
xaxis(axis=YEquals(-4),
      .5green,
      Ticks(ticklabel=new string(real x){return format("\tiny %.4f",10x);},
            Ticks=new real[]{0,3/12,7/12,11/12,1},
            ticks=GradSansLabel
           )
);
xaxis(axis=YEquals(-6),
      .8pink,
      Ticks(ticklabel=OmitFormat("\scriptsize [%.2f]",1/3),
            Step=1/3,
            step=1/12,
            modify = OmitTick(2/12,11/12),
            pTick=2bp+red, ptick=1bp+blue
           )
);
shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0054: fig_xa06_311212_xaxis.asy
(Code compilé avec Asymptote version 2.22svn-r5538)
largeur320 Figure fig_xa06_311212_xaxis 
import graph;
unitsize(16mm);
 
usepackage("siunitx", "locale=DE");
 
ticksize=3mm;
Ticksize=1.5mm;

xlimits(min=20.5,max=24.5);
xaxis(LeftTicks(Label(align=W,blue),Step=1,blue),Arrow);
 
real[] nb={22.10000123456789, 23.6};
xaxis(nullpen,Ticks(Format("\num{%.7f}"),nb,1bp+red)); // nullpen pour n'ajouter que les graduations !
                                                       // (inutile de tracer une deuxième fois l'axe)
 
shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0055: fig_xb01_060210_xaxis_tickmodifier.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_xb01_060210_xaxis_tickmodifier 
import graph;
size(7.5cm,0);

xlimits(min=-7,max=8);

xaxis("$x_1$",Ticks());

tickmodifier valeurssansgrad;

valeurssansgrad=OmitTick(-2,5);
xaxis(axis=YEquals(-4),"$x_2$",Ticks(valeurssansgrad));

valeurssansgrad=OmitTickInterval(1,5);
xaxis(axis=YEquals(-8),"$x_3$",Ticks(valeurssansgrad));

valeurssansgrad=OmitTickIntervals(new real[]{1,-4},new real[]{5,-2});
xaxis(axis=YEquals(-12),"$x_4$",Ticks(valeurssansgrad));

real[] a={-4,3}, b={-2,5};
valeurssansgrad=OmitTickIntervals(a,b);
xaxis(axis=YEquals(-16),"$x_5$",Ticks(valeurssansgrad));

shipout(bbox(3mm,Fill(white)));
Asymptote - Figure 0056: fig_xo01_231211_xaxis_object_label.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_xo01_231211_xaxis_object_label 
usepackage("esvect");
usepackage("fourier","upright");
import graph;
unitsize(0.75cm);
real u0=-1, r=3;
int n=4;
object objtemp, ui[];
pair   z[];
for(int k=0; k<=n; ++k){
  z.push(u0+k*r);
  objtemp = draw(Label(format("$u_%i$",k),align=N),ellipse,z[k],nullpen);
  ui.push(objtemp);
  label(format("$M_%i$",k),z[k],4S);
}
// Du "deferred drawing" pour le tracé des flèches entre les "objects".
add(new void(picture pic, transform t) {
     for(int k=0; k<n; ++k) 
         draw(pic,Label("$+r$",align=LeftSide),
                  point(ui[k],NE,t){NE}..{S}point(ui[k+1],N,t),
                  Arrow);
});
xaxis(Ticks("%",Step=1,step=1,Size=1mm));
draw("$\vec{i}$",(0,0)--(1,0),1.5bp+red,Arrow(SimpleHead,size=8));
label("$O$",0,S,red);
real abs[]={5,11};
for(real x:abs) labelx(string(x),x,realEpsilon*S);
Asymptote - Figure 0057: fig_xo02_231211_xaxis_object_label.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_xo02_231211_xaxis_object_label 
usepackage("esvect");
usepackage("fourier","upright");
import graph;
unitsize(0.7cm);
real u0=-1, r=3;
int n=4;
object objtemp, ui[];
pair   z[];
int uc[]={2,4}; // rang des termes connus
for(int k=0; k<=n; ++k){
  z.push(u0+k*r);
  bool b; for(int j:uc) if(j==k) b=true;
  if (b) objtemp=draw(Label(format("$u_%i$",k)+format("$=%f$",z[k].x),align=N),
                      ellipse,z[k],red);
  else   objtemp=draw(Label(format("$u_%i$",k),align=N),
                      ellipse,z[k],nullpen);
  ui.push(objtemp);
  label(format("$M_%i$",k),z[k],S);
}
// Du "deferred drawing" pour le tracé des flèches entre les "objects".
add(new void(picture pic, transform t) {
     for(int k=0; k<n; ++k) 
         draw(pic,Label("$+r$",align=LeftSide),
                  point(ui[k],NE,t){NE}..{S}point(ui[k+1],N,t),
                  Arrow);
});
xaxis(Ticks("%",Step=1,step=1,Size=1mm));
draw("$\vec{i}$",(0,0)--(1,0),1.5bp+red,Arrow(SimpleHead,size=8));
label("$O$",0,S,red);
Asymptote - Figure 0058: fig_xo03_231211_xaxis_object_label.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_xo03_231211_xaxis_object_label 
usepackage("esvect");
usepackage("fourier","upright");
import graph;
unitsize(0.27cm);
real u0=2, r=2;
int n=4;
object objtemp, ui[];
pair   z[];
int uc[]={3,4}; // rang des termes connus
for(int k=0; k<=n; ++k){
  z.push(u0*r^k);
  bool b; for(int j:uc) if(j==k) b=true;
  if (b) objtemp=draw(Label(format("$u_%i$",k)+format("$=%f$",z[k].x),align=N),
                      ellipse,z[k],red);
  else   objtemp=draw(Label(format("$u_%i$",k),align=N),
                      ellipse,z[k],nullpen);
  ui.push(objtemp);
  label(format("$M_%i$",k),z[k],S);
}
// Du "deferred drawing" pour le tracé des flèches entre les "objects".
add(new void(picture pic, transform t) {
     for(int k=0; k<n; ++k) 
         draw(pic,Label("$\times q$",align=LeftSide),
                  point(ui[k],NNE,t){N}..{S}point(ui[k+1],N,t),
                  Arrow);
});
xaxis(Ticks("%",Step=1,step=1,Size=1mm));
label("$O$",0,S,red);
Asymptote - Figure 0059: fig_ya01_060210_yaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ya01_060210_yaxis 
import graph;
unitsize(1cm);

ylimits(min=-3,max=4);

yaxis("$y_1$");

yaxis(axis=XEquals(2.2),"$y_2$",Ticks());

yaxis(axis=XEquals(4.4),"$y_3$",Ticks(modify=NoZero));

yaxis(axis=XEquals(6.6),"$y_4$",RightTicks(Step=2));

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0060: fig_ya02_060210_yaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ya02_060210_yaxis 
import graph;
unitsize(1cm);

ylimits(min=-3,max=4);

yaxis(Label("$y_1$",align=E),
      RightTicks(new real[]{0,1,1.5},Size=1mm,1bp+red),
      Arrow);

yaxis(axis=XEquals(2.2),"$y_2$",
      Ticks(),
      Arrow);

yaxis(axis=XEquals(4.4),"$y_3$",
      ymin=-2,ymax=1.5,red,
      Ticks(end=false),
      Arrow);

yaxis(axis=XEquals(6.6),"$y_4$",
      ymax=3,
      RightTicks(Step=3,step=.5,endlabel=false),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Asymptote - Figure 0061: fig_ya03_060210_yaxis.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ya03_060210_yaxis 
import graph;
unitsize(1cm);

ylimits(min=-3,max=4);

yaxis("$y_1$",
      Ticks("%", 
            new real[]{0,1,sqrt(2)},Size=1mm,1bp+red),
      Arrow);
labely("$\sqrt{2}$",(0,sqrt(2)),E);

yaxis(axis=XEquals(2.2),
      Label("$y_2$",align=NE),
      Ticks(begin=false,end=false,
            beginlabel=false,endlabel=false,
            pTick=blue,ptick=gray),
      Arrow);

yaxis(axis=XEquals(4.4),
      Label("$y_3$",align=NE),
      ymin=-1,ymax=3.5,red,
      Ticks(step=.5,end=false),
      Arrow);

yaxis(axis=XEquals(6.6),
      Label("$y_4$",align=NE),
      RightTicks(Step=2,step=.5),
      Arrow);

shipout(bbox(2mm,Fill(white)));
Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE

Dernière modification le Sun Aug 4 11:14:38 CEST 2013 par G.Marris       Valide XHTML