/* Enoncé :
Pour le cercle de centre O ci-contre, 
les cordes [AB] et [CD] ont même longueur.
1. Démontrer que les triangles EAB et ECD sont isométriques.
2. En déduire que la droite (OE) est la médiatrice du segment [BD].
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7.5cm,0);
triangle t1 = triangleabc(5,7,6,angle=-90);
show(t1,LA="$A$",LB="$B$",LC="$D$",La="",Lb="",Lc="");
point C=reflect(bisector(t1.B,t1.C))*t1.A;
triangle t2 = triangle(C,t1.B,t1.C);
show(t2,LA="$C$",LB="",LC="",La="",Lb="",Lc="");
draw(circumcircle(t1));
point O=circumcenter(t1),
      E=extension(t1.A,t1.C,t2.A,t2.B);
dot("$O$",O,S);
dot("$E$",E,NE);
draw(t1.A--t1.B,StickIntervalMarker(1,2));
draw(t2.A--t2.C,StickIntervalMarker(1,2));
addMargins(.5cm,.5cm);

/* Enoncé :
Soit ABC un triangle, M le point d'intersection de la médiatrice Delta
du segment [BC] et de la bissectrice d de l'angle BÂC.
H et K sont les projetés orthogonaux de M sur (AB) et (AC).
1. Démontrer que les triangles MHB et MKC sont isométriques.
2. En déduire l'égalité AB+AC=2AH.
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7.5cm,0);
triangle t1 = triangleabc(2.6,2.2,3.7,angle=-10);
show(t1,LA="$A$",LB="$B$",LC="$C$",La="",Lb="",Lc="",1bp+black);
line d=bisector(t1.VA),
     delta=bisector(t1.BC);
draw(Label("$d$",Relative(1),align=SW),d);
markangle(t1.AB, t1.AC, StickIntervalMarker(2,1));
draw(segment(t1.BC),1bp+blue,StickIntervalMarker(2,2, 0.8*blue));
draw(Label("$\Delta$",Relative(0),align=NW),delta,dashed+.8bp+red);
perpendicularmark(t1.BC,delta);
point M=intersectionpoint(d,delta);
dot("$M$",M,SE);
point K=projection(t1.AC)*M,
      H=projection(t1.AB)*M;
label("$K$",K,NW);
label("$H$",H,SW);
perpendicularmark(t1.AB,line(M,H));
perpendicularmark(t1.AC,line(M,K),quarter=3);
draw(t1.C--K--M--H);
addMargins(.2cm,.2cm);

/* Enoncé : 
Soit (C) un cercle, A un point extérieur à (C),
R et Q les points de (C) tels que (AR) et (AQ) tangentes à (C).
B et C les points respectivement sur [AR] et [AQ] tels que
(BC) soit tangente à (C) en un point noté P.
Déterminer le périmètre du triangle ABC
et montrer qu'il ne dépend pas de la position de P sur l'arc RQ.
*/
import geometry;
usepackage("mathrsfs");
size(7.5cm,0);
triangle t1 = triangleabc(7,8,9,angle=-150);
drawline(t1);
label(t1,alignFactor=2);
circle c1=excircle(t1.BC);draw(c1);
point O=c1.C,
      R=projection(t1.AB)*O,
      P=projection(t1.BC)*O,
      Q=projection(t1.AC)*O;
draw(O--R^^O--P^^O--Q^^O--t1.B^^O--t1.C);
perpendicularmark(t1.AB,line(O,R));
perpendicularmark(t1.BC,line(O,P),quarter=3);
perpendicularmark(t1.AC,line(O,Q),quarter=3);
label("$R$",R,dir(O--R));
label("$P$",P,dir(O--P));
label("$Q$",Q,dir(O--Q));
label("$O$",O,dir(Q--O));
label("$O$",O,dir(Q--O));
draw(Label("$(\mathscr{C})$", Relative(0.6)), c1);
addMargins(.5cm,.5cm);

/* Enoncé :
   A et B sont deux points donnés. On souhaite construire en utilisant
   seulement une règle non-graduée (dont les extrémités sont rongées...)
   et un compas, le point C vérifiant les deux conditions suivantes :
   1) C appartient à (AB) sans appartenir à [AB]
   2) AC = AB/4
   Quel est le nombre minimum d'arcs de cercles (ou de cercles)
   qu'il est nécessaire de tracer pour construire C ?
*/
import geometry;
usepackage("fourier","upright");
size(9cm);

pen   p1=fontsize(10pt)+.5green;
real  a=4;
point pA=(-a/2,0), pB=(a/2,0), pS=2pA-pB;
point M2M3[]=intersectionpoints(circle(pA,a),circle(pB,a));
point M4=intersectionpoint(line(pA,M2M3[1]),line(pS,M2M3[0]));
point M5=intersectionpoint(line(pA,M2M3[0]),line(pS,M2M3[1]));
point pC=intersectionpoint(line(M4,M5),line(pA,pB));

draw(line(pA,pB)); draw(circle(pB,a)); draw(circle(pA,a));
draw(line(M2M3[0],pS)); draw(line(M2M3[1],pS));
draw(line(M2M3[0],pA)); draw(line(M2M3[1],pA));
draw(line(M4,M5));

draw(segment(pB,pC),red,StickIntervalMarker(i=5,n=1,angle=45,size=1mm,
                                            0.8*red,dotframe(red)));
dot("$A$",pA,NE,blue); dot("$B$",pB,NE,blue);
dot("$M_1$",pS,S,p1);
dot("$M_2$",M2M3[0],E,p1); dot("$M_3$",M2M3[1],E,p1);
dot("$M_4$",M4,E,p1); dot("$M_5$",M5,E,p1); dot("$C$",pC,NW,red);

// Une méthode avec un seul cercle existe... mais elle est bien compliquée !