Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE
CERCLES, ARCS DE CERCLE (38)
Liste des figures
Figure fig_aa01_190208_cercle
figure 0001
Figure fig_aa02_210208_cercle
figure 0002
Figure fig_aa03_210208_cercle
figure 0003
Figure fig_aa04_020308_cercle
figure 0004
Figure fig_ab01_220208_cercle
figure 0005
Figure fig_ab02_020308_cercles
figure 0006
Figure fig_ad01_120308_cercle_diametre
figure 0007
Figure fig_ad02_120308_cercle_diametre
figure 0008
Figure fig_ad03_250308_cercle_diametre
figure 0009
Figure fig_ad04_250308_cercle_diametre
figure 0010
Figure fig_at01_250308_tangentes_cercle
figure 0011
Figure fig_at02_250308_tangentes_cercle
figure 0012
Figure fig_at03_250308_tangentes_cercle
figure 0013
Figure fig_at04_290308_tangentes_cercle
figure 0014
Figure fig_at05_290308_tangentes_cercle
figure 0015
Figure fig_ca01_020308_cercle_trigo
figure 0016
Figure fig_ca02_050708_cercle_trigo
figure 0017
Figure fig_ca03_050708_cercle_trigo
figure 0018
Figure fig_cb01_050708_cercle_trigo
figure 0019
Figure fig_cb02_050708_cercle_trigo
figure 0020
Figure fig_cb03_050708_cercle_trigo
figure 0021
Figure fig_cb04_050708_cercle_trigo
figure 0022
Figure fig_cb05_050708_cercle_trigo
figure 0023
Figure fig_cc01_050708_cercle_trigo
figure 0024
Figure fig_cc02_050708_cercle_trigo
figure 0025
Figure fig_pa01_261011_point_sur_cercle
figure 0026
Figure fig_ra01_160308_arc
figure 0027
Figure fig_ra02_160308_arc
figure 0028
Figure fig_ra03_160308_arc
figure 0029
Figure fig_rb01_160308_arc
figure 0030
Figure fig_rc01_160308_arcs
figure 0031
Figure fig_rc02_160308_arcs
figure 0032
Figure fig_rc03_160308_arcs
figure 0033
Figure fig_rc04_160308_arcs
figure 0034
Figure fig_rc05_160308_arcs
figure 0035
Figure fig_sa01_290308_disque
figure 0036
Figure fig_sc01_290308_couronne_circulaire
figure 0037
Figure fig_wa01_210608_cercle
figure 0038
Asymptote - Figure 0001: fig_aa01_190208_cercle.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_aa01_190208_cercle 
size(6cm,0);

// un cercle de rayon 1, centré en O
draw(unitcircle);

// on indique le centre
dot((0,0));
// et le rayon
draw(Label("$r$"),(0,0)--dir(45),Arrow);
Asymptote - Figure 0002: fig_aa02_210208_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa02_210208_cercle 
size(6cm,0);

// un cercle de rayon 1, centré en O
draw(unitcircle);
// et un cercle de rayon 2, centré en O
draw(scale(2)*unitcircle);

// on indique le centre
dot((0,0));
// et le rayon
draw(Label("$r$"),(0,0)--dir(-30),Arrow);
Asymptote - Figure 0003: fig_aa03_210208_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa03_210208_cercle 
size(6cm,0);

// la même figure que précédemment...
draw(unitcircle);
draw(scale(2)*unitcircle);
dot((0,0));
draw(Label("$r$"),(0,0)--dir(-30),Arrow);

// ... en ajoutant un point sur le grand cercle
// de coordonnées polaire (r=2,alpha=150°);
dot(2*dir(150));

// et en fixant une zone minimale d'affichage
fixedscaling((-3,-3),(2.5,1.5));
// Ici la zone d'affichage effective est un rectangle
// défini par les points (-3,-3) et (2.5,2) pour
// permettre l'affichage complet du grand cercle de rayon 2.
Asymptote - Figure 0004: fig_aa04_020308_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_aa04_020308_cercle 
size(6cm,0);
// un cercle de rayon 1, centré en O
draw(unitcircle);
// et un cercle de rayon 2, centré en (1,0)
draw(circle((1,0),2));
// un point pour indiquer le centre du repère
dot((0,0));
// une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0005: fig_ab01_220208_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ab01_220208_cercle 
size(7cm,0);

// Un cercle vert de centre O et de rayon 1
draw(unitcircle,green);
// En rouge, l'image du cercle unitaire par un agrandissement (x2)
draw(scale(2)*unitcircle,red);
// En bleu, l'image du cercle unitaire 
// par la translation de vecteur (1,0).
draw(shift(1,0)*unitcircle,blue);
// En orange, l'image du cercle unitaire par un agrandissement (x2)
// suivie de la translation de vecteur (1,0).
draw(shift(1,0)*scale(2)*unitcircle,1bp+orange);

// et un point pour indiquer le centre du repère
dot("O",(0,0));
// une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0006: fig_ab02_020308_cercles.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ab02_020308_cercles 
size(7cm,0);
import math;
// On définit un style de stylo par défaut
currentpen=.8bp+.3blue;
// On définit trois réels
real r1=3, r2=sqrt(19), r3=7;
pair O=(0,0);
// On définit un cercle, on en trace trois.
path cercle1=circle(O,r1);
draw(cercle1);
draw(circle(O,r2),lightred);
draw(circle(O,r3),currentpen+.8green);
// A point de cercle3 d'abscisse positive dont l'ordonnée est r1
pair A=(sqrt(r3^2-r1^2),r1);
// B point de cercle3 d'abscisse négative dont l'ordonnée est -r2
pair B=(-sqrt(r3^2-r2^2),-r2);
// C point de cercle2 d'ordonnée négative dont l'abscisse est r1
pair C=(r1,-sqrt(r2^2-r1^2));
// D point de cercle3 tel que vec{OD} colinéaire et de même sens que vec{CA} 
pair D=r3*dir(C--A);
// On trace le triangle ABC
draw(A--B--C--cycle);
// on trace la droite (OD) en traçant en fait le segment [MN]
// tel que \vec{OM}=-.5\vec{OD} et \vec{ON}=1.5\vec{OD}
draw(interp(O,D,-0.5)--interp(O,D,1.5),blue);
// On place les points O, A, B, C, D
dot("$O$",O,N,red);
dot("$A$",A,dir(C--A,B--A),red);
dot("$B$",B,dir(C--B,A--B),red);
dot("$C$",C,dir(A--C,B--C),red);
dot("$D$",D,E,red);

shipout(bbox(3mm,white));
Asymptote - Figure 0007: fig_ad01_120308_cercle_diametre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ad01_120308_cercle_diametre 
/* Cercle défini par deux points définissant
   un de ses diamètres.
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7cm,0);

// On définit deux points A et B
point A=(-2,0), B=(4,2);
// et le cercle de diamètre [AB]
path cercle=circle(A,B);

// On trace ce qui a été défini :
show(defaultcoordsys);
dot("$A$",A,dir(B--A),red);
dot("$B$",B,dir(A--B),red);
draw(cercle);
Asymptote - Figure 0008: fig_ad02_120308_cercle_diametre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ad02_120308_cercle_diametre 
/* Cercle défini par deux points définissant
   un de ses diamètres.
*/
import geometry;
size(7cm,0);

// On définit deux points A et B
point pC=(-1,3), pD=(3,-1);
// et le cercle de diamètre [AB]
path c1=circle(pC,pD);

// On trace ce qui a été défini :
show(defaultcoordsys);
dot("$C$",pC,dir(pD--pC),red);
dot("$D$",pD,dir(pC--pD),red);
draw(c1,1bp+blue);

// On ajoute le centre du cercle
dot("$\Omega$",(pC+pD)/2,green);

// Une marge de 1cm
addMargins(1cm,1cm);
Asymptote - Figure 0009: fig_ad03_250308_cercle_diametre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ad03_250308_cercle_diametre 
/* Le même exemple que précédemment..
   en utilisant le type "circle" de l'extension geometry
   et sa notation "cercle.C" pour placer le centre.
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7cm,0);

// Le cercle de diamètre les points (-1,3) et (3,-1)
circle c1=circle((-1,3),(3,-1));
// On trace le repère et le cercle...
show(defaultcoordsys);
draw(c1,1bp+blue);
// ... et on ajoute le centre :
dot("$\Omega$",c1.C,green);

// Une marge de 1cm
addMargins(1cm,1cm);
Asymptote - Figure 0010: fig_ad04_250308_cercle_diametre.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ad04_250308_cercle_diametre 
/* Cercle dont on connait un diamètre
   et deux tangentes passant par un point donné.
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7cm,0);

// On définit, 3 points, le cercle de diamètre [AB].
point A=(-1,2),B=(3,0),M=(2.5,4.5);
circle cerc=circle(A,B);
// On trace le repère, M, le cercle, son centre.
show(defaultcoordsys);
dot("$M$",M,SE,blue);
draw(cerc,.9bp+red);
dot("$\Omega$",cerc.C,S,blue);
draw(A--B);dot(A--B);
// Tableau des éventuelles tangentes au cercle
// passant par le point M...
line[] tang=tangents(cerc,M);
// ... et on trace les deux tangentes :
draw(tang[0],dashed+.8bp+black);
draw(tang[1],dashed+.8bp+green);

// Une marge de 1cm
addMargins(.5cm,.5cm);
Asymptote - Figure 0011: fig_at01_250308_tangentes_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_at01_250308_tangentes_cercle 
/* Cercle défini par centre et rayon
   et une première façon de définir une tangente
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

unitsize(1cm);
// On définit...
circle cerc=circle((0,0),3);
line T1=tangent(cerc,Relative(0)),
     T2=tangent(cerc,Relative(0.5)), // 1/2 tour
     T3=tangent(cerc,Relative(0.75)), // 3/4 de tour 
     T4=tangent(cerc,Relative(1)), // 1 tour
     T5=tangent(cerc,Relative(1.25)),
     T6=tangent(cerc,Relative(-2.2));
point pT6=point(cerc,Relative(-2.2));
// ... et on dessine :
draw(cerc);
dot("$\Omega$",cerc.C,S,blue);
distance("$R=3$",cerc.C,point(cerc,0),0);
draw(Label("$T_0$",Relative(0.8),align=E),T1,.8bp+red);
draw(Label("$T_{0,5}$",Relative(0.8),align=W),T2,.8bp+blue);
draw(Label("$T_{0,75}$",Relative(0.7),align=S),T3,.8bp+green);
draw(Label("$T_{1}$",Relative(0.7),align=E),T4,.8bp+.8red);
draw(Label("$T_{1,25}$",Relative(0.8),align=N),T5,.8bp+.8green);
draw(Label("$T_{-2,2}$",Relative(0.9),align=SE),T6,.8bp+.8blue);
dot("$A$",pT6,N);
// Ajout d'une marge
addMargins(.5cm,.5cm);
Asymptote - Figure 0012: fig_at02_250308_tangentes_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_at02_250308_tangentes_cercle 
/* Cercle défini par centre et rayon
   et une deuxième façon de définir une tangente
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

unitsize(1cm);
// On définit...
circle cerc=circle((0,0),3);
line T0=tangent(cerc,curabscissa(0)),
     T1=tangent(cerc,curabscissa(pi)),
     T2=tangent(cerc,curabscissa(2*pi)),
     T3=tangent(cerc,curabscissa(3*pi)),
     T4=tangent(cerc,curabscissa(4*pi)),
     T5=tangent(cerc,curabscissa(5*pi)),
     T6=tangent(cerc,curabscissa(6*pi));         
point pT4=point(cerc,curabscissa(4*pi));
// ... et on dessine :
draw(cerc);
dot("$\Omega$",cerc.C,S,blue);
distance("$R=3$",cerc.C,point(cerc,0),0);
draw(Label("$T_0$",Relative(0.5),align=NE),T0,.8bp+red);
draw(Label("$T_{\pi}$",Relative(0.5),align=NE),T1,.8bp+blue);
draw(Label("$T_{2\pi}$",Relative(0.5),align=NW),T2,.8bp+green);
draw(Label("$T_{3\pi}$",Relative(0.5),align=W),T3,.8bp+.8red);
draw(Label("$T_{4\pi}$",Relative(0.5),align=SW),T4,.8bp+.8green);
draw(Label("$T_{5\pi}$",Relative(0.5),align=SE),T5,.8bp+.8blue);
draw(Label("$T_{6\pi}$",Relative(0.5),align=SE),T6,.8bp+.8red);
dot("$A$",pT4,N);
// Ajout d'une marge
addMargins(.5cm,.5cm);
Asymptote - Figure 0013: fig_at03_250308_tangentes_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_at03_250308_tangentes_cercle 
/* Cercle défini par centre et rayon
   et une troisième façon de définir une tangente
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

unitsize(1cm);
// On définit...
circle cerc=circle((0,0),3);

line T0=tangent(cerc,angabscissa(0)),
     T45=tangent(cerc,angabscissa(45)),
     T120=tangent(cerc,angabscissa(120)),
     T60=tangent(cerc,angabscissa(-60)),
     T150=tangent(cerc,angabscissa(-150));               
// angabscissa(real) renvoie une abscisse angulaire
point pT120=point(cerc,angabscissa(120));

// ... et on dessine :
draw(cerc);
dot("$\Omega$",cerc.C,S,blue);
distance("$R=3$",cerc.C,point(cerc,0),0);
draw(Label("$T_0$",Relative(0.9),align=E),T0,.8bp+red);
draw(Label("$T_{45}$",Relative(0.7),align=NE),T45,.8bp+green);
draw(Label("$T_{120}$",Relative(0.9),align=NW),T120,.8bp+blue);
draw(Label("$T_{-60}$",Relative(0.2),align=SE),T60,.8bp+blue);
draw(Label("$T_{-150}$",Relative(0.9),align=SW),T150,.8bp+green);
dot("$A$",pT120,S);
// Ajout d'une marge
addMargins(.5cm,.5cm);
Asymptote - Figure 0014: fig_at04_290308_tangentes_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_at04_290308_tangentes_cercle 
/* Cercle défini par centre et rayon
   et une quatrième façon de définir une tangente
*/
import geometry;
unitsize(1cm);
// On définit...
circle cerc=circle((0,0),3);
point A=(1,2), B=(-3,3);
line TA=tangent(cerc,A),
     TB=tangent(cerc,B);

// ... et on dessine :
draw(cerc);
dot("$\Omega$",cerc.C,S,blue);
dot("$A$",A,NW); dot("$B$",B,N);
draw(A--cerc.C--B,dashed);
distance("$R=3$",cerc.C,point(cerc,0),0);
draw(Label("$T_1$",Relative(0.9),align=NE),TA,.8bp+red);
draw(Label("$T_2$",Relative(0.9),align=NW),TB,.8bp+green);

// Ajout d'une marge
addMargins(.5cm,.5cm);
Asymptote - Figure 0015: fig_at05_290308_tangentes_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_at05_290308_tangentes_cercle 
/* L'exemple précédent avec ajout
   des points du cercle relatifs aux tangentes,
   des angles droits.
*/
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

unitsize(1cm);
// On définit...
circle cerc=circle((0,0),3);
point A=(1,2), B=(-3,3);
line TA=tangent(cerc,A),
     TB=tangent(cerc,B);
point pTA=point(cerc,A),
      pTB=point(cerc,B);
// ... et on dessine :
draw(cerc);
dot("$\Omega$",cerc.C,S,blue);
dot("$A$",A,NW); dot("$B$",B,N);
draw(pTA--cerc.C--B,dashed);
distance("$R=3$",cerc.C,point(cerc,0),0);
draw(Label("$T_1$",Relative(0.9),align=NE),TA,.8bp+red);
draw(Label("$T_2$",Relative(0.9),align=NW),TB,.8bp+green);
dot("$A'$",pTA,NE); dot("$B'$",pTB,E);
perpendicularmark(line(cerc.C,pTA),TA,quarter=3);
perpendicularmark(line(cerc.C,pTB),TB);

// Ajout d'une marge
addMargins(.5cm,.5cm);
Asymptote - Figure 0016: fig_ca01_020308_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca01_020308_cercle_trigo 
size(7.5cm,0);
import geometry;

pair O=(0,0), pI=(1,0), pJ=(0,1);
dot("$O$",O,SW);
draw(unitcircle);

real angle1=63, angle2=130;
pair pM=dir(angle1), pN=dir(angle2);
draw(pJ--O--pI--pM--O--pN--pM);

draw("$\alpha$",arc(pI,O,pM,0.15),blue,Arrow);
draw("$\beta$",arc(pI,O,pN,0.3),blue,Arrow);
pair pcos1=(Cos(angle1),0), psin2=(0,Sin(angle2));
draw(pM--pcos1^^pN--psin2,blue);
perpendicular(pcos1,NE,blue);
perpendicular(psin2,SW,blue);

dot(scale(.7)*"$(\cos\alpha,\sin\alpha)$",pM,dir(O--pM));
dot(scale(.7)*"$(\cos\beta,\sin\beta)$",pN,dir(O--pN));
dot(scale(.7)*"$\cos\alpha$",pcos1,dir(pM--pcos1));
dot(scale(.7)*"$\sin\beta$",psin2,dir(pN--psin2));
Asymptote - Figure 0017: fig_ca02_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca02_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; // extension provisoire de Ph.Ivaldi dont certaines macros
// pourraient intégrer un jour la version officielle Asymptote.
// On en utilise ci-dessous la fonction texfrac.

draw(unitcircle);

// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
int k=8; // nombre de points particuliers sur le cercle
int d=-1; // paramètre pour définir le point de départ des valeurs
// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

real a=360/k;
for (int i=0; i<k; ++i)
  {
    pair pC=dir((i+d)*a);
    label(texfrac(2*(i+d),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC,dashed);
  }
draw((1,0)--(0,0)--(0,1),blue,Arrows(HookHead));
Asymptote - Figure 0018: fig_ca03_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_ca03_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; // extension provisoire de Ph.Ivaldi dont certaines macros
// pourraient intégrer un jour la version officielle Asymptote.
// On en utilise ci-dessous la fonction texfrac.

draw(unitcircle);

// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
int k=12; // nombre de points particuliers sur le cercle
int d=0; // paramètre pour définir le point de départ des valeurs
// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

real a=360/k;
for (int i=0; i<k; ++i)
  {
    pair pC=dir((i+d)*a);
    label(texfrac(2*(i+d),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC,dashed);
  }
draw((1,0)--(0,0)--(0,1),blue,Arrows(HookHead));
Asymptote - Figure 0019: fig_cb01_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cb01_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; 

draw(unitcircle);

int k=24;
real a=360/k;
for (int i=0; i<k; ++i)
  {
    if (i==0 || (pgcd(i,2)!=1 || pgcd(i,3)==3)) {
    pair pC=dir((i)*a);
    label(texfrac(2*(i),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC);
    }
  }
Asymptote - Figure 0020: fig_cb02_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cb02_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; 

draw(unitcircle);

int k=24;
real a=360/k;
for (int i=-11; i<k-11; ++i)
  {
    if (i==0 || (pgcd(i,2)!=1 || pgcd(i,3)==3)) {
    pair pC=dir((i)*a);
    label(texfrac(2*(i),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC);
    }
  }
Asymptote - Figure 0021: fig_cb03_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cb03_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; 

draw(unitcircle);

int k=24;
real a=360/k;
for (int i=-11; i<k-11; ++i)
{
  if (i==0 || (pgcd(i,2)!=1 || pgcd(i,3)==3)) {
    pair pC=dir((i)*a);
    label(texfrac(2*(i),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC);
  }
}
for (int j=30; j<=60; j+=15)
{
  draw(dir(j)--dir(180-j)--dir(j-180)--dir(-j)--cycle,dashed);
}
Asymptote - Figure 0022: fig_cb04_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cb04_050708_cercle_trigo 
size(7.5cm,0);
import base_pi; 

defaultpen(fontsize(12pt)+blue); // Stylo par défaut
pen p=fontsize(8pt)+black;  // Un stylo particulier 

draw(unitcircle);

int k=24;
real a=360/k;
for (int i=-11; i<k-11; ++i)
{
  if (i==0 || (pgcd(i,2)!=1 || pgcd(i,3)==3)) {
    pair pC=dir((i)*a);
    label(texfrac(2*(i),k,factor="\pi"),pC,align=pC);
    draw((0,0)--pC);
  }
}
for (int j=30; j<=60; j+=15)
{
  draw(dir(j)--dir(180-j)--dir(j-180)--dir(-j)--cycle,dashed);
}
label("$\frac{1}{2}$",(.5,0),align=S,p,Fill(white));
label("$-\frac{1}{2}$",(-.5,0),align=S,p,Fill(white));
label("$\frac{1}{2}$",(0,.5),align=E,p,Fill(white));
label("$-\frac{1}{2}$",(0,-.5),align=E,p,Fill(white));
label("$\frac{\sqrt2}{2}$",(.707,0),align=N,p,Fill(white));
label("$-\frac{\sqrt2}{2}$",(-.707,0),align=N,p,Fill(white));
label("$\frac{\sqrt2}{2}$",(0,.707),align=W,p,Fill(white));
label("$-\frac{\sqrt2}{2}$",(0,-.707),align=W,p,Fill(white));
label("$\frac{\sqrt3}{2}$",(.866,0),align=S,p,Fill(white));
label("$-\frac{\sqrt3}{2}$",(-.866,0),align=S,p,Fill(white));
label("$\frac{\sqrt3}{2}$",(0,.866),align=E,p,Fill(white));
label("$-\frac{\sqrt3}{2}$",(0,-.866),align=E,p,Fill(white));
Asymptote - Figure 0023: fig_cb05_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cb05_050708_cercle_trigo 
size(10cm,0);
import base_pi; 

defaultpen(fontsize(12pt)+blue); // Stylo par défaut
pen p=fontsize(8pt)+black;  // Un stylo particulier 

draw(unitcircle);
path axecos = (-1,0)--(1.5,0),
     axesin = (0,-1)--(0,1.5),
     axetan = (1,-1.2)--(1,1.9);
draw(axecos,Arrow());
draw(axesin,Arrow());
draw(axetan,Arrow());
pair t30 = extension((0,0),dir(30),(1,0),(1,1)),
     t45 = extension((0,0),dir(45),(1,0),(1,1)),
     t60 = extension((0,0),dir(60),(1,0),(1,1));
draw(dir(30)--t30^^dir(45)--t45^^dir(60)--t60,dashed);

int k=24;
real a=360/k;
for (int i=-11; i<k-11; ++i)
{
  if (i==0 || (pgcd(i,2)!=1 || pgcd(i,3)==3)) {
    pair pC=dir((i)*a);
    label(texfrac(2*(i),k,factor="\pi"),pC,align=pC,Fill(white));
    draw((0,0)--pC);
  }
}
for (int j=30; j<=60; j+=15)
{
  draw(dir(j)--dir(180-j)--dir(j-180)--dir(-j)--cycle,dashed);
}

label("$\frac{1}{2}$",(.5,0),align=S,p,Fill(white));
label("$-\frac{1}{2}$",(-.5,0),align=S,p,Fill(white));
label("$\frac{1}{2}$",(0,.5),align=E,p,Fill(white));
label("$-\frac{1}{2}$",(0,-.5),align=E,p,Fill(white));
label("$\frac{\sqrt2}{2}$",(.707,0),align=N,p,Fill(white));
label("$-\frac{\sqrt2}{2}$",(-.707,0),align=N,p,Fill(white));
label("$\frac{\sqrt2}{2}$",(0,.707),align=W,p,Fill(white));
label("$-\frac{\sqrt2}{2}$",(0,-.707),align=W,p,Fill(white));
label("$\frac{\sqrt3}{2}$",(.866,0),align=S,p,Fill(white));
label("$-\frac{\sqrt3}{2}$",(-.866,0),align=S,p,Fill(white));
label("$\frac{\sqrt3}{2}$",(0,.866),align=E,p,Fill(white));
label("$-\frac{\sqrt3}{2}$",(0,-.866),align=E,p,Fill(white));

label("\begin{minipage}{1.5cm}
           \centering axe des\\ cosinus
        \end{minipage}",(1.4,0),align=N,p,Fill(white));
label("\begin{minipage}{1.3cm}
           \centering axe des\\ sinus
       \end{minipage}",(0,1.4),align=W,p,Fill(white));
label("\begin{minipage}{1.4cm}
           \centering axe des\\ tangentes
       \end{minipage}",(1,1.9),align=W,p,Fill(white));
label("$\sqrt3$",(1,1.73),align=E,p,Fill(white));
label("$1$",(1,1),align=E,p,Fill(white));
Asymptote - Figure 0024: fig_cc01_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cc01_050708_cercle_trigo 
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))

size(7.5cm,0);
show(currentcoordsys);
circle C=circle((0,0),1);
draw(C, linewidth(bp));
point pA=curpoint(C,pi/3),
      pB=curpoint(C,-pi/6),
      pC=curpoint(C,3pi/4),
      pD=curpoint(C,-2pi/3),
      pE=curpoint(C,pi);
pen p1=5bp+blue, p2=dashed;
dot(pA,p1); draw(pA--projection(Ox)*pA,p2);
dot(pB,p1); draw(pB--projection(Oy)*pB,p2);
dot(pC,p1); draw(pC--(0,0),p2);
dot(pD,p1); draw(pD--projection(Ox)*pD,p2);
dot(pE,p1); 

markangle(Oy,Ox,StickIntervalMarker(2,2,true));

draw((0,0)--(1,0),invisible,StickIntervalMarker());
draw((0,0)--(0,1),invisible,StickIntervalMarker());
draw((0,0)--(-1,0),invisible,StickIntervalMarker());

addMargins(.5cm,.5cm);
Asymptote - Figure 0025: fig_cc02_050708_cercle_trigo.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_cc02_050708_cercle_trigo 
// import geometry_dev; // extension devenue l'extension geometry officielle
import geometry;        // le 12/05/09, dans la version 1.71 d'asymptote. :-))
import markers;
size(7.5cm,0);
show(currentcoordsys);
circle C=circle((0,0),1);
draw(C,.4bp+black);
point pA=curpoint(C,pi/4),
      pB=curpoint(C,-pi/3),
      pC=curpoint(C,5pi/6),
      pD=curpoint(C,-2pi/3),
      pE=curpoint(C,-pi/2),
      pF=curpoint(C,pi/6),
      pG=curpoint(C,-3pi/4),
      pH=curpoint(C,pi);      
pen p1=5bp+blue, p2=dashed;
dot(pA,p1); draw(pA--(0,0),p2);
dot("$-\frac{\pi}{3}$",pB,SE,p1); draw(pB--projection(Ox)*pB,p2);
dot("$\frac{5\pi}{6}$",pC,NW,p1); draw(pC--projection(Oy)*pC,p2);
dot(pD,p1); draw(pD--projection(Ox)*pD,p2);
dot(pE,p1); 
dot(pF,p1); draw(pF--projection(Oy)*pF,p2);
dot(pG,p1); draw(pG--(0,0),p2);
dot(pH,p1); 

markangle(Ox,Oy,StickIntervalMarker(2,3,size=2mm,space=1mm,true,gray));

draw((0,0)--(1,0),invisible,
     StickIntervalMarker(2,2,angle=45,size=2mm,space=1mm,gray));
draw((0,0)--(0,1),invisible,
     StickIntervalMarker(2,2,angle=45,size=2mm,space=1mm,gray));
draw((0,0)--(-1,0),invisible,
     StickIntervalMarker(2,2,angle=45,size=2mm,space=1mm,gray));

addMargins(.5cm,.5cm);
Asymptote - Figure 0026: fig_pa01_261011_point_sur_cercle.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_pa01_261011_point_sur_cercle 
size(7.5cm,0);
path C=unitcircle;
draw(Label("(C)",Relative(2/3),align=SW),C);

real a=0.72, b=1.8888881111;

pair pA=point(C,a),
     pB=point(C,b),
     pI=extension(pA,pA+dir(C,a),pB,pB+dir(C,b));
     
path p1 = subpath(C,b,a){unit(pA)}..{-unit(pB)}pB--cycle; // pour un chemin (C) quelconque
filldraw(p1,paleblue);                                    // remplacer : unit(pA)
path p2 = subpath(C,b,a){-unit(pA)}..{unit(pB)}pB--cycle; // par : unit(-accel(C,a))
filldraw(p2,palegreen);

dot(format("$A_{%.3f}$",a),pA,unit(pA),4bp+blue);
dot(format("$B_{%.3f}$",b),pB,unit(pB),4bp+blue);

for (real k=0; k<length(C); k+=1)
  dot(Label(format("%.3f",k)),point(C,k),unit(accel(C,k)),4bp+red);

draw(circle(pI,abs(pA-pI)),red+dashed);
  
label(format("nombre de noeuds du chemin (C) = %i",size(C)),truepoint(S),2S);
label(format("nombre de sections du chemin (C) = %i",length(C)),truepoint(S),S);
label(format("longueur du chemin (C) = %.10f",arclength(C)),truepoint(S),S);
Asymptote - Figure 0027: fig_ra01_160308_arc.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_ra01_160308_arc 
size(7cm,0);
dot("O",(0,0),SW);
// Arc de cercle de centre (0,0), de rayon 4
// débutant au point d'angle polaire 0° 
// et finissant au point d'angle polaire 30°
draw(arc((0,0),4,0,30),1bp+red);
Asymptote - Figure 0028: fig_ra02_160308_arc.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_ra02_160308_arc 
size(7cm,0);
// On place l'origine du repère.
dot("O",(0,0),SW);
// On définit un point A que l'on place également.
pair A=(1,1); dot("A",A,W);
// On définit une valeur de rayon.
real r=4;
// Arc de cercle de centre A, de rayon r
// débutant au point d'angle polaire 0° 
// et finissant au point d'angle polaire -30°
// relativement au point A !
draw(arc(A,r,0,-30),1bp+red);
// Tracé de deux rayons pour mieux voir.
draw(A+r*E--A--A+r*dir(-30),dashed+green);
// Rappel : E=(1,0) et dir(-30)=(cos(-30°);sin(-30°))
Asymptote - Figure 0029: fig_ra03_160308_arc.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_ra03_160308_arc 
size(7cm,0);
// On place l'origine du repère.
dot("O",(0,0),SW);
// On définit trois points que l'on place également.
pair A=(0,1); dot("$A$",A,W);
pair B=(3,0); dot("$B$",B,SW);
pair C=(2,1.5); dot("$C$",C,NW);
// Arc de cercle de centre A, de rayon AB
// débutant en B 
// et finissant au point M de [AC) tel que AM=AB.
draw(arc(A,B,C),1bp+blue);
// Tracé de deux segments pour mieux voir.
draw(B--A--C,dashed+green);
// une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0030: fig_rb01_160308_arc.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rb01_160308_arc 
size(7cm,0);
// On définit un réel et trois points.
real h=5;
pair O=(0,0),A=(-h,0),B=(h,0);
// On trace le demi-cercle de diamètre [AB]
// en tournant dans le sens direct de B vers A.
draw(arc(O,B,A),1bp+blue);
// Tracé du diamètre [AB].
draw(A--B,dashed+green);
// Et on ajoute les points.
dot(O);
dot("$A$",A,SW);
dot("$B$",B,SE);
// une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0031: fig_rc01_160308_arcs.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rc01_160308_arcs 
size(7cm,0);
filldraw(buildcycle(arc((0,0),4,0,180),
                    arc((-1,0),3,0,180),
                    arc((3,0),1,0,180)),
         lightgrey,red
         );
Asymptote - Figure 0032: fig_rc02_160308_arcs.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rc02_160308_arcs 
size(7cm,0);
filldraw(buildcycle(arc((0,0),4,0,180),
                    arc((-1,0),3,0,180),
                    arc((2,0),2,0,180)),
         lightgrey,red
         );
Asymptote - Figure 0033: fig_rc03_160308_arcs.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rc03_160308_arcs 
import patterns;
size(7cm,0);
pair O=(0,0),A1=(-1,0),A2=(3,0);
real r=4, r1=3, r2=1;
path chemin=buildcycle(arc(O,r,0,180),arc(A1,r1,0,180),arc(A2,r2,0,180));
add("hachure",crosshatch(H=2mm,lightgray));
filldraw(chemin,pattern("hachure"),1bp+blue);
Asymptote - Figure 0034: fig_rc04_160308_arcs.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rc04_160308_arcs 
size(7cm,0);
// On définit...
pair O=(0,0),A1=(-1,0),A2=(3,0);
real r=4, r1=3, r2=1;
path chemin=buildcycle(arc(O,r,0,180),arc(A1,r1,0,180),arc(A2,r2,0,180));
pen stylo=1bp+blue, pinceau=lightgrey;
// ... puis on dessine.
filldraw(chemin,pinceau,stylo);
draw(A1+r1*W--A2+r2*E,dashed+red);
dot(O);draw(Label("$r$"),O--r*dir(60),Arrow);
dot(A1);draw(Label("$r_1$"),A1--A1+r1*dir(90),Arrow);
dot(A2);draw(Label("$r_2$"),A2--A2+r2*dir(120),Arrow);
// une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0035: fig_rc05_160308_arcs.asy
(Code compilé avec Asymptote version 2.14svn)
largeur320 Figure fig_rc05_160308_arcs 
size(7cm,0);
real h=5;
pair O=(0,0),A=(h,0),B=(-h,0);
// M(r=h,theta=70) point du cercle de diamètre [AB]
pair M=h*dir(70);
// H, projeté orthogonal de M sur l'axe (AB) des abscisses
pair H=(M.x,0);
// On définit le centre des demi-cercles.
pair A1=(A+H)/2, B1=(B+H)/2;
// On définit les stylos qui seront utilisés.
pen stylo=1bp+blue, pinceau=lightgrey;
// On définit les arcs de cercles.
path dc=arc(O,A,B),dca=arc(A1,A,H),dcb=arc(B1,H,B);
// ... et on trace le tout :
filldraw(buildcycle(dc,dca,dcb),pinceau,stylo);
dot(O); dot("$M$",M,dir(O--M));
draw(A--B^^O--M--H^^A--M--B,dashed);
// en ajoutant deux points d'intersection...
dot("$N$",intersectionpoint(reverse(dca),M--A),N);
dot("$P$",intersectionpoint(dcb,M--B),N);
// ... une bordure blanche de 3mm autour de l'image
shipout(bbox(3mm,white));
Asymptote - Figure 0036: fig_sa01_290308_disque.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sa01_290308_disque 
size(4.5cm,0);
import patterns;
//settings.outformat="pdf";

add("hachure1",hatch(H=1mm,dir=N,p=green));
add("hachure2",hatch(H=2mm,dir=SW,p=red));
add("hachure3",hatch(H=3mm,dir=SE,p=blue));
add("hachure4",hatch(H=4mm,dir=S,p=yellow));

real a=2.5;
filldraw(unitcircle,pattern("hachure1"),1bp+lightgreen);
filldraw(shift(a,0)*unitcircle,pattern("hachure2"),1bp+lightred);
filldraw(shift(0,-a)*unitcircle,pattern("hachure3"),1bp+lightblue);
filldraw(shift(a,-a)*unitcircle,pattern("hachure4"),1bp+lightyellow);

//shipout(bbox(3mm,white));
//shipout(bbox(2mm,invisible),"pdf");
Asymptote - Figure 0037: fig_sc01_290308_couronne_circulaire.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_sc01_290308_couronne_circulaire 
size(7cm,0);

path[] couronne={circle((0,0),1.5), reverse(unitcircle)};
fill(couronne,red+zerowinding);

shipout(bbox(3mm,white));
Asymptote - Figure 0038: fig_wa01_210608_cercle.asy
(Code compilé avec Asymptote version 1.95svn)
largeur320 Figure fig_wa01_210608_cercle 
size(6cm,0);

pen[] p={red,green,blue,magenta};
tensorshade(unitcircle,p);
Page Asymptote du site référent / Page d'accueil de la galerie / FORUM ASYMPTOTE

Dernière modification le Fri Oct 28 12:59:42 CEST 2011 par G.Marris       Valide XHTML